python_packaging/src/external/pybind/tools/pybind11Config.cmake.in

   1 # pybind11Config.cmake
   2 # --------------------
   3 #
   4 # PYBIND11 cmake module.
   5 # This module sets the following variables in your project::
   6 #
   7 #   pybind11_FOUND - true if pybind11 and all required components found on the system
   8 #   pybind11_VERSION - pybind11 version in format Major.Minor.Release
   9 #   pybind11_INCLUDE_DIRS - Directories where pybind11 and python headers are located.
  10 #   pybind11_INCLUDE_DIR - Directory where pybind11 headers are located.
  11 #   pybind11_DEFINITIONS - Definitions necessary to use pybind11, namely USING_pybind11.
  12 #   pybind11_LIBRARIES - compile flags and python libraries (as needed) to link against.
  13 #   pybind11_LIBRARY - empty.
  14 #   CMAKE_MODULE_PATH - appends location of accompanying FindPythonLibsNew.cmake and
  15 #                       pybind11Tools.cmake modules.
  16 #
  17 #
  18 # Available components: None
  19 #
  20 #
  21 # Exported targets::
  22 #
  23 # If pybind11 is found, this module defines the following :prop_tgt:`IMPORTED`
  24 # interface library targets::
  25 #
  26 #   pybind11::module - for extension modules
  27 #   pybind11::embed - for embedding the Python interpreter
  28 #
  29 # Python headers, libraries (as needed by platform), and the C++ standard
  30 # are attached to the target. Set PythonLibsNew variables to influence
  31 # python detection and PYBIND11_CPP_STANDARD (-std=c++11 or -std=c++14) to
  32 # influence standard setting. ::
  33 #
  34 #   find_package(pybind11 CONFIG REQUIRED)
  35 #   message(STATUS "Found pybind11 v${pybind11_VERSION}: ${pybind11_INCLUDE_DIRS}")
  36 #
  37 #   # Create an extension module
  38 #   add_library(mylib MODULE main.cpp)
  39 #   target_link_libraries(mylib pybind11::module)
  40 #
  41 #   # Or embed the Python interpreter into an executable
  42 #   add_executable(myexe main.cpp)
  43 #   target_link_libraries(myexe pybind11::embed)
  44 #
  45 # Suggested usage::
  46 #
  47 # find_package with version info is not recommended except for release versions. ::
  48 #
  49 #   find_package(pybind11 CONFIG)
  50 #   find_package(pybind11 2.0 EXACT CONFIG REQUIRED)
  51 #
  52 #
  53 # The following variables can be set to guide the search for this package::
  54 #
  55 #   pybind11_DIR - CMake variable, set to directory containing this Config file
  56 #   CMAKE_PREFIX_PATH - CMake variable, set to root directory of this package
  57 #   PATH - environment variable, set to bin directory of this package
  58 #   CMAKE_DISABLE_FIND_PACKAGE_pybind11 - CMake variable, disables
  59 #     find_package(pybind11) when not REQUIRED, perhaps to force internal build
  60
  61 @PACKAGE_INIT@
  62
  63 set(PN pybind11)
  64
  65 # location of pybind11/pybind11.h
  66 set(${PN}_INCLUDE_DIR "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@")
  67
  68 set(${PN}_LIBRARY "")
  69 set(${PN}_DEFINITIONS USING_${PN})
  70
  71 check_required_components(${PN})
  72
  73 # make detectable the FindPythonLibsNew.cmake module
  74 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
  75
  76 include(pybind11Tools)
  77
  78 if(NOT (CMAKE_VERSION VERSION_LESS 3.0))
  79 #-----------------------------------------------------------------------------
  80 # Don't include targets if this file is being picked up by another
  81 # project which has already built this as a subproject
  82 #-----------------------------------------------------------------------------
  83 if(NOT TARGET ${PN}::pybind11)
  84     include("${CMAKE_CURRENT_LIST_DIR}/${PN}Targets.cmake")
  85
  86     find_package(PythonLibsNew ${PYBIND11_PYTHON_VERSION} MODULE REQUIRED)
  87     set_property(TARGET ${PN}::pybind11 APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${PYTHON_INCLUDE_DIRS})
  88     set_property(TARGET ${PN}::embed APPEND PROPERTY INTERFACE_LINK_LIBRARIES ${PYTHON_LIBRARIES})
  89     if(WIN32 OR CYGWIN)
  90       set_property(TARGET ${PN}::module APPEND PROPERTY INTERFACE_LINK_LIBRARIES ${PYTHON_LIBRARIES})
  91     endif()
  92
  93     if(CMAKE_VERSION VERSION_LESS 3.3)
  94       set_property(TARGET ${PN}::pybind11 APPEND PROPERTY INTERFACE_COMPILE_OPTIONS "${PYBIND11_CPP_STANDARD}")
  95     else()
  96       set_property(TARGET ${PN}::pybind11 APPEND PROPERTY INTERFACE_COMPILE_OPTIONS $<$<COMPILE_LANGUAGE:CXX>:${PYBIND11_CPP_STANDARD}>)
  97     endif()
  98
  99     get_property(_iid TARGET ${PN}::pybind11 PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
 100     get_property(_ill TARGET ${PN}::module PROPERTY INTERFACE_LINK_LIBRARIES)
 101     set(${PN}_INCLUDE_DIRS ${_iid})
 102     set(${PN}_LIBRARIES ${_ico} ${_ill})
 103 endif()
 104 endif()