src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 file(GLOB MDRUN_SOURCES mdrun/*.c mdrun/*.cpp)
  36 # make an "object library" that we can re-use for multiple targets
  37 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  38
  39 if(GMX_FAHCORE)
  40     # The lack of a real source file here alongside the object library
  41     # may break some generators, according to CMake documentation. If
  42     # so, we can consider adding some dummy file to make it work.
  43     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  44 elseif(GMX_BUILD_MDRUN_ONLY)
  45     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  46     target_link_libraries(mdrun libgromacs ${GMX_EXE_LINKER_FLAGS})
  47     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  48     set_target_properties(mdrun PROPERTIES
  49         OUTPUT_NAME "${BINARY_NAME}"
  50         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  51     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  52     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  53          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  54     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  55             DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
  56 else()
  57     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  58     if(GMX_X11)
  59         file(GLOB VIEW_SOURCES view/*.cpp)
  60     else()
  61         file(GLOB VIEW_SOURCES view/view.cpp)
  62     endif()
  63     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  64     add_executable(gmx
  65         ${GMX_MAIN_SOURCES}
  66         $<TARGET_OBJECTS:mdrun_objlib>
  67         $<TARGET_OBJECTS:view_objlib>)
  68     target_link_libraries(gmx libgromacs ${GMX_EXE_LINKER_FLAGS})
  69     if(GMX_X11)
  70         target_link_libraries(gmx ${X11_LIBRARIES})
  71     endif()
  72     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  73     set_target_properties(gmx PROPERTIES
  74         OUTPUT_NAME "${BINARY_NAME}"
  75         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  76     install(TARGETS gmx
  77             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  78
  79     ########################
  80     # Completion generation
  81
  82     include(gmxCustomCommandUtilities)
  83
  84     gmx_add_custom_output_target(completion OUTPUT STAMP
  85         COMMAND ${CMAKE_COMMAND} -E make_directory completion
  86         COMMAND ${CMAKE_COMMAND} -E chdir completion
  87             $<TARGET_FILE:gmx> -quiet help -export completion
  88         WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  89         DEPENDS gmx
  90         COMMENT "Generating command-line completions for programs")
  91     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
  92     # this can be done are exactly the same (ability to run the compiled
  93     # binaries).
  94     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  95     if (GMX_BUILD_HELP)
  96         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
  97         set_directory_properties(PROPERTIES
  98             ADDITIONAL_MAKE_CLEAN_FILES "completion")
  99         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 100     endif()
 101     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 102         install(DIRECTORY ${COMPLETION_DIR}/
 103                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 104         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 105              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 106         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 107                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 108     endif()
 109
 110     if (GMX_SYMLINK_OLD_BINARY_NAMES)
 111         configure_file(CreateLinks.cmake.cmakein CreateLinks.cmake @ONLY)
 112         set(CREATE_LINKS_SCRIPT ${CMAKE_CURRENT_BINARY_DIR}/CreateLinks.cmake)
 113         install(SCRIPT ${CREATE_LINKS_SCRIPT} COMPONENT links)
 114     endif()
 115
 116     if(BUILD_TESTING)
 117         add_subdirectory(mdrun/tests)
 118     endif()
 119 endif()