cmake/gmxVersionInfo.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Sets version information variables and provides CMake functions for
  36 # generating files based on them
  37 #
  38 # This script provides the following basic version variables that need to be
  39 # maintained manually:
  40 #   GMX_VERSION_MAJOR      Major version number.
  41 #   GMX_VERSION_MINOR      Minor version number.
  42 #   GMX_VERSION_PATCH      Patch version number.
  43 #       Should always be defined: zero for, e.g., 5.0.
  44 #   GMX_VERSION_SUFFIX     String suffix to add to numeric version string.
  45 #       "-dev" is automatically added when not building from a source package,
  46 #       and does not need to be kept here.
  47 #   LIBRARY_SOVERSION      so version for the built libraries.
  48 #       Should be increased for each binary incompatible release (in GROMACS,
  49 #       the typical policy is to increase it for each major/minor version
  50 #       change, but not for patch releases, even if the latter may not always
  51 #       be fully binary compatible).
  52 #   LIBRARY_VERSION        Full library version.
  53 #   REGRESSIONTEST_BRANCH  For builds not from source packages, name of the
  54 #       regressiontests branch at gerrit.gromacs.org whose HEAD can test this
  55 #       code, *if* this code is recent enough (i.e., contains all changes from
  56 #       the corresponding code branch that affects the regression test
  57 #       results).
  58 #   REGRESSIONTEST_MD5SUM
  59 #       The MD5 checksum of the regressiontest tarball. Only used when building
  60 #       from a source package.
  61 # They are collected into a single section below.
  62 # The following variables are set based on these:
  63 #   GMX_VERSION            String composed from GMX_VERSION_* numeric variables
  64 #       above. Example: 4.6.1, 5.0
  65 #   GMX_VERSION_STRING     String with GMX_VERSION suffixed with the given
  66 #       suffix and possibly "-dev" for builds not from a source package.
  67 #   GMX_VERSION_NUMERIC    Numeric version number (e.g., 40601 for 4.6.1).
  68 #   GMX_API_VERSION        Numeric API version.
  69 #       This is currently set automatically to GMX_VERSION_NUMERIC, but may
  70 #       become manually maintained in the future if there will be releases
  71 #       where the API does not change, but programs/libraries do.
  72 #       In such a case, this should be the first version where the current API
  73 #       appeared.
  74 #   REGRESSIONTEST_VERSION For source packages, version number of the
  75 #       matching regressiontests tarball.  Not used for builds not from source
  76 #       packages.
  77 # The latter two are used to generate gromacs/version.h to allow software
  78 # written against the GROMACS API to provide some #ifdef'ed code to support
  79 # multiple GROMACS versions.
  80 #
  81 # The following variables are defined without manual intervention:
  82 #   SOURCE_IS_SOURCE_DISTRIBUTION  The source tree is from a source tarball.
  83 #   SOURCE_IS_GIT_REPOSITORY       The source tree is a git repository.
  84 # Note that both can be false if the tree has been extracted, e.g., as a
  85 # tarball directly from git.
  86 # Additionally, the following variable is defined:
  87 #   BUILD_IS_INSOURCE              The build is happening in-source.
  88 #
  89 # This script also declares machinery to generate and obtain version
  90 # information from a git repository.  This is enabled by default if the source
  91 # tree is a git, but can be disabled with
  92 #   GMX_GIT_VERSION_INFO           Advanced CMake variable to disable git
  93 #                                  version info generation.
  94 # The main interface to this machinery is the gmx_configure_version_file()
  95 # CMake function.  The signature is
  96 #   gmx_configure_version_file(<input> <output>
  97 #                              [REMOTE_HASH] [SOURCE_FILE]
  98 #                              [TARGET <target>]
  99 #                              [COMMENT <comment>])
 100 #   <input>      Specify the input and output files as for configure_file().
 101 #   <output>     The configuration is done with configure_file(... @ONLY) with
 102 #                the following variables defined (as well as all the
 103 #                GMX_VERSION* variables from above):
 104 #                  GMX_VERSION_STRING_FULL
 105 #                  GMX_VERSION_FULL_HASH
 106 #                  GMX_VERSION_CENTRAL_BASE_HASH
 107 #                The output file is created during build time, so any dependent
 108 #                targets should specify it as a dependency.
 109 #   REMOTE_HASH  Currently, this has no effect, but it signifies that the
 110 #                <input> file is using the CENTRAL_BASE_HASH variable.
 111 #                This variable is much more expensive to initialize than the
 112 #                others, so this allows local changes in this file to only
 113 #                compute that value when required if that becomes necessary.
 114 #   SOURCE_FILE  Signals that <output> will be used as a source file.
 115 #                The function will set properties for the source file
 116 #                appropriately to signify that it is generated.
 117 #   TARGET       By default, this function uses add_custom_command() to
 118 #                generate the output file.  If TARGET is specified, then
 119 #                add_custom_target() is used to create a target with the given
 120 #                name <target> that runs this custom command.  Use this if
 121 #                the same file will be used for multiple downstream targets,
 122 #                or if the explicit target for the file is otherwise
 123 #                necessary.
 124 #   COMMENT      Set a custom comment to be shown when building the rule
 125 #                (see add_custom_command(... COMMENT <comment>)).
 126 # As an alternative to using this script, also the following variables are
 127 # provided (can be useful when generating more complex CMake scripts that do
 128 # build-time tasks):
 129 #   VERSION_INFO_CMAKE_SCRIPT
 130 #       Absolute path to a CMake script that can be included using include()
 131 #       to declare the GMX_VERSION_* variables documented for
 132 #       gmx_configure_version_file().
 133 #   VERSION_INFO_DEPS
 134 #       If a custom command depends on VERSION_INFO_CMAKE_SCRIPT, then it
 135 #       should add ${VERSION_INFO_DEPS} to its DEPENDS list to get the
 136 #       appropriate dependencies.
 137 # TODO: If someone wants to add a custom target that depends on
 138 # VERSION_INFO_CMAKE_SCRIPT, a separate variable may be needed for those
 139 # dependencies.
 140 #
 141 # The version string printed by 'gmx -version' (and also printed in the startup
 142 # header) can provide useful information for, e.g., diagnosing bug reports and
 143 # identifying what exact version the user was using.  The following formats are
 144 # possible (with examples given for a particular version):
 145 #   4.6.1       Plain version number without any suffix signifies a build from
 146 #               a released source tarball.
 147 #   4.6.1-dev   '-dev' suffix signifies all other builds. If there is no other
 148 #               information, either the user built the code outside any git
 149 #               repository, or disabled the version info generation.
 150 #   4.6.1-dev-YYYYMMDD-1234abc
 151 #               The YYYYMMDD part shows the commit date (not author date) of
 152 #               the HEAD commit from which the code was built.  The abbreviated
 153 #               hash is the hash of that commit (the full hash is available in
 154 #               'gmx -version' output).
 155 #               If the HEAD hash is not identified as coming from branches in
 156 #               "authoritative" GROMACS repositories, 'gmx -version' will show
 157 #               the nearest ancestor commit that is identified as such (but see
 158 #               the '-local' and '-unknown' suffixes below).
 159 #   4.6.1-dev-YYYYMMDD-1234abc-dirty
 160 #               As above, but there were local modifications in the source tree
 161 #               when the code was built.
 162 #   4.6.1-dev-YYYYMMDD-1234abc-unknown
 163 #               As above, but there were no remotes in the repository that
 164 #               could be identified as "authoritative" GROMACS repositories.
 165 #               This happens if the code is not cloned from git.gromacs.org
 166 #               or gerrit.gromacs.org.
 167 #   4.6.1-dev-YYYYMMDD-1234abc-local
 168 #               As above, but there were no commits in the recent history of
 169 #               the branch that could be identified as coming from
 170 #               "authoritative" GROMACS repositories.  This should be
 171 #               relatively rare.
 172 #
 173 # Other variables set here are not intended for use outside this file.
 174 # The scripts gmxGenerateVersionInfo.cmake and gmxConfigureVersionInfo.cmake
 175 # are used internally by this machinery, as well as VersionInfo.cmake.cmakein.
 176
 177 #####################################################################
 178 # Basic nature of the source tree
 179
 180 set(SOURCE_IS_GIT_REPOSITORY OFF)
 181 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 182 if (EXISTS "${PROJECT_SOURCE_DIR}/.git")
 183     set(SOURCE_IS_GIT_REPOSITORY ON)
 184 endif()
 185 # This file is excluded from CPack source packages, but part of the repository,
 186 # so it should get included everywhere else.
 187 if (NOT EXISTS "${PROJECT_SOURCE_DIR}/admin/.isreposource")
 188     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 189 endif()
 190 set(BUILD_IS_INSOURCE OFF)
 191 if ("${PROJECT_SOURCE_DIR}" STREQUAL "${PROJECT_BINARY_DIR}")
 192     set(BUILD_IS_INSOURCE ON)
 193 endif()
 194
 195 #####################################################################
 196 # Manually maintained version info
 197
 198 # The GROMACS convention is that these are the version number of the next
 199 # release that is going to be made from this branch.
 200 set(GMX_VERSION_MAJOR 5)
 201 set(GMX_VERSION_MINOR 1)
 202 set(GMX_VERSION_PATCH 0)
 203 # The suffix, on the other hand, is used mainly for betas and release
 204 # candidates, where it signifies the last such release from this branch;
 205 # it will be empty before the first such release, as well as after the
 206 # final release is out.
 207 set(GMX_VERSION_SUFFIX "")
 208
 209 set(LIBRARY_SOVERSION 1)
 210 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
 211
 212 set(REGRESSIONTEST_BRANCH "refs/heads/master")
 213 set(REGRESSIONTEST_MD5SUM "a07524afebca5013540d4f2f72df2dce")
 214
 215 #####################################################################
 216 # General version management based on manually set numbers
 217
 218 if (GMX_VERSION_PATCH)
 219     set(GMX_VERSION "${GMX_VERSION_MAJOR}.${GMX_VERSION_MINOR}.${GMX_VERSION_PATCH}")
 220 else()
 221     set(GMX_VERSION "${GMX_VERSION_MAJOR}.${GMX_VERSION_MINOR}")
 222 endif()
 223 set(GMX_VERSION_STRING "${GMX_VERSION}${GMX_VERSION_SUFFIX}")
 224 if (NOT SOURCE_IS_SOURCE_DISTRIBUTION)
 225     set(GMX_VERSION_STRING "${GMX_VERSION_STRING}-dev")
 226 endif()
 227
 228 set(REGRESSIONTEST_VERSION "${GMX_VERSION_STRING}")
 229
 230 math(EXPR GMX_VERSION_NUMERIC
 231      "${GMX_VERSION_MAJOR}*10000 + ${GMX_VERSION_MINOR}*100 + ${GMX_VERSION_PATCH}")
 232 set(GMX_API_VERSION ${NUM_VERSION})
 233
 234 #####################################################################
 235 # git version info management
 236
 237 # There can be clusters where git and CMake can run on nodes where the other is
 238 # not available, accessing the same source tree.
 239 # Should be unlikely, but doesn't hurt to check.
 240 set(_git_info_default OFF)
 241 if (SOURCE_IS_GIT_REPOSITORY)
 242     find_package(Git)
 243     if (GIT_FOUND)
 244         set(_git_info_default ON)
 245     endif()
 246 endif()
 247 option(GMX_GIT_VERSION_INFO "Generate git version information" ${_git_info_default})
 248 mark_as_advanced(GMX_GIT_VERSION_INFO)
 249 # Detect preconditions for version info generation if it is requested.
 250 if (GMX_GIT_VERSION_INFO)
 251     if (NOT SOURCE_IS_GIT_REPOSITORY)
 252         message(FATAL_ERROR
 253             "Cannot generate git version information from source tree not under git. "
 254             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 255     endif()
 256     # We need at least git v1.5.3 be able to parse git's date output.
 257     if (NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 258         message(FATAL_ERROR
 259             "No compatible git version found (>= 1.5.3 required). "
 260             "Won't be able to generate development version information. "
 261             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 262     endif()
 263 endif()
 264
 265 include(gmxCustomCommandUtilities)
 266
 267 # The first two are also for use outside this file, encapsulating the details
 268 # of how to use the generated VersionInfo.cmake.
 269 set(VERSION_INFO_CMAKE_FILE   ${PROJECT_BINARY_DIR}/VersionInfo.cmake)
 270 set(VERSION_INFO_DEPS         ${VERSION_INFO_CMAKE_FILE})
 271 # Capture the location of the necessary files in internal variables for use in
 272 # the function below.
 273 set(VERSION_INFO_CMAKEIN_FILE     ${CMAKE_CURRENT_LIST_DIR}/VersionInfo.cmake.cmakein)
 274 set(VERSION_INFO_CONFIGURE_SCRIPT ${CMAKE_CURRENT_LIST_DIR}/gmxConfigureVersionInfo.cmake)
 275
 276 # Rules to create the VersionInfo.cmake file.
 277 # For git info, the sequence is:
 278 #   1. (configure time) VersionInfo.cmake.cmakein -> VersionInfo-partial.cmake.cmakein
 279 #        - Set all variables that are known at configure time.
 280 #   2. (build time)     VersionInfo-partial.cmake.cmakein -> VersionInfo.cmake
 281 #        - Set variables that may change as result of repository state changes
 282 #          (i.e., everything that requires running git).
 283 #        - Runs every time as a git-version-info target, but the output file
 284 #          timestamp only changes if its contents actually change.
 285 #        - Depending on the native build system, this may run once per build
 286 #          or once per each time it is required for step 3.
 287 #   3. (build time)     VersionInfo.cmake -> other files
 288 #        - Set variables in files specified with gmx_configure_version_file()
 289 #          using the values generated in step 2.
 290 #        - Each file runs as a custom command that depends on the previous
 291 #          steps, and runs only if the VersionInfo.cmake file is newer than the
 292 #          output file.
 293 # Without git info, the sequence is:
 294 #  1. (configure time) VersionInfo.cmake.cmakein -> VersionInfo.cmake
 295 #        - Everything is known at configure time, so the output is generated
 296 #          immediately with all variables set (git info will be empty).
 297 #  2. (build time)     VersionInfo.cmake -> other files
 298 #        - As with git info, processes files from gmx_configure_version_file().
 299 #        - These are again custom commands that depend on the output from
 300 #          step 1, so they get regenerated only when the static version info
 301 #          changes.
 302 if (GMX_GIT_VERSION_INFO)
 303     # Configure information known at this time into a partially filled
 304     # version info file.
 305     set(VERSION_INFO_CMAKEIN_FILE_PARTIAL
 306         ${PROJECT_BINARY_DIR}/VersionInfo-partial.cmake.cmakein)
 307     # Leave these to be substituted by the custom target below.
 308     set(GMX_VERSION_STRING_FULL       "\@GMX_VERSION_STRING_FULL\@")
 309     set(GMX_VERSION_FULL_HASH         "\@GMX_VERSION_FULL_HASH\@")
 310     set(GMX_VERSION_CENTRAL_BASE_HASH "\@GMX_VERSION_CENTRAL_BASE_HASH\@")
 311     configure_file(${VERSION_INFO_CMAKEIN_FILE}
 312                    ${VERSION_INFO_CMAKEIN_FILE_PARTIAL}
 313                    @ONLY)
 314     # If generating the version info, create a target that runs on every build
 315     # and does the actual git calls, storing the results into a CMake script.
 316     # This needs to be run at build time to update the version information
 317     # properly when the git hash changes, but the build system does not.
 318     # All targets added by gmx_configure_version_file() use the information
 319     # from this script to get their variables from, removing the need to run
 320     # git multiple times and simplifying reuse for other purposes.
 321     gmx_add_custom_output_target(git-version-info RUN_ALWAYS
 322         OUTPUT ${VERSION_INFO_CMAKE_FILE}
 323         COMMAND ${CMAKE_COMMAND}
 324             -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
 325             -D PROJECT_VERSION=${GMX_VERSION_STRING}
 326             -D PROJECT_SOURCE_DIR=${PROJECT_SOURCE_DIR}
 327             -D VERSION_CMAKEIN=${VERSION_INFO_CMAKEIN_FILE_PARTIAL}
 328             -D VERSION_OUT=${VERSION_INFO_CMAKE_FILE}
 329             -P ${CMAKE_CURRENT_LIST_DIR}/gmxGenerateVersionInfo.cmake
 330         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 331         COMMENT "Generating git version information")
 332     list(APPEND VERSION_INFO_DEPS git-version-info)
 333 else()
 334     # If the version info is static, just generate the CMake script with the
 335     # version variables during the CMake run.
 336     set(GMX_VERSION_STRING_FULL       ${GMX_VERSION_STRING})
 337     set(GMX_VERSION_FULL_HASH         "")
 338     set(GMX_VERSION_CENTRAL_BASE_HASH "")
 339     configure_file(${VERSION_INFO_CMAKEIN_FILE} ${VERSION_INFO_CMAKE_FILE})
 340 endif()
 341 unset(GMX_VERSION_STRING_FULL)
 342 unset(GMX_VERSION_FULL_HASH)
 343 unset(GMX_VERSION_CENTRAL_BASE_HASH)
 344
 345 # The main user-visible interface to the machinery.
 346 # See documentation at the top of the script.
 347 function (gmx_configure_version_file INFILE OUTFILE)
 348     include(CMakeParseArguments)
 349     set(_options REMOTE_HASH SOURCE_FILE)
 350     set(_one_value_args COMMENT TARGET)
 351     cmake_parse_arguments(ARG "${_options}" "${_one_value_args}" "" ${ARGN})
 352     if (ARG_UNPARSED_ARGUMENTS)
 353         message(FATAL_ERROR "Unknown arguments: ${ARG_UNPARSED_ARGUMENTS}")
 354     endif()
 355     # Some callers may pass partial paths that do not really make sense,
 356     # so create a default comment that only contains the actual file name.
 357     get_filename_component(_basename ${OUTFILE} NAME)
 358     set(_comment "Generating ${_basename}")
 359     if (ARG_COMMENT)
 360         set(_comment ${ARG_COMMENT})
 361     endif()
 362     # Mimic configure_file()
 363     if (NOT IS_ABSOLUTE ${INFILE})
 364         set(INFILE ${CMAKE_CURRENT_SOURCE_DIR}/${INFILE})
 365     endif()
 366     # The touch command is necessary to ensure that after the target is run,
 367     # the timestamp is newer than in the input files.
 368     add_custom_command(OUTPUT ${OUTFILE}
 369         COMMAND ${CMAKE_COMMAND}
 370             -D VERSION_VARIABLES=${VERSION_INFO_CMAKE_FILE}
 371             -D VERSION_CMAKEIN=${INFILE}
 372             -D VERSION_OUT=${OUTFILE}
 373             -P ${VERSION_INFO_CONFIGURE_SCRIPT}
 374         COMMAND ${CMAKE_COMMAND} -E touch ${OUTFILE}
 375         WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 376         DEPENDS ${INFILE} ${VERSION_INFO_DEPS} ${VERSION_INFO_CONFIGURE_SCRIPT}
 377         COMMENT "${_comment}"
 378         VERBATIM)
 379     if (ARG_TARGET)
 380         add_custom_target(${ARG_TARGET} DEPENDS ${OUTFILE} VERBATIM)
 381         gmx_set_custom_target_output(${ARG_TARGET} ${OUTFILE})
 382     endif()
 383     if (ARG_SOURCE_FILE)
 384         set_source_files_properties(${OUTFILE} PROPERTIES GENERATED true)
 385     endif()
 386 endfunction()