src/gromacs/ewald/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # Set up the module library
  37 add_library(ewald INTERFACE)
  38 gmx_add_libgromacs_sources(
  39     calculate_spline_moduli.cpp
  40     ewald.cpp
  41     ewald_utils.cpp
  42     long_range_correction.cpp
  43     pme.cpp
  44     pme_gather.cpp
  45     pme_grid.cpp
  46     pme_load_balancing.cpp
  47     pme_only.cpp
  48     pme_pp.cpp
  49     pme_redistribute.cpp
  50     pme_solve.cpp
  51     pme_spline_work.cpp
  52     pme_spread.cpp
  53     # Files that implement stubs
  54     pme_gpu_program.cpp
  55     pme_pp_comm_gpu_impl.cpp
  56     pme_coordinate_receiver_gpu_impl.cpp
  57     pme_force_sender_gpu_impl.cpp
  58     )
  59 if (GMX_GPU_CUDA)
  60     gmx_add_libgromacs_sources(
  61         # CUDA-specific sources
  62         pme_gather.cu
  63         pme_solve.cu
  64         pme_spread.cu
  65         pme_gpu_program_impl.cu
  66         pme_pp_comm_gpu_impl.cu
  67         pme_force_sender_gpu_impl.cu
  68         pme_coordinate_receiver_gpu_impl.cu
  69         # GPU-specific sources
  70         pme_gpu.cpp
  71         pme_gpu_internal.cpp
  72         pme_gpu_timings.cpp
  73         )
  74     _gmx_add_files_to_property(CUDA_SOURCES
  75         # Must add these files so they can include device_information.h
  76         pme_gpu_internal.cpp
  77         pme_gpu_timings.cpp
  78         )
  79 elseif (GMX_GPU_OPENCL)
  80     gmx_add_libgromacs_sources(
  81         # OpenCL-specific sources
  82         pme_gpu_program_impl_ocl.cpp
  83         # GPU-specific sources
  84         pme_gpu.cpp
  85         pme_gpu_internal.cpp
  86         pme_gpu_timings.cpp
  87         )
  88 elseif (GMX_GPU_SYCL)
  89     gmx_add_libgromacs_sources(
  90         # GPU-specific sources
  91         pme_gather_sycl.cpp
  92         pme_gpu.cpp
  93         pme_gpu_internal.cpp
  94         pme_gpu_program_impl_sycl.cpp
  95         pme_gpu_timings.cpp
  96         pme_solve_sycl.cpp
  97         pme_spread_sycl.cpp
  98         )
  99     _gmx_add_files_to_property(SYCL_SOURCES
 100         pme_gather_sycl.cpp
 101         pme_gpu_internal.cpp
 102         pme_gpu_program.cpp
 103         pme_gpu_program_impl_sycl.cpp
 104         pme_gpu_3dfft_sycl.cpp
 105         pme_gpu_timings.cpp
 106         pme_solve_sycl.cpp
 107         pme_spread_sycl.cpp
 108       )
 109 else()
 110     gmx_add_libgromacs_sources(
 111         # Files that implement stubs
 112         pme_gpu_program_impl.cpp
 113         )
 114 endif()
 115
 116 # Source files have the following private module dependencies.
 117 target_link_libraries(ewald PRIVATE
 118                       #                      gmxlib
 119                       #                      math
 120                       #                      mdtypes
 121                       #                      tng_io
 122                       )
 123
 124 # Public interface for modules, including dependencies and interfaces
 125 #target_include_directories(ewald PUBLIC
 126 target_include_directories(ewald INTERFACE
 127                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
 128 #target_link_libraries(ewald PUBLIC
 129 target_link_libraries(ewald INTERFACE
 130                       legacy_api
 131                       )
 132
 133 # TODO: when fileio is an OBJECT target
 134 #target_link_libraries(ewald PUBLIC legacy_api)
 135 #target_link_libraries(ewald PRIVATE common)
 136
 137 # Module dependencies
 138 # This module convey transitive dependence on these modules.
 139 #target_link_libraries(ewald PUBLIC
 140 target_link_libraries(ewald INTERFACE
 141                       #                      utility
 142                       )
 143 # Source files have the following private module dependencies.
 144 #target_link_libraries(ewald PRIVATE tng_io)
 145 # TODO: Explicitly link specific modules.
 146 #target_link_libraries(ewald PRIVATE legacy_modules)
 147
 148 if (BUILD_TESTING)
 149     add_subdirectory(tests)
 150 endif()
 151
 152
 153 set(PME_OCL_KERNEL_SOURCES
 154     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gpu_calculate_splines.clh"
 155     "${CMAKE_CURRENT_SOURCE_DIR}/pme_solve.clh"
 156     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gather.clh"
 157     "${CMAKE_CURRENT_SOURCE_DIR}/pme_spread.clh")
 158
 159 if(CLANG_TIDY_EXE)
 160    set(OCL_COMPILER "${CLANG_TIDY_EXE}")
 161    set(CLANG_TIDY_ARGS "-quiet;-checks=*,-readability-implicit-bool-conversion,-llvm-header-guard,-hicpp-signed-bitwise,-clang-analyzer-deadcode.DeadStores,-google-readability-todo,-clang-diagnostic-padded,-fcomment-block-commands=internal;--;${CMAKE_C_COMPILER}")
 162 else()
 163    set(OCL_COMPILER "${CMAKE_C_COMPILER}")
 164 endif()
 165
 166 # TODO: test all warp sizes on all vendor targets?
 167 foreach(VENDOR AMD NVIDIA INTEL)
 168     foreach(WARPSIZE 16 32 64)
 169         math(EXPR SPREAD_WG_SIZE "8*${WARPSIZE}")
 170         math(EXPR SOLVE_WG_SIZE "8*${WARPSIZE}")
 171         math(EXPR GATHER_WG_SIZE "4*${WARPSIZE}")
 172         set(OBJ_FILE pme_ocl_kernel_warpSize${WARPSIZE}_${VENDOR}.o)
 173         add_custom_command(OUTPUT ${OBJ_FILE} COMMAND ${OCL_COMPILER}
 174         ${CMAKE_CURRENT_SOURCE_DIR}/pme_program.cl ${CLANG_TIDY_ARGS}
 175         -Xclang -finclude-default-header  -D_${VENDOR}_SOURCE_
 176         -Dwarp_size=${WARPSIZE}
 177         -Dorder=4
 178         -DthreadsPerAtom=16
 179         -Dc_pmeMaxUnitcellShift=2
 180         -Dc_skipNeutralAtoms=false
 181         -Dc_virialAndEnergyCount=7
 182         -Dc_spreadWorkGroupSize=${SPREAD_WG_SIZE}
 183         -Dc_solveMaxWorkGroupSize=${SOLVE_WG_SIZE}
 184         -Dc_gatherWorkGroupSize=${GATHER_WG_SIZE}
 185         -DDIM=3 -DXX=0 -DYY=1 -DZZ=2
 186         -DwrapX=true -DwrapY=true
 187         -c -I ${CMAKE_SOURCE_DIR}/src -std=cl1.2
 188         -Weverything  -Wno-conversion -Wno-missing-variable-declarations -Wno-used-but-marked-unused
 189         -Wno-cast-align -Wno-incompatible-pointer-types
 190         # to avoid  "warning: unknown command tag name" for \internal
 191         -Wno-documentation-unknown-command
 192         # to avoid pme_gpu_types.h:100:52: warning: padding struct 'struct PmeGpuConstParams' with 4 bytes to align 'd_virialAndEnergy'
 193         -Wno-padded
 194         -o${OBJ_FILE}
 195         )
 196         list(APPEND PME_OCL_KERNELS ${OBJ_FILE})
 197     endforeach()
 198 endforeach()
 199
 200 add_custom_target(ocl_pme_kernels DEPENDS ${PME_OCL_KERNELS} )
 201 gmx_set_custom_target_output(ocl_pme_kernels ${PME_OCL_KERNELS})