tests/CppCheck.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(CPPCHECK_EXECUTABLE
  36     NAMES cppcheck
  37     DOC "cppcheck executable")
  38 mark_as_advanced(CPPCHECK_EXECUTABLE)
  39 option(CPPCHECK_XML_OUTPUT "Whether to produce XML output from cppcheck (mainly for Jenkins)"
  40        OFF)
  41 mark_as_advanced(CPPCHECK_XML_OUTPUT)
  42
  43 # Depends on stderr redirection and cat
  44 if (CPPCHECK_EXECUTABLE AND UNIX)
  45     # Produce the list of files to check
  46     file(GLOB_RECURSE _inputfiles RELATIVE ${CMAKE_SOURCE_DIR}
  47         ${CMAKE_SOURCE_DIR}/src/*.c
  48         ${CMAKE_SOURCE_DIR}/src/*.cpp
  49         ${CMAKE_SOURCE_DIR}/src/*.cu)
  50     file(GLOB_RECURSE _files_to_ignore RELATIVE ${CMAKE_SOURCE_DIR}
  51         ${CMAKE_SOURCE_DIR}/src/nb_kernel_Elec*.c
  52         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_blas/*.c
  53         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_lapack/*.c
  54         ${CMAKE_SOURCE_DIR}/src/contrib/*.c
  55         ${CMAKE_SOURCE_DIR}/src/contrib/*.cpp
  56         ${CMAKE_SOURCE_DIR}/src/contrib/*.cu
  57         ${CMAKE_SOURCE_DIR}/src/external/*.c
  58         ${CMAKE_SOURCE_DIR}/src/external/*.cpp
  59         ${CMAKE_SOURCE_DIR}/src/external/*.cu
  60         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/scanner.cpp
  61         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/parser.cpp
  62         )
  63     list(REMOVE_ITEM _inputfiles ${_files_to_ignore})
  64
  65     # Set flags for cppcheck
  66     set(_outputext txt)
  67     set(_outputopt --template=gcc)
  68     if (CPPCHECK_XML_OUTPUT)
  69         set(_outputext xml)
  70         set(_outputopt --xml)
  71     endif()
  72     set(_common_flags
  73         --enable=style -DLINUX -DHAVE_UNISTD_H
  74         -I src
  75         -I src/external/thread_mpi/include
  76         -I src/external/tng_io/include
  77         -I ${CMAKE_BINARY_DIR}/src
  78         --quiet
  79         --inline-suppr
  80         ${_outputopt})
  81     set(_c_flags
  82         --suppress=variableScope
  83         --suppress=unnecessaryForwardDeclaration
  84         --suppress=unusedVariable
  85         --suppress=unreadVariable
  86         --suppress=unusedStructMember
  87         --suppress=invalidscanf
  88         --suppress=sizeofCalculation
  89         --suppress=missingInclude:src/programs/mdrun/gmx_gpu_utils/gmx_gpu_utils.cu
  90         --suppress=*:src/external/Random123-1.08/include/Random123/features/compilerfeatures.h
  91         --suppress=assignIfError:src/gromacs/mdlib/nbnxn_atomdata.c #Ticket 5695
  92         --suppress=invalidPointerCast:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  93         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  94         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel_utils.cuh
  95         )
  96     set(_cxx_flags
  97         -D__cplusplus
  98         --suppress=variableScope
  99         --suppress=unnecessaryForwardDeclaration
 100         --suppress=invalidscanf:src/gromacs/fileio/matio.cpp
 101         --suppress=invalidscanf:src/gromacs/fileio/xvgr.cpp
 102         --suppress=invalidscanf:src/gromacs/topology/index.cpp
 103         --suppress=invalidscanf:src/gromacs/gmxpreprocess/pdb2top.cpp
 104         --suppress=passedByValue:src/gromacs/simd/tests/*
 105         )
 106
 107     # This list will hold the list of all files with cppcheck errors
 108     # (one per input file)
 109     set(_filelist)
 110
 111     foreach (_filename ${_inputfiles})
 112         set(_target_name cppcheck-${_filename}.${_outputext})
 113         string(REPLACE "/" "_" _target_name ${_target_name})
 114         list(APPEND _filelist ${_target_name})
 115         if (_filename MATCHES "\\.cpp$")
 116             set(_lang CXX)
 117             set(_lang_flags ${_cxx_flags})
 118         else()
 119             set(_lang C)
 120             set(_lang_flags ${_c_flags})
 121         endif()
 122         add_custom_command(
 123             OUTPUT ${_target_name}
 124             COMMAND ${CPPCHECK_EXECUTABLE} ${_common_flags} ${_lang_flags}
 125                 ${_filename} 2> ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 126             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 127             IMPLICIT_DEPENDS ${_lang} ${CMAKE_SOURCE_DIR}/${_filename}
 128             COMMENT "Running cppcheck for ${_filename}"
 129             VERBATIM)
 130         if (NOT CPPCHECK_XML_OUTPUT)
 131             add_custom_command(
 132                 OUTPUT ${_target_name}
 133                 COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 134                 VERBATIM APPEND)
 135         endif()
 136     endforeach()
 137     if (NOT CPPCHECK_XML_OUTPUT)
 138         set(_target_name cppcheck-errors.${_outputext})
 139         add_custom_command(
 140             OUTPUT ${_target_name}
 141             COMMAND cat ${_filelist} > ${_target_name}
 142             DEPENDS ${_filelist}
 143             COMMENT "Combining cppcheck results"
 144             VERBATIM)
 145         list(APPEND _filelist ${_target_name})
 146     endif()
 147     add_custom_target(cppcheck DEPENDS ${_filelist})
 148 else()
 149     add_custom_target(cppcheck
 150         COMMAND ${CMAKE_COMMAND} -E echo
 151             "cppcheck was not found by CMake. Rerun CMake specifying CPPCHECK_EXECUTABLE."
 152         VERBATIM)
 153 endif()