cmake/gmxManageMPI.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage the MPI setup, assuming that CMAKE_C_COMPILER is an MPI
  36 # (wrapper) compiler.
  37 if(GMX_MPI)
  38   if(GMX_THREAD_MPI)
  39     message(STATUS "MPI is not compatible with thread-MPI. Disabling thread-MPI.")
  40     set(GMX_THREAD_MPI OFF CACHE BOOL
  41         "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" FORCE)
  42   endif()
  43
  44   # Test the CMAKE_C_COMPILER for being an MPI (wrapper) compiler
  45   TRY_COMPILE(MPI_FOUND ${CMAKE_BINARY_DIR}
  46     "${CMAKE_SOURCE_DIR}/cmake/TestMPI.c"
  47     COMPILE_DEFINITIONS )
  48
  49   # If CMAKE_C_COMPILER is not a MPI wrapper. Try to find MPI using cmake module as fall-back.
  50   if(NOT MPI_FOUND)
  51       set(MPI_PREFIX MPI_C)
  52       find_package(MPI)
  53       if(${${MPI_PREFIX}_FOUND})
  54         set(MPI_COMPILE_FLAGS ${${MPI_PREFIX}_COMPILE_FLAGS})
  55         set(MPI_LINKER_FLAGS ${${MPI_PREFIX}_LINK_FLAGS})
  56         include_directories(${${MPI_PREFIX}_INCLUDE_PATH})
  57         list(APPEND GMX_EXTRA_LIBRARIES ${${MPI_PREFIX}_LIBRARIES})
  58       endif()
  59       set(MPI_FOUND ${${MPI_PREFIX}_FOUND})
  60   endif()
  61
  62   if(MPI_FOUND)
  63     include(gmxTestMPI_IN_PLACE)
  64     if (GMX_MPI_IN_PLACE)
  65       gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  66     endif()
  67
  68     # Find path of the mpi compilers
  69     if (${${MPI_PREFIX}_FOUND})
  70         get_filename_component(_mpi_c_compiler_path "${MPI_C_COMPILER}" PATH)
  71         get_filename_component(_mpiexec_path "${MPIEXEC}" PATH)
  72     else()
  73         get_filename_component(_cmake_c_compiler_path "${CMAKE_C_COMPILER}" PATH)
  74         get_filename_component(_cmake_cxx_compiler_path "${CMAKE_CXX_COMPILER}" PATH)
  75     endif()
  76
  77     # Test for and warn about unsuitable MPI versions
  78     #
  79     # Execute the ompi_info binary with the full path of the compiler wrapper
  80     # found, otherwise we run the risk of false positives.
  81     find_file(MPI_INFO_BIN ompi_info
  82               HINTS ${_mpi_c_compiler_path} ${_mpiexec_path}
  83                     ${_cmake_c_compiler_path} ${_cmake_cxx_compiler_path}
  84               NO_DEFAULT_PATH
  85               NO_SYSTEM_ENVIRONMENT_PATH
  86               NO_CMAKE_SYSTEM_PATH)
  87     if (MPI_INFO_BIN)
  88       exec_program(${MPI_INFO_BIN}
  89         ARGS -v ompi full
  90         OUTPUT_VARIABLE OPENMPI_TYPE
  91         RETURN_VALUE OPENMPI_EXEC_RETURN)
  92       if(OPENMPI_EXEC_RETURN EQUAL 0)
  93         string(REGEX REPLACE ".*Open MPI: \([0-9]+\\.[0-9]*\\.?[0-9]*\).*" "\\1" OPENMPI_VERSION ${OPENMPI_TYPE})
  94         if(OPENMPI_VERSION VERSION_LESS "1.4.1")
  95           MESSAGE(WARNING
  96              "CMake found OpenMPI version ${OPENMPI_VERSION} on your system. "
  97              "There are known problems with GROMACS and OpenMPI version < 1.4.1. "
  98              "Please consider updating your OpenMPI if your MPI wrapper compilers "
  99              "are using the above OpenMPI version.")
 100         endif()
 101         unset(OPENMPI_VERSION)
 102         unset(OPENMPI_TYPE)
 103         unset(OPENMPI_EXEC_RETURN)
 104       endif()
 105     endif()
 106     unset(MPI_INFO_BIN CACHE)
 107
 108     # Execute the mpiname binary with the full path of the compiler wrapper
 109     # found, otherwise we run the risk of false positives.
 110     find_file(MPINAME_BIN mpiname
 111               HINTS ${_mpi_c_compiler_path}
 112                     ${_cmake_c_compiler_path} ${_cmake_cxx_compiler_path}
 113               NO_DEFAULT_PATH
 114               NO_SYSTEM_ENVIRONMENT_PATH
 115               NO_CMAKE_SYSTEM_PATH)
 116     if (MPINAME_BIN)
 117       exec_program(${MPINAME_BIN}
 118         ARGS -n -v
 119         OUTPUT_VARIABLE MVAPICH2_TYPE
 120         RETURN_VALUE MVAPICH2_EXEC_RETURN)
 121       if(MVAPICH2_EXEC_RETURN EQUAL 0)
 122         string(REGEX MATCH "MVAPICH2" MVAPICH2_NAME ${MVAPICH2_TYPE})
 123         # Want to check for MVAPICH2 in case some other library supplies mpiname
 124         string(REGEX REPLACE "MVAPICH2 \([0-9]+\\.[0-9]*[a-z]?\\.?[0-9]*\)" "\\1" MVAPICH2_VERSION ${MVAPICH2_TYPE})
 125         if(${MVAPICH2_NAME} STREQUAL "MVAPICH2" AND MVAPICH2_VERSION VERSION_LESS "1.5")
 126           # This test works correctly even with 1.5a1
 127           MESSAGE(WARNING
 128              "CMake found MVAPICH2 version ${MVAPICH2_VERSION} on your system. "
 129              "There are known problems with GROMACS and MVAPICH2 version < 1.5. "
 130              "Please consider updating your MVAPICH2 if your MPI wrapper compilers "
 131              "are using the above MVAPICH2 version.")
 132        endif()
 133        unset(MVAPICH2_VERSION)
 134        unset(MVAPICH2_NAME)
 135        unset(MVAPICH2_TYPE)
 136        unset(MVAPICH2_EXEC_RETURN)
 137       endif()
 138     endif()
 139     unset(MPINAME_BIN CACHE)
 140
 141     # Using find_file() runs the CMake standard module
 142     # GetPrerequisites.cmake, which adds the file_cmd
 143     # variable to the top-level CMake namespace. This is
 144     # fixed in CMake 2.8.10. Meanwhile, clean up for it.
 145     if(CMAKE_VERSION VERSION_LESS "2.8.10")
 146         mark_as_advanced(file_cmd)
 147     endif()
 148
 149   else()
 150       message(FATAL_ERROR
 151         "MPI support requested, but no MPI compiler found. Either set the "
 152         "C-compiler (CMAKE_C_COMPILER) to the MPI compiler (often called mpicc), "
 153         "or set the variables reported missing for MPI_C above.")
 154   endif()
 155
 156   include(gmxTestCatamount)
 157   gmx_test_catamount(GMX_CRAY_CATAMOUNT)
 158   if(GMX_CRAY_CATAMOUNT)
 159     set(GMX_NO_SYSTEM 1)
 160     set(GMX_NO_NICE 1)
 161     set(HAVE_PWD_H 0)
 162   endif()
 163
 164   set(GMX_LIB_MPI 1)
 165 endif()