src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019 by the GROMACS development team.
   6 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 set(LIBGROMACS_SOURCES)
  38
  39 if (GMX_CLANG_CUDA)
  40     include(gmxClangCudaUtils)
  41 endif()
  42
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  44 set_property(GLOBAL PROPERTY CUDA_SOURCES)
  45 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  46 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  47
  48 set(libgromacs_object_library_dependencies "")
  49 function (_gmx_add_files_to_property PROPERTY)
  50     foreach (_file ${ARGN})
  51         if (IS_ABSOLUTE "${_file}")
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  53         else()
  54             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  55                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  56         endif()
  57     endforeach()
  58 endfunction ()
  59
  60 function (gmx_add_libgromacs_sources)
  61     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  62 endfunction ()
  63
  64 # Permit the configuration to disable compiling the many nbnxm kernels
  65 # and others involved in force calculations. Currently only
  66 # short-ranged and bonded kernels are disabled this way, but in future
  67 # others may be appropriate. Thus the cmake option is not specific to
  68 # nbnxm module.
  69 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  70 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  71
  72 # Add these contents first because linking their tests can take a lot
  73 # of time, so we want lots of parallel work still available after
  74 # linking starts.
  75 add_subdirectory(utility)
  76 # Add normal contents
  77 add_subdirectory(gmxlib)
  78 add_subdirectory(mdlib)
  79 add_subdirectory(applied_forces)
  80 add_subdirectory(listed_forces)
  81 add_subdirectory(nbnxm)
  82 add_subdirectory(commandline)
  83 add_subdirectory(domdec)
  84 add_subdirectory(ewald)
  85 add_subdirectory(fft)
  86 add_subdirectory(gpu_utils)
  87 add_subdirectory(hardware)
  88 add_subdirectory(linearalgebra)
  89 add_subdirectory(math)
  90 add_subdirectory(mdrun)
  91 add_subdirectory(mdrunutility)
  92 add_subdirectory(mdspan)
  93 add_subdirectory(mdtypes)
  94 add_subdirectory(onlinehelp)
  95 add_subdirectory(options)
  96 add_subdirectory(pbcutil)
  97 add_subdirectory(random)
  98 add_subdirectory(restraint)
  99 add_subdirectory(tables)
 100 add_subdirectory(taskassignment)
 101 add_subdirectory(timing)
 102 add_subdirectory(topology)
 103 add_subdirectory(trajectory)
 104 add_subdirectory(swap)
 105 add_subdirectory(essentialdynamics)
 106 add_subdirectory(pulling)
 107 add_subdirectory(simd)
 108 add_subdirectory(imd)
 109 add_subdirectory(compat)
 110 add_subdirectory(mimic)
 111 add_subdirectory(modularsimulator)
 112 add_subdirectory(gmxana)
 113 add_subdirectory(gmxpreprocess)
 114 add_subdirectory(correlationfunctions)
 115 add_subdirectory(statistics)
 116 add_subdirectory(analysisdata)
 117 add_subdirectory(coordinateio)
 118 add_subdirectory(trajectoryanalysis)
 119 add_subdirectory(energyanalysis)
 120 add_subdirectory(tools)
 121
 122 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 123 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 124
 125 # This would be the standard way to include thread_mpi, but
 126 # we want libgromacs to link the functions directly
 127 #if(GMX_THREAD_MPI)
 128 #    add_subdirectory(thread_mpi)
 129 #endif()
 130 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 131 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 132 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 133 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 134 if(CYGWIN)
 135     # Needs POSIX-isms for strdup, not just std-isms
 136     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 137 endif()
 138 gmx_target_compile_options(thread_mpi)
 139 if (WIN32)
 140     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 141 endif()
 142 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 143
 144 if(GMX_INSTALL_LEGACY_API)
 145   install(FILES
 146           analysisdata.h
 147           options.h
 148           selection.h
 149           trajectoryanalysis.h
 150           DESTINATION include/gromacs)
 151 endif()
 152
 153 # This code is here instead of utility/CMakeLists.txt, because CMake
 154 # custom commands and source file properties can only be set in the directory
 155 # that contains the target that uses them.
 156 # TODO: Generate a header instead that can be included from baseversion.cpp.
 157 # That probably simplifies things somewhat.
 158 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 159 gmx_configure_version_file(
 160     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 161     REMOTE_HASH
 162     EXTRA_VARS
 163         GMX_SOURCE_DOI
 164         GMX_RELEASE_HASH
 165         GMX_SOURCE_HASH
 166         )
 167 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 168
 169 # Mark some shared GPU implementation files to compile with CUDA if needed
 170 if (GMX_GPU_CUDA)
 171     get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 172     set_source_files_properties(${CUDA_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 173 endif()
 174
 175 if (GMX_GPU_CUDA)
 176     # Work around FindCUDA that prevents using target_link_libraries()
 177     # with keywords otherwise...
 178     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 179     if (NOT GMX_CLANG_CUDA)
 180         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 181     else()
 182         add_library(libgromacs ${LIBGROMACS_SOURCES})
 183     endif()
 184     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 185 else()
 186     add_library(libgromacs ${LIBGROMACS_SOURCES})
 187 endif()
 188
 189 if (TARGET Heffte::Heffte)
 190     target_link_libraries(libgromacs PRIVATE Heffte::Heffte)
 191 endif()
 192
 193 if (GMX_SYCL_HIPSYCL AND GMX_HIPSYCL_HAVE_HIP_TARGET)
 194     target_link_libraries(libgromacs PUBLIC roc::rocfft)
 195 endif()
 196
 197 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:common>)
 198 # As long as the libgromacs target has source files that reference headers from
 199 # modules that don't provide CMake targets, libgromacs needs to use `src/`
 200 # amongst its include directories (to support `#include "gromacs/module/header.h"`).
 201 add_library(legacy_modules INTERFACE)
 202 target_include_directories(legacy_modules INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>)
 203 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:legacy_modules>)
 204
 205 # Add these contents first because linking their tests can take a lot
 206 # of time, so we want lots of parallel work still available after
 207 # linking starts.
 208 add_subdirectory(fileio)
 209 add_subdirectory(selection)
 210
 211 # Handle the object libraries that contain the source file
 212 # dependencies that need special handling because they are generated
 213 # or external code.
 214 foreach(object_library ${libgromacs_object_library_dependencies})
 215     if (BUILD_SHARED_LIBS)
 216         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 217     endif()
 218     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 219     target_link_libraries(${object_library} PRIVATE common)
 220
 221     # Add the sources from the object libraries to the main library.
 222     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 223 endforeach()
 224 gmx_target_compile_options(libgromacs)
 225 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 226 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 227
 228 if (GMX_GPU_OPENCL)
 229     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 230     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 231
 232     # Default to using clFFT found on the system
 233     # switch to quiet at the second run.
 234     if (DEFINED clFFT_LIBRARY)
 235         set (clFFT_FIND_QUIETLY TRUE)
 236     endif()
 237     find_package(clFFT)
 238     if (NOT clFFT_FOUND)
 239         if (GMX_EXTERNAL_CLFFT)
 240             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 241         endif()
 242
 243         if(MSVC)
 244             message(FATAL_ERROR
 245 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 246 requires clFFT, which was not found on your system. GROMACS does bundle
 247 clFFT to help with building for OpenCL, but that clFFT has not yet been
 248 ported to the more recent versions of that compiler that GROMACS itself
 249 requires. Thus for now, OpenCL is not available with MSVC and the internal
 250 build of clFFT in GROMACS 2019. Either change compiler, try installing
 251 a clFFT package, or use the latest GROMACS 2018 point release.")
 252         endif()
 253
 254         # Fall back on the internal version
 255         set (_clFFT_dir ../external/clFFT/src)
 256         add_subdirectory(${_clFFT_dir} clFFT-build)
 257         target_sources(libgromacs PRIVATE
 258             $<TARGET_OBJECTS:clFFT>
 259         )
 260         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 261         # Use the magic variable for how to link any library needed for
 262         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 263         # (e.g. Windows, BSD, Mac).
 264         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 265     else()
 266         target_link_libraries(libgromacs PRIVATE clFFT)
 267     endif()
 268 endif()
 269
 270 # Permit GROMACS code to include externally developed headers, such as
 271 # the functionality from the nonstd project that we use for
 272 # gmx::compat::optional. These are included as system headers so that
 273 # no warnings are issued from them.
 274 #
 275 # TODO Perhaps generalize this for all headers from src/external
 276 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 277
 278 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 279     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 280     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 281     # with the SIMD_AVX_512_CXX_FLAGS flags.
 282     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 283 endif()
 284
 285 # Do any special handling needed for .cpp files that use
 286 # CUDA runtime headers
 287 if (GMX_GPU_CUDA AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 288     foreach(_compile_flag ${NVCC_CLANG_SUPPRESSIONS_CXXFLAGS})
 289         set(GMX_CUDA_CLANG_FLAGS "${GMX_CUDA_CLANG_FLAGS} ${_compile_flag}")
 290     endforeach()
 291     if (GMX_CLANG_CUDA)
 292         foreach (_file ${LIBGROMACS_SOURCES})
 293             get_filename_component(_ext ${_file} EXT)
 294             get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 295             if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 296                 gmx_compile_cuda_file_with_clang(${_file})
 297             endif()
 298         endforeach()
 299     else()
 300         get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 301         set_source_files_properties(${CUDA_SOURCES} PROPERTIES COMPILE_FLAGS ${GMX_CUDA_CLANG_FLAGS})
 302     endif()
 303 endif()
 304
 305 # Only add the -fsycl flag to sources that really need it
 306 if (GMX_GPU_SYCL)
 307     get_property(SYCL_SOURCES GLOBAL PROPERTY SYCL_SOURCES)
 308     add_sycl_to_target(TARGET libgromacs SOURCES ${SYCL_SOURCES})
 309 endif()
 310
 311 gmx_setup_tng_for_libgromacs()
 312
 313 # We apply the SYCL flag explicitly just for libgromacs, since bugs in the beta versions of
 314 # icpx/dpcpp leads to crashes if we try to link an library without any SYCL code with the
 315 # -fsycl flag enabled. Once that bug is fixed, we should change it to simply add
 316 # SYCL_CXX_FLAGS to GMX_SHARED_LINKER_FLAGS.
 317 target_link_libraries(libgromacs
 318                       PRIVATE
 319                       ${EXTRAE_LIBRARIES}
 320                       ${GMX_EXTRA_LIBRARIES}
 321                       ${GMX_COMMON_LIBRARIES}
 322                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 323                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 324                       ${SYCL_CXX_FLAGS}
 325                       ${OpenCL_LIBRARIES}
 326                       $<$<PLATFORM_ID:SunOS>:socket>
 327                       PUBLIC
 328                       ${GMX_PUBLIC_LIBRARIES}
 329                       )
 330 target_link_libraries(libgromacs PUBLIC legacy_api)
 331 # Dependencies from libgromacs to the modules are set up here, but
 332 # once the add_subdirectory() commands are re-ordered then
 333 # responsibility for setting this up will move to the respective
 334 # modules.
 335 target_link_libraries(libgromacs PRIVATE
 336                       $<BUILD_INTERFACE:analysisdata>
 337                       $<BUILD_INTERFACE:applied_forces>
 338                       $<BUILD_INTERFACE:commandline>
 339                       $<BUILD_INTERFACE:compat>
 340                       $<BUILD_INTERFACE:coordinateio>
 341                       $<BUILD_INTERFACE:correlationfunctions>
 342                       $<BUILD_INTERFACE:domdec>
 343 #                      $<BUILD_INTERFACE:energyanalysis>
 344                       $<BUILD_INTERFACE:essentialdynamics>
 345                       $<BUILD_INTERFACE:ewald>
 346                       $<BUILD_INTERFACE:fft>
 347                       $<BUILD_INTERFACE:fileio>
 348                       $<BUILD_INTERFACE:gmxana>
 349                       $<BUILD_INTERFACE:gmxlib>
 350                       $<BUILD_INTERFACE:gmxpreprocess>
 351                       $<BUILD_INTERFACE:gpu_utils>
 352                       $<BUILD_INTERFACE:hardware>
 353                       $<BUILD_INTERFACE:imd>
 354                       $<BUILD_INTERFACE:linearalgebra>
 355                       $<BUILD_INTERFACE:listed_forces>
 356                       $<BUILD_INTERFACE:math>
 357                       $<BUILD_INTERFACE:mdlib>
 358                       $<BUILD_INTERFACE:mdrun>
 359                       $<BUILD_INTERFACE:mdrunutility>
 360                       $<BUILD_INTERFACE:mdspan>
 361                       $<BUILD_INTERFACE:mdtypes>
 362                       $<BUILD_INTERFACE:mimic>
 363                       $<BUILD_INTERFACE:modularsimulator>
 364                       $<BUILD_INTERFACE:nbnxm>
 365                       $<BUILD_INTERFACE:onlinehelp>
 366                       $<BUILD_INTERFACE:options>
 367                       $<BUILD_INTERFACE:pbcutil>
 368                       $<BUILD_INTERFACE:pulling>
 369                       $<BUILD_INTERFACE:random>
 370                       $<BUILD_INTERFACE:restraint>
 371                       $<BUILD_INTERFACE:selection>
 372                       $<BUILD_INTERFACE:simd>
 373                       $<BUILD_INTERFACE:statistics>
 374                       $<BUILD_INTERFACE:swap>
 375                       $<BUILD_INTERFACE:tables>
 376                       $<BUILD_INTERFACE:taskassignment>
 377                       $<BUILD_INTERFACE:timing>
 378                       $<BUILD_INTERFACE:tools>
 379                       $<BUILD_INTERFACE:topology>
 380                       $<BUILD_INTERFACE:trajectory>
 381                       $<BUILD_INTERFACE:trajectoryanalysis>
 382                       $<BUILD_INTERFACE:utility>
 383     )
 384 if (GMX_OPENMP)
 385     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 386 endif()
 387 set_target_properties(libgromacs PROPERTIES
 388                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 389                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 390                       VERSION ${LIBRARY_VERSION}
 391                       )
 392
 393 gmx_manage_lmfit()
 394 target_link_libraries(libgromacs PRIVATE lmfit)
 395 gmx_manage_muparser()
 396 target_link_libraries(libgromacs PRIVATE muparser)
 397
 398 # Make sure we fix "everything" found by compilers that support that
 399 gmx_warn_on_everything(libgromacs)
 400 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 401    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 402      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 403      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 404      /wd6001  #unitialized memory
 405      /wd6011  #derefencing NULL
 406      /wd6053  #prior call not zero-terminate
 407      /wd6054  #might not be zero-terminated
 408      /wd6385  #reading invalid data
 409      /wd6386  #buffer overrun
 410      /wd6387  #could be '0'
 411      /wd28199 #uninitialized memory
 412      # For compile time constant (e.g. templates) the following warnings have flase postives
 413      /wd6239  #(<non-zero> && <expr>)
 414      /wd6240  #(<expr> && <non-zero>)
 415      /wd6294  #Ill-defined for-loop
 416      /wd6326  #comparison of constant with other constant
 417      /wd28020 #expression involving paramter is not true
 418      # Misc
 419      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 420      /wd6993  #OpenMP ignored
 421      #TODO
 422      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 423      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 424      /wd6246  #hides declaration
 425      >
 426    )
 427 endif()
 428
 429 if (GMX_CLANG_TIDY)
 430    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 431        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 432 endif()
 433
 434 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 435 # and we know they are not real issues. So we only check that it can compile without error
 436 # but ignore all warnings.
 437 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 438     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 439 endif()
 440
 441 # TODO: Stop installing libgromacs. Possibly allow installation during deprecation period with GMX_INSTALL_LEGACY_API.
 442 if (BUILD_SHARED_LIBS)
 443     install(TARGETS libgromacs
 444             EXPORT libgromacs
 445             LIBRARY
 446                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 447                 COMPONENT libraries
 448             RUNTIME
 449                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 450                 COMPONENT libraries
 451             ARCHIVE
 452                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 453                 COMPONENT libraries
 454             INCLUDES DESTINATION include)
 455     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 456     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 457     if(GMX_INSTALL_LEGACY_API)
 458         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 459     endif()
 460 endif()
 461 add_library(Gromacs::libgromacs ALIAS libgromacs)
 462
 463 include(InstallLibInfo.cmake)
 464
 465 # Technically, the user could want to do this for an OpenCL build
 466 # using the CUDA runtime, but currently there's no reason to want to
 467 # do that.
 468 if (INSTALL_CUDART_LIB) #can be set manual by user
 469     if (GMX_GPU_CUDA)
 470         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 471             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 472             if(IS_CUDART) #libcuda should not be installed
 473                 #install also name-links (linker uses those)
 474                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 475                 install(FILES ${CUDA_LIBS} DESTINATION
 476                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 477             endif()
 478         endforeach()
 479     else()
 480         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 481     endif()
 482 endif()
 483
 484 if(GMX_GPU_OPENCL)
 485     # Install the utility headers
 486     file(GLOB OPENCL_INSTALLED_FILES
 487         gpu_utils/vectype_ops.clh
 488         gpu_utils/device_utils.clh
 489         )
 490     install(FILES ${OPENCL_INSTALLED_FILES}
 491         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 492         COMPONENT libraries)
 493     file(GLOB OPENCL_INSTALLED_FILES
 494         pbcutil/ishift.h
 495         )
 496     install(FILES ${OPENCL_INSTALLED_FILES}
 497         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 498         COMPONENT libraries)
 499
 500     # Install the NBNXM source and headers
 501     file(GLOB OPENCL_INSTALLED_FILES
 502         nbnxm/constants.h
 503         )
 504     install(FILES ${OPENCL_INSTALLED_FILES}
 505         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 506         COMPONENT libraries)
 507     file(GLOB OPENCL_INSTALLED_FILES
 508         nbnxm/opencl/nbnxm_ocl_kernels.cl
 509         nbnxm/opencl/nbnxm_ocl_kernel.clh
 510         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 511         nbnxm/opencl/nbnxm_ocl_kernels.clh
 512         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 513         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 514         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 515         nbnxm/opencl/nbnxm_ocl_consts.h
 516         )
 517     install(FILES ${OPENCL_INSTALLED_FILES}
 518         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 519         COMPONENT libraries)
 520
 521     # Install the PME source and headers
 522     file(GLOB OPENCL_INSTALLED_FILES
 523         ewald/pme_spread.clh
 524         ewald/pme_solve.clh
 525         ewald/pme_gather.clh
 526         ewald/pme_gpu_calculate_splines.clh
 527         ewald/pme_program.cl
 528         ewald/pme_gpu_types.h
 529         )
 530     install(FILES ${OPENCL_INSTALLED_FILES}
 531         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 532         COMPONENT libraries)
 533 endif()