tests/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(REGRESSIONTEST_PATH "" CACHE PATH "Directory containing regressiontests")
  36 mark_as_advanced(REGRESSIONTEST_PATH)
  37 option(REGRESSIONTEST_DOWNLOAD
  38     "Automatically download regressiontests. Tests can be run with ctest." OFF)
  39
  40 if(REGRESSIONTEST_DOWNLOAD)
  41     if (NOT SOURCE_IS_SOURCE_DISTRIBUTION)
  42         set(REGRESSIONTEST_URL http://gerrit.gromacs.org/snapshot/${REGRESSIONTEST_BRANCH})
  43         set(REGRESSIONTEST_PATH "${CMAKE_CURRENT_BINARY_DIR}/regressiontests"
  44             CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  45     else()
  46         set(REGRESSIONTEST_URL http://gerrit.gromacs.org/download/regressiontests-${REGRESSIONTEST_VERSION}.tar.gz)
  47         set(REGRESSIONTEST_PATH
  48             "${CMAKE_CURRENT_BINARY_DIR}/regressiontests-${REGRESSIONTEST_VERSION}"
  49             CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  50     endif()
  51     set(REGRESSIONTEST_FILE "${CMAKE_CURRENT_BINARY_DIR}/regressiontests.tgz")
  52     message("Downloading: ${REGRESSIONTEST_URL}")
  53     file(DOWNLOAD ${REGRESSIONTEST_URL} "${REGRESSIONTEST_FILE}" SHOW_PROGRESS STATUS status LOG log)
  54     list(GET status 0 status_code)
  55     list(GET status 1 status_string)
  56
  57     if(NOT status_code EQUAL 0)
  58         message(FATAL_ERROR "error: downloading '${REGRESSIONTEST_URL}' failed
  59 status_code: ${status_code}
  60 status_string: ${status_string}
  61 log: ${log}")
  62     endif()
  63     if (SOURCE_IS_SOURCE_DISTRIBUTION)
  64         file(MD5 ${REGRESSIONTEST_FILE} COMPUTED_MD5SUM)
  65         if(NOT ${REGRESSIONTEST_MD5SUM} STREQUAL ${COMPUTED_MD5SUM})
  66             message(FATAL_ERROR "Download of regressiontests failed. Expected MD5 of ${REGRESSIONTEST_MD5SUM} but download has ${COMPUTED_MD5SUM}")
  67         endif()
  68     endif()
  69
  70     file(REMOVE_RECURSE "${REGRESSIONTEST_PATH}") #delete potential prior folder
  71     execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf "${REGRESSIONTEST_FILE}"
  72         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
  73     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  74         message(FATAL_ERROR "Download incorrect. Doesn't contain required gmxtest.pl")
  75     endif()
  76     set(REGRESSIONTEST_DOWNLOAD OFF CACHE BOOL "Tests already downloaded. Set to yes to download again" FORCE)
  77 endif()
  78
  79 if(REGRESSIONTEST_PATH AND (GMX_BLUEGENE OR CMAKE_CROSSCOMPILING OR CMAKE_CONFIGURATION_TYPES OR GMX_BUILD_MDRUN_ONLY))
  80     # TODO: It would be nicer to do these before potentially downloading the tests.
  81     # Bluegene requires us to compile both front-end and back-end binaries
  82     # (single build is insufficient)
  83     # Testing an mdrun-only builds require supporting binaries from a full build
  84     message(WARNING
  85         "With cross-compiling, multi-configuration generators (e.g. Visual Studio), or with mdrun-only builds, running regressiontests from build system is not supported. Please run gmxtest.pl directly.")
  86     set(REGRESSIONTEST_PATH OFF CACHE BOOL
  87         "With cross-compiling or multi-configuration generators, running regressiontests from build system is not supported." FORCE)
  88 endif()
  89
  90 if(REGRESSIONTEST_PATH)
  91     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  92         message(FATAL_ERROR
  93             "REGRESSIONTEST_PATH invalid. The path needs to contain gmxtest.pl.")
  94     endif()
  95
  96     # gmxtests target builds all binaries required for running gmxtest
  97     add_custom_target(gmxtests DEPENDS gmx)
  98     add_dependencies(check gmxtests)
  99
 100     if(GMX_DOUBLE)
 101         list(APPEND ARGS -double)
 102     endif()
 103     if(GMX_LIB_MPI AND NOT MPIEXEC) #autodetection failed or CC=mpicc was used
 104         message(WARNING
 105             "Please set MPIEXEC. Otherwise mpirun is assumed for runnings tests.")
 106     endif()
 107     if(GMX_LIB_MPI)
 108         set(GMX_TEST_NUMBER_PROCS 8 CACHE STRING "Number of processors used for testing")
 109         mark_as_advanced(GMX_TEST_NUMBER_PROCS)
 110         list(APPEND ARGS -np ${GMX_TEST_NUMBER_PROCS})
 111         if(MPIEXEC)
 112             list(APPEND ARGS -mpirun ${MPIEXEC})
 113         endif()
 114         #We should use MPIEXEC_NUMPROC_FLAG but gmxtest.pl doesn't let us pass it
 115     endif()
 116     if(GMX_BINARY_SUFFIX)
 117         list(APPEND ARGS -suffix ${GMX_BINARY_SUFFIX})
 118     endif()
 119     #crosscompile is only used to disable checking whether binaries work
 120     #given that we know they are there and that mdrun might not be exectuable
 121     #(e.g. Cray) we enable it.
 122     list(APPEND ARGS -crosscompile)
 123
 124     set(REGRESSIONTEST_EXTRA_ARGS "" CACHE STRING
 125         "Extra arguments passed to gmxtest")
 126     mark_as_advanced(REGRESSIONTEST_EXTRA_ARGS)
 127     list(APPEND ARGS ${REGRESSIONTEST_EXTRA_ARGS})
 128
 129     list(APPEND ARGS -noverbose -nosuffix)
 130
 131     if(GMX_NATIVE_WINDOWS)
 132         set(PATH_SEPARATOR "\\;")
 133         #replacing \ with / shouldn't be neccessary. But otherwise "..\bin\;c:\.."
 134         #gets turned into "...\bin\\c:\.." don't know why and don't have a better
 135         #workaround. This workaround doesn't hurt.
 136         string(REPLACE "\\" "/" PATH "$ENV{PATH}")
 137         #protect ; (don't treat as list)
 138         string(REPLACE ";" "\\;" PATH "${PATH}")
 139     else()
 140         set(PATH_SEPARATOR ":")
 141         set(PATH "$ENV{PATH}")
 142     endif()
 143
 144     foreach(FOLDER bin lib) #lib folders might be needed for
 145         #e.g. DLLs. For GMX paths native ("\") is needed for GMXLIB detection
 146         file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${FOLDER}" DIR)
 147         set(PATH "${DIR}${PATH_SEPARATOR}${PATH}")
 148     endforeach()
 149
 150     find_program(PERL_EXECUTABLE NAMES "perl")
 151     mark_as_advanced(PERL_EXECUTABLE)
 152
 153     if (NOT PERL_EXECUTABLE)
 154         message(FATAL_ERROR "Perl not found. Install perl, set PERL_EXECUTABLE to the perl location, or unset REGRESSIONTEST_PATH to disable testing.")
 155     endif()
 156
 157     #currently not testing tools because they don't contain any useful tests
 158     foreach(subtest simple complex kernel freeenergy pdb2gmx rotation)
 159         add_test(NAME regressiontests/${subtest}
 160             #windows requires the command to be perl and not the script
 161             COMMAND perl "${REGRESSIONTEST_PATH}/gmxtest.pl" ${subtest} ${ARGS})
 162         set_tests_properties(regressiontests/${subtest} PROPERTIES
 163             ENVIRONMENT "PATH=${PATH}")
 164     endforeach()
 165 else()
 166     add_custom_target(regressiontests-notice
 167         ${CMAKE_COMMAND} -E echo "NOTE: Regression tests have not been run. If you want to run them from the build system, get the correct version of the regression tests package and set REGRESSIONTEST_PATH in CMake to point to it, or set REGRESSIONTEST_DOWNLOAD=ON."
 168         DEPENDS run-ctest
 169         COMMENT "Regression tests not available" VERBATIM)
 170     add_dependencies(check regressiontests-notice)
 171 endif()
 172
 173 include(CppCheck.cmake)