src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \cond \internal \file scanner.l
  36  * \brief
  37  * Tokenizer for the selection language.
  38  *
  39  * \author Teemu Murtola <teemu.murtola@gmail.com>
  40  * \ingroup module_selection
  41  * \endcond
  42  */
  43 /*! \internal \file scanner.cpp
  44  * \brief
  45  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  46  *
  47  * \ingroup module_selection
  48  */
  49 %top{
  50 #if !defined _gmx_sel_yyIN_HEADER
  51 #include "gmxpre.h"
  52 #endif
  53
  54 // Required before flex definitions, since it includes <stdint.h>.
  55 // Otherwise, compilers not strictly C99 get macro redefinition errors,
  56 // since flex defines INT32_MAX etc. in such cases.
  57 #include "gromacs/utility/basedefinitions.h"
  58 }
  59 %{
  60 #include "gromacs/utility/cstringutil.h"
  61
  62 #include "parser.h"
  63 #include "scanner.h"
  64 #include "scanner_internal.h"
  65
  66 // This macro makes the actions a bit shorter, since nearly every action needs
  67 // this call.
  68 #define ADD_TOKEN _gmx_sel_lexer_add_token(yylloc, yytext, yyleng, state)
  69
  70 // Set YY_BREAK to an empty value to avoid warnings (for the PGI compiler)
  71 // when we have return statements followed by break. Instead, we add breaks
  72 // manually.
  73 #define YY_BREAK
  74 %}
  75
  76 INTEGER    [[:digit:]]+
  77 DSEQ       ([[:digit:]]+)
  78 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  79 EXP        ([eE][+-]?{DSEQ})
  80 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  81 STRING     (\"([^\"\\\n]|(\\\"))*\")
  82 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  83 CMPOP      (([<>]=?)|([!=]=))
  84 COMMENT    (#.*)
  85
  86 %option nodefault
  87 %option noyywrap
  88 %option reentrant
  89 %option prefix="_gmx_sel_yy"
  90 %option header-file="scanner_flex.h"
  91 %option nounistd
  92 %option never-interactive
  93
  94 %s matchof
  95 %s matchbool
  96 %s cmdstart
  97
  98 %%
  99
 100 %{
 101     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
 102     int              retval;
 103     /* Return a token if one is pending */
 104     retval = _gmx_sel_lexer_process_pending(yylval, yylloc, state);
 105     if (retval != 0)
 106     {
 107         return retval;
 108     }
 109     /* Handle the start conditions for 'of' matching */
 110     if (state->bMatchOf)
 111     {
 112         BEGIN(matchof);
 113         state->bMatchOf = false;
 114     }
 115     else if (state->bMatchBool)
 116     {
 117         BEGIN(matchbool);
 118         state->bMatchBool = false;
 119     }
 120     else if (state->bCmdStart)
 121     {
 122         BEGIN(cmdstart);
 123         state->bCmdStart = false;
 124     }
 125     else
 126     {
 127         BEGIN(0);
 128     }
 129 %}
 130
 131 {COMMENT}       break;
 132 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 133 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 134 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 135
 136 \\\n            { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 137 ";"|\n          {
 138                     if (yytext[0] == ';' || state->bInteractive)
 139                     {
 140                         rtrim(state->pselstr);
 141                         state->bCmdStart = true;
 142                         return CMD_SEP;
 143                     }
 144                     else
 145                     {
 146                         _gmx_sel_lexer_add_token(yylloc, " ", 1, state);
 147                     }
 148                     break;
 149                 }
 150
 151 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 152 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 153
 154 <matchbool>{
 155 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 156 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 157 }
 158 group           { ADD_TOKEN; return GROUP; }
 159 to              { ADD_TOKEN; return TO; }
 160 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 161 and|"&&"        { ADD_TOKEN; return AND; }
 162 or|"||"         { ADD_TOKEN; return OR; }
 163 xor             { ADD_TOKEN; return XOR; }
 164 not|"!"         { ADD_TOKEN; return NOT; }
 165 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 166
 167 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yylloc, yytext, yyleng, state); }
 168
 169 [[:space:]]+    { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 170 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 171 .               { ADD_TOKEN; return yytext[0]; }