src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  38
  39 function (gmx_install_headers)
  40     if (NOT GMX_BUILD_MDRUN_ONLY)
  41         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  42         install(FILES       ${ARGN}
  43                 DESTINATION "${INCL_INSTALL_DIR}/${_dest}"
  44                 COMPONENT   development)
  45     endif()
  46     foreach (_file ${ARGN})
  47         if (IS_ABSOLUTE "${_file}")
  48             set_property(GLOBAL APPEND PROPERTY GMX_INSTALLED_HEADERS ${_file})
  49         else()
  50             set_property(GLOBAL APPEND PROPERTY GMX_INSTALLED_HEADERS
  51                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  52         endif()
  53     endforeach()
  54 endfunction ()
  55
  56 function (gmx_write_installed_header_list)
  57     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  58     string(REPLACE ";" "\n" _list "${_list}")
  59     # TODO: Make this only update the file timestamp if the contents actually change.
  60     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  61 endfunction()
  62
  63 if(GMX_USE_TNG)
  64     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  65            OFF)
  66     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  67     if(GMX_EXTERNAL_TNG)
  68         find_package(TNG_IO 1.6.0)
  69         if(NOT TNG_IO_FOUND)
  70             message(FATAL_ERROR
  71                 "TNG >= 1.6.0 not found. "
  72                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  73         endif()
  74         include_directories(${TNG_IO_INCLUDE_DIRS})
  75     endif()
  76     if(NOT GMX_EXTERNAL_TNG)
  77         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  78         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  79         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  80         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  81
  82         if (HAVE_ZLIB)
  83             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  84             include_directories(${ZLIB_INCLUDE_DIRS})
  85         endif()
  86     endif()
  87 else()
  88     # We still need to get tng/tng_io_fwd.h from somewhere!
  89     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  90 endif()
  91
  92 add_subdirectory(gmxlib)
  93 add_subdirectory(mdlib)
  94 add_subdirectory(gmxpreprocess)
  95 add_subdirectory(listed-forces)
  96 add_subdirectory(commandline)
  97 add_subdirectory(fft)
  98 add_subdirectory(linearalgebra)
  99 add_subdirectory(math)
 100 add_subdirectory(random)
 101 add_subdirectory(onlinehelp)
 102 add_subdirectory(options)
 103 add_subdirectory(pbcutil)
 104 add_subdirectory(timing)
 105 add_subdirectory(topology)
 106 add_subdirectory(utility)
 107 add_subdirectory(fileio)
 108 add_subdirectory(swap)
 109 add_subdirectory(essentialdynamics)
 110 add_subdirectory(pulling)
 111 add_subdirectory(simd)
 112 add_subdirectory(imd)
 113 if (NOT GMX_BUILD_MDRUN_ONLY)
 114     add_subdirectory(legacyheaders)
 115     add_subdirectory(gmxana)
 116     add_subdirectory(statistics)
 117     add_subdirectory(analysisdata)
 118     add_subdirectory(selection)
 119     add_subdirectory(trajectoryanalysis)
 120     add_subdirectory(tools)
 121 endif()
 122
 123 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 124
 125 # This would be the standard way to include thread_mpi, but
 126 # we want libgromacs to link the functions directly
 127 #if(GMX_THREAD_MPI)
 128 #    add_subdirectory(thread_mpi)
 129 #endif()
 130 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 131
 132 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 133 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 134
 135 configure_file(version.h.cmakein version.h)
 136 gmx_install_headers(
 137     analysisdata.h
 138     commandline.h
 139     options.h
 140     selection.h
 141     trajectoryanalysis.h
 142     utility.h
 143     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 144     )
 145
 146 # This code is here instead of utility/CMakeLists.txt, because CMake
 147 # custom commands and source file properties can only be set in the directory
 148 # that contains the target that uses them.
 149 # TODO: Generate a header instead that can be included from baseversion.c.
 150 # That probably simplifies things somewhat.
 151 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 152 gmx_configure_version_file(
 153     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 154     REMOTE_HASH SOURCE_FILE)
 155 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 156
 157 # apply gcc 4.4.x bug workaround
 158 if(GMX_USE_GCC44_BUG_WORKAROUND)
 159    include(gmxGCC44O3BugWorkaround)
 160    gmx_apply_gcc44_bug_workaround("listed-forces/bonded.cpp")
 161    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 162    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 163 endif()
 164
 165 if (GMX_GPU)
 166     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES}
 167             OPTIONS
 168             RELWITHDEBINFO -g
 169             DEBUG -g -D_DEBUG_=1)
 170 else()
 171     add_library(libgromacs ${LIBGROMACS_SOURCES})
 172 endif()
 173
 174 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 175 # is a generated source file. These are awkward to suppress inline, so
 176 # we do it in the compilation command (after testing that the compiler
 177 # supports the suppressions). Setting the properties only works after
 178 # the related target has been created, e.g. after when the file is
 179 # used with add_library().
 180 include(CheckCXXCompilerFlag)
 181 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 182 if (HAS_NO_UNUSED_PARAMETER)
 183     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 184 endif()
 185 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 186 if (HAS_NO_DEPRECATED_REGISTER)
 187     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 188 else()
 189     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 190     if (HAS_NO_DEPRECATED)
 191         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 192     endif()
 193 endif()
 194 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 195
 196 target_link_libraries(libgromacs
 197                       ${EXTRAE_LIBRARIES}
 198                       ${GMX_EXTRA_LIBRARIES}
 199                       ${TNG_IO_LIBRARIES}
 200                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 201                       ${XML_LIBRARIES}
 202                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 203 set_target_properties(libgromacs PROPERTIES
 204                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 205                       SOVERSION ${LIBRARY_SOVERSION}
 206                       VERSION ${LIBRARY_VERSION}
 207                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 208
 209 gmx_write_installed_header_list()
 210
 211 # Only install the library in mdrun-only mode if it is actually necessary
 212 # for the binary
 213 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 214     install(TARGETS libgromacs
 215             EXPORT libgromacs
 216             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 217             RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 218             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 219             COMPONENT libraries)
 220 endif()
 221
 222 if (NOT GMX_BUILD_MDRUN_ONLY)
 223     include(InstallLibInfo.cmake)
 224 endif()
 225
 226 if (INSTALL_CUDART_LIB) #can be set manual by user
 227     if (GMX_GPU)
 228         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 229             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 230             if(IS_CUDART) #libcuda should not be installed
 231                 #install also name-links (linker uses those)
 232                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 233                 install(FILES ${CUDA_LIBS} DESTINATION
 234                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 235             endif()
 236         endforeach()
 237     else()
 238         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 239     endif()
 240 endif()