python_packaging/src/external/pybind/CMakeLists.txt

   1 # CMakeLists.txt -- Build system for the pybind11 modules
   2 #
   3 # Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
   4 #
   5 # All rights reserved. Use of this source code is governed by a
   6 # BSD-style license that can be found in the LICENSE file.
   7
   8 cmake_minimum_required(VERSION 2.8.12)
   9
  10 if (POLICY CMP0048)
  11   # cmake warns if loaded from a min-3.0-required parent dir, so silence the warning:
  12   cmake_policy(SET CMP0048 NEW)
  13 endif()
  14
  15 # CMake versions < 3.4.0 do not support try_compile/pthread checks without C as active language.
  16 if(CMAKE_VERSION VERSION_LESS 3.4.0)
  17   project(pybind11)
  18 else()
  19   project(pybind11 CXX)
  20 endif()
  21
  22 # Check if pybind11 is being used directly or via add_subdirectory
  23 set(PYBIND11_MASTER_PROJECT OFF)
  24 if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
  25   set(PYBIND11_MASTER_PROJECT ON)
  26 endif()
  27
  28 option(PYBIND11_INSTALL "Install pybind11 header files?" ${PYBIND11_MASTER_PROJECT})
  29 option(PYBIND11_TEST    "Build pybind11 test suite?"     ${PYBIND11_MASTER_PROJECT})
  30
  31 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/tools")
  32
  33 include(pybind11Tools)
  34
  35 # Cache variables so pybind11_add_module can be used in parent projects
  36 set(PYBIND11_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}/include" CACHE INTERNAL "")
  37 set(PYTHON_INCLUDE_DIRS ${PYTHON_INCLUDE_DIRS} CACHE INTERNAL "")
  38 set(PYTHON_LIBRARIES ${PYTHON_LIBRARIES} CACHE INTERNAL "")
  39 set(PYTHON_MODULE_PREFIX ${PYTHON_MODULE_PREFIX} CACHE INTERNAL "")
  40 set(PYTHON_MODULE_EXTENSION ${PYTHON_MODULE_EXTENSION} CACHE INTERNAL "")
  41 set(PYTHON_VERSION_MAJOR ${PYTHON_VERSION_MAJOR} CACHE INTERNAL "")
  42 set(PYTHON_VERSION_MINOR ${PYTHON_VERSION_MINOR} CACHE INTERNAL "")
  43
  44 # NB: when adding a header don't forget to also add it to setup.py
  45 set(PYBIND11_HEADERS
  46   include/pybind11/detail/class.h
  47   include/pybind11/detail/common.h
  48   include/pybind11/detail/descr.h
  49   include/pybind11/detail/init.h
  50   include/pybind11/detail/internals.h
  51   include/pybind11/detail/typeid.h
  52   include/pybind11/attr.h
  53   include/pybind11/buffer_info.h
  54   include/pybind11/cast.h
  55   include/pybind11/chrono.h
  56   include/pybind11/common.h
  57   include/pybind11/complex.h
  58   include/pybind11/options.h
  59   include/pybind11/eigen.h
  60   include/pybind11/embed.h
  61   include/pybind11/eval.h
  62   include/pybind11/functional.h
  63   include/pybind11/numpy.h
  64   include/pybind11/operators.h
  65   include/pybind11/pybind11.h
  66   include/pybind11/pytypes.h
  67   include/pybind11/stl.h
  68   include/pybind11/stl_bind.h
  69 )
  70 string(REPLACE "include/" "${CMAKE_CURRENT_SOURCE_DIR}/include/"
  71        PYBIND11_HEADERS "${PYBIND11_HEADERS}")
  72
  73 if (PYBIND11_TEST)
  74   add_subdirectory(tests)
  75 endif()
  76
  77 include(GNUInstallDirs)
  78 include(CMakePackageConfigHelpers)
  79
  80 # extract project version from source
  81 file(STRINGS "${PYBIND11_INCLUDE_DIR}/pybind11/detail/common.h" pybind11_version_defines
  82      REGEX "#define PYBIND11_VERSION_(MAJOR|MINOR|PATCH) ")
  83 foreach(ver ${pybind11_version_defines})
  84   if (ver MATCHES "#define PYBIND11_VERSION_(MAJOR|MINOR|PATCH) +([^ ]+)$")
  85     set(PYBIND11_VERSION_${CMAKE_MATCH_1} "${CMAKE_MATCH_2}" CACHE INTERNAL "")
  86   endif()
  87 endforeach()
  88 set(${PROJECT_NAME}_VERSION ${PYBIND11_VERSION_MAJOR}.${PYBIND11_VERSION_MINOR}.${PYBIND11_VERSION_PATCH})
  89 message(STATUS "pybind11 v${${PROJECT_NAME}_VERSION}")
  90
  91 option (USE_PYTHON_INCLUDE_DIR "Install pybind11 headers in Python include directory instead of default installation prefix" OFF)
  92 if (USE_PYTHON_INCLUDE_DIR)
  93     file(RELATIVE_PATH CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX} ${PYTHON_INCLUDE_DIRS})
  94 endif()
  95
  96 if(NOT (CMAKE_VERSION VERSION_LESS 3.0))  # CMake >= 3.0
  97   # Build an interface library target:
  98   add_library(pybind11 INTERFACE)
  99   add_library(pybind11::pybind11 ALIAS pybind11)  # to match exported target
 100   target_include_directories(pybind11 INTERFACE $<BUILD_INTERFACE:${PYBIND11_INCLUDE_DIR}>
 101                                                 $<BUILD_INTERFACE:${PYTHON_INCLUDE_DIRS}>
 102                                                 $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
 103   target_compile_options(pybind11 INTERFACE $<BUILD_INTERFACE:${PYBIND11_CPP_STANDARD}>)
 104
 105   add_library(module INTERFACE)
 106   add_library(pybind11::module ALIAS module)
 107   if(NOT MSVC)
 108     target_compile_options(module INTERFACE -fvisibility=hidden)
 109   endif()
 110   target_link_libraries(module INTERFACE pybind11::pybind11)
 111   if(WIN32 OR CYGWIN)
 112     target_link_libraries(module INTERFACE $<BUILD_INTERFACE:${PYTHON_LIBRARIES}>)
 113   elseif(APPLE)
 114     target_link_libraries(module INTERFACE "-undefined dynamic_lookup")
 115   endif()
 116
 117   add_library(embed INTERFACE)
 118   add_library(pybind11::embed ALIAS embed)
 119   target_link_libraries(embed INTERFACE pybind11::pybind11 $<BUILD_INTERFACE:${PYTHON_LIBRARIES}>)
 120 endif()
 121
 122 if (PYBIND11_INSTALL)
 123   install(DIRECTORY ${PYBIND11_INCLUDE_DIR}/pybind11 DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 124   # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
 125   set(PYBIND11_CMAKECONFIG_INSTALL_DIR "share/cmake/${PROJECT_NAME}" CACHE STRING "install path for pybind11Config.cmake")
 126
 127   configure_package_config_file(tools/${PROJECT_NAME}Config.cmake.in
 128                                 "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
 129                                 INSTALL_DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
 130   # Remove CMAKE_SIZEOF_VOID_P from ConfigVersion.cmake since the library does
 131   # not depend on architecture specific settings or libraries.
 132   set(_PYBIND11_CMAKE_SIZEOF_VOID_P ${CMAKE_SIZEOF_VOID_P})
 133   unset(CMAKE_SIZEOF_VOID_P)
 134   write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
 135                                    VERSION ${${PROJECT_NAME}_VERSION}
 136                                    COMPATIBILITY AnyNewerVersion)
 137   set(CMAKE_SIZEOF_VOID_P ${_PYBIND11_CMAKE_SIZEOF_VOID_P})
 138   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
 139                 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
 140                 tools/FindPythonLibsNew.cmake
 141                 tools/pybind11Tools.cmake
 142           DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
 143
 144   if(NOT (CMAKE_VERSION VERSION_LESS 3.0))
 145     if(NOT PYBIND11_EXPORT_NAME)
 146       set(PYBIND11_EXPORT_NAME "${PROJECT_NAME}Targets")
 147     endif()
 148
 149     install(TARGETS pybind11 module embed
 150             EXPORT "${PYBIND11_EXPORT_NAME}")
 151     if(PYBIND11_MASTER_PROJECT)
 152       install(EXPORT "${PYBIND11_EXPORT_NAME}"
 153               NAMESPACE "${PROJECT_NAME}::"
 154               DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
 155     endif()
 156   endif()
 157 endif()