src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 if(GMX_USE_TNG)
  49     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  50            OFF)
  51     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  52     if(GMX_EXTERNAL_TNG)
  53         find_package(TNG_IO 1.6.0)
  54         if(NOT TNG_IO_FOUND)
  55             message(FATAL_ERROR
  56                 "TNG >= 1.6.0 not found. "
  57                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  58         endif()
  59         include_directories(${TNG_IO_INCLUDE_DIRS})
  60     endif()
  61     if(NOT GMX_EXTERNAL_TNG)
  62         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  63         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  64         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  65         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  66
  67         if (HAVE_ZLIB)
  68             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  69             include_directories(${ZLIB_INCLUDE_DIRS})
  70         endif()
  71     endif()
  72 else()
  73     # We still need to get tng/tng_io_fwd.h from somewhere!
  74     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  75 endif()
  76
  77 add_subdirectory(gmxlib)
  78 add_subdirectory(mdlib)
  79 add_subdirectory(gmxpreprocess)
  80 add_subdirectory(commandline)
  81 add_subdirectory(fft)
  82 add_subdirectory(linearalgebra)
  83 add_subdirectory(math)
  84 add_subdirectory(random)
  85 add_subdirectory(onlinehelp)
  86 add_subdirectory(options)
  87 add_subdirectory(timing)
  88 add_subdirectory(utility)
  89 add_subdirectory(fileio)
  90 add_subdirectory(swap)
  91 add_subdirectory(essentialdynamics)
  92 add_subdirectory(pulling)
  93 add_subdirectory(simd)
  94 add_subdirectory(imd)
  95 if (NOT GMX_BUILD_MDRUN_ONLY)
  96     add_subdirectory(legacyheaders)
  97     add_subdirectory(gmxana)
  98     add_subdirectory(statistics)
  99     add_subdirectory(analysisdata)
 100     add_subdirectory(selection)
 101     add_subdirectory(trajectoryanalysis)
 102     add_subdirectory(tools)
 103 endif()
 104
 105 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 106
 107 # This would be the standard way to include thread_mpi, but
 108 # we want libgromacs to link the functions directly
 109 #if(GMX_THREAD_MPI)
 110 #    add_subdirectory(thread_mpi)
 111 #endif()
 112 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 113
 114 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 115 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 116
 117 file(GLOB LIBGROMACS_HEADERS *.h)
 118 configure_file(version.h.cmakein version.h)
 119 gmx_install_headers("" ${LIBGROMACS_HEADERS})
 120 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
 121
 122 # Add target that generates baseversion-gen.c every time make is run
 123 # if git version info is requested, or create it statically.
 124 # This code is here instead of utility/CMakeLists.txt because CMake
 125 # ignores set_source_file_properties from subdirectories.
 126 set(GENERATED_VERSION_FILE
 127     ${CMAKE_CURRENT_BINARY_DIR}/utility/baseversion-gen.c)
 128 set(GENERATED_VERSION_FILE_SOURCE
 129     ${CMAKE_CURRENT_SOURCE_DIR}/utility/baseversion-gen.c.cmakein)
 130 if (GMX_GIT_VERSION_INFO)
 131     add_custom_target(gmx-version ALL
 132             COMMAND ${CMAKE_COMMAND}
 133                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
 134                 -D PROJECT_VERSION="${PROJECT_VERSION}"
 135                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
 136                 -D VERSION_CMAKEIN=${GENERATED_VERSION_FILE_SOURCE}
 137                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
 138                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
 139             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 140             DEPENDS ${GENERATED_VERSION_FILE_SOURCE}
 141             COMMENT "Generating git version information")
 142     set_source_files_properties(${GENERATED_VERSION_FILE}
 143                                 PROPERTIES GENERATED true)
 144 else()
 145     set(GMX_PROJECT_VERSION_STR ${PROJECT_VERSION})
 146     configure_file(${GENERATED_VERSION_FILE_SOURCE} ${GENERATED_VERSION_FILE})
 147 endif()
 148 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 149
 150 # apply gcc 4.4.x bug workaround
 151 if(GMX_USE_GCC44_BUG_WORKAROUND)
 152    include(gmxGCC44O3BugWorkaround)
 153    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 154    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 155    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 156 endif()
 157
 158 add_library(libgromacs ${LIBGROMACS_SOURCES})
 159 if (GMX_GIT_VERSION_INFO)
 160     add_dependencies(libgromacs gmx-version)
 161 endif()
 162
 163 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 164 # is a generated source file. These are awkward to suppress inline, so
 165 # we do it in the compilation command (after testing that the compiler
 166 # supports the suppressions). Setting the properties only works after
 167 # the related target has been created, e.g. after when the file is
 168 # used with add_library().
 169 include(CheckCXXCompilerFlag)
 170 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 171 if (HAS_NO_UNUSED_PARAMETER)
 172     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 173 endif()
 174 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 175 if (HAS_NO_DEPRECATED_REGISTER)
 176     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 177 else()
 178     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 179     if (HAS_NO_DEPRECATED)
 180         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 181     endif()
 182 endif()
 183 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 184
 185 target_link_libraries(libgromacs
 186                       ${EXTRAE_LIBRARIES}
 187                       ${GMX_GPU_LIBRARIES}
 188                       ${GMX_EXTRA_LIBRARIES}
 189                       ${TNG_IO_LIBRARIES}
 190                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 191                       ${XML_LIBRARIES}
 192                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 193 set_target_properties(libgromacs PROPERTIES
 194                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 195                       SOVERSION ${LIBRARY_SOVERSION}
 196                       VERSION ${LIBRARY_VERSION}
 197                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 198
 199 # Only install the library in mdrun-only mode if it is actually necessary
 200 # for the binary
 201 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 202     install(TARGETS libgromacs
 203         LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 204         RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 205         ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 206         COMPONENT libraries)
 207 endif()
 208
 209 if (NOT GMX_BUILD_MDRUN_ONLY)
 210     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 211                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 212     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 213             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 214             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 215             COMPONENT development)
 216 endif()
 217
 218 if (INSTALL_CUDART_LIB) #can be set manual by user
 219     if (GMX_GPU)
 220         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 221             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 222             if(IS_CUDART) #libcuda should not be installed
 223                 #install also name-links (linker uses those)
 224                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 225                 install(FILES ${CUDA_LIBS} DESTINATION
 226                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 227             endif()
 228         endforeach()
 229     else()
 230         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 231     endif()
 232 endif()