docs/old-html/BuildHtmlHelp.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 if (NOT DEFINED GMX_EXECUTABLE OR NOT DEFINED OUTPUT_DIR OR NOT DEFINED SOURCE_HTML_DIR)
  36     message(FATAL_ERROR "Required input parameter not set")
  37 endif()
  38
  39 file(MAKE_DIRECTORY ${OUTPUT_DIR})
  40 file(MAKE_DIRECTORY ${OUTPUT_DIR}/programs)
  41 file(COPY ${SOURCE_HTML_DIR}/header.html.in DESTINATION .)
  42 file(COPY ${SOURCE_HTML_DIR}/footer.html DESTINATION .)
  43 file(COPY ${SOURCE_HTML_DIR}/links.dat   DESTINATION .)
  44
  45 # This is generated by gmx help -export html
  46 set(HEADER_FILE header.html)
  47
  48 execute_process(
  49     COMMAND ${GMX_EXECUTABLE} -quiet help -export html
  50     RESULT_VARIABLE exitcode)
  51 if (exitcode)
  52     # Ensure that no partial output is left behind.
  53     file(REMOVE_RECURSE ${OUTPUT_DIR})
  54     file(REMOVE ${HEADER_FILE})
  55     message(FATAL_ERROR
  56         "Failed to generate HTML help. "
  57         "Set GMX_BUILD_HELP=OFF or GMX_BUILD_HELP=AUTO if you want to skip them.\n"
  58         "Error/exit code: ${exitcode}")
  59 endif()
  60
  61 set(FOOTER_FILE ${SOURCE_HTML_DIR}/footer.html)
  62 file(READ ${HEADER_FILE} HEADER_TEXT)
  63 file(READ ${FOOTER_FILE} FOOTER_TEXT)
  64 set(_title_re "[Tt][Ii][Tt][Ll][Ee]")
  65
  66 function(CREATE_HTML_FILE SOURCE_FILE ROOTPATH)
  67     file(RELATIVE_PATH _rel_path ${SOURCE_HTML_DIR} ${SOURCE_FILE})
  68     file(READ ${SOURCE_FILE} _content)
  69     string(REGEX REPLACE "^ *<${_title_re}>(.*)</${_title_re}>\n" "" _content "${_content}")
  70     set(TITLE "${CMAKE_MATCH_1}")
  71     string(CONFIGURE "${HEADER_TEXT}" _header @ONLY)
  72     set(_content "${_header}${_content}${FOOTER_TEXT}")
  73     file(WRITE ${OUTPUT_DIR}/${_rel_path} "${_content}")
  74 endfunction()
  75
  76 create_html_file(${SOURCE_HTML_DIR}/online.html "")
  77 file(COPY ${SOURCE_HTML_DIR}/images DESTINATION ${OUTPUT_DIR})
  78 file(MAKE_DIRECTORY ${OUTPUT_DIR}/online)
  79 file(COPY ${SOURCE_HTML_DIR}/online/style.css DESTINATION ${OUTPUT_DIR}/online)
  80 file(GLOB _source_files ${SOURCE_HTML_DIR}/online/*.html)
  81 foreach(_file ${_source_files})
  82     create_html_file(${_file} "../")
  83 endforeach()