cmake/gmxManageFFTLibraries.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016 by the GROMACS development team.
   5 # Copyright (c) 2017,2018,2019,2020,2021, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # Manage setup of the different FFT libraries we can use in Gromacs.
  37 set(PKG_FFT "")
  38 set(PKG_FFT_LIBS "")
  39 # Intel 11 and up makes life somewhat easy if you just want to use
  40 # all their stuff. It's not easy if you only want some of their
  41 # stuff...
  42 set(MKL_MANUALLY FALSE)
  43 if (GMX_FFT_LIBRARY STREQUAL "MKL" AND NOT GMX_INTEL_LLVM)
  44     # The user will have to provide the set of magic libraries in
  45     # MKL_LIBRARIES (see below), which we cache (non-advanced), so that they
  46     # don't have to keep specifying it, and can easily see that
  47     # CMake is still using that information.
  48     set(MKL_MANUALLY TRUE)
  49 endif()
  50 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
  51 gmx_dependent_cache_variable(
  52     MKL_LIBRARIES
  53     "List of libraries for linking to MKL. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}"
  54     STRING ""
  55     MKL_MANUALLY)
  56 gmx_dependent_cache_variable(
  57     MKL_INCLUDE_DIR
  58     "Path to mkl.h (non-inclusive)."
  59     PATH ""
  60     MKL_MANUALLY)
  61 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
  62     # ${FFTW} must be in upper case
  63     if(GMX_DOUBLE)
  64         set(FFTW "FFTW")
  65     else()
  66         set(FFTW "FFTWF")
  67     endif()
  68
  69     if(GMX_BUILD_OWN_FFTW)
  70
  71         if(MSVC)
  72             message(FATAL_ERROR "Cannot build FFTW3 automatically (GMX_BUILD_OWN_FFTW=ON) in Visual Studio")
  73         endif()
  74         if(CMAKE_GENERATOR STREQUAL "Ninja")
  75             message(FATAL_ERROR "Cannot build FFTW3 automatically (GMX_BUILD_OWN_FFTW=ON) with ninja")
  76         endif()
  77
  78         add_subdirectory(src/external/build-fftw)
  79         include_directories(BEFORE ${${FFTW}_INCLUDE_DIRS})
  80         # libgmxfftw is always built static, so libgromacs does not
  81         # have a dependency on anything, so PKG_FFT should be empty
  82         set(PKG_FFT "")
  83         set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3 build managed by GROMACS")
  84     else()
  85         string(TOLOWER "${FFTW}" LOWERFFTW)
  86         find_package(FFTW COMPONENTS ${LOWERFFTW})
  87
  88         if(NOT ${FFTW}_FOUND)
  89             MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for mixed-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON), or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
  90         endif()
  91
  92         set(PKG_FFT "${${FFTW}_PKG}")
  93         include_directories(SYSTEM ${${FFTW}_INCLUDE_DIRS})
  94
  95         if(NOT WIN32) # Detection doesn't work on Windows
  96           if ((${GMX_SIMD_ACTIVE} MATCHES "SSE" OR ${GMX_SIMD_ACTIVE} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
  97               set(FFT_WARNING_MESSAGE "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
  98           else()
  99               if(${GMX_SIMD_ACTIVE} MATCHES "AVX" AND NOT (${FFTW}_HAVE_SSE OR ${FFTW}_HAVE_SSE2))
 100                   # If we end up here we have an AVX Gromacs build, and
 101                   # FFTW with SIMD.
 102                   set(FFT_WARNING_MESSAGE "The FFTW library was compiled with neither --enable-sse nor --enable-sse2; those would have enabled SSE(2) SIMD instructions. This will give suboptimal performance. You should (re)compile the FFTW library with --enable-sse2 and --enable-avx (and --enable-avx2 or --enable-avx512 if supported).")
 103               endif()
 104           endif()
 105         endif()
 106
 107         find_path(ARMPL_INCLUDE_DIR "armpl.h" HINTS ${${FFTW}_INCLUDE_DIRS}
 108             NO_DEFAULT_PATH
 109             NO_CMAKE_ENVIRONMENT_PATH
 110             NO_CMAKE_PATH
 111             NO_SYSTEM_ENVIRONMENT_PATH
 112             NO_CMAKE_SYSTEM_PATH)
 113         mark_as_advanced(ARMPL_INCLUDE_DIR)
 114         if (ARMPL_INCLUDE_DIR)
 115             set(GMX_FFT_ARMPL_FFTW3 1)
 116             set(FFT_STATUS_MESSAGE "Using external FFT library - ARM Performance Library (FFTW3 compatibility mode)")
 117         else()
 118             set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3")
 119         endif()
 120     endif()
 121     if (NOT GMX_FFT_ARMPL_FFTW3)
 122         set(GMX_FFT_FFTW3 1)
 123     endif()
 124
 125     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 126 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 127     # Intel compilers make life somewhat easy if you just want to use
 128     # all their stuff. It's not easy if you only want some of their
 129     # stuff...
 130     if (NOT MKL_MANUALLY)
 131         # The next line takes care of everything for MKL
 132         if (WIN32)
 133             # This works according to the Intel MKL 10.3 for Windows
 134             # docs, but on Jenkins Win2k8, icl tries to interpret it
 135             # as a file. Shrug.
 136             set(FFT_LINKER_FLAGS "/Qmkl:sequential")
 137         elseif(GMX_INTEL_LLVM AND GMX_INTEL_LLVM_VERSION GREATER_EQUAL 2021020)
 138             set(FFT_LINKER_FLAGS "-qmkl=sequential")
 139         else()
 140             set(FFT_LINKER_FLAGS "-mkl=sequential")
 141         endif()
 142         # Some versions of icc require this in order that mkl.h can be
 143         # found at compile time.
 144         list(APPEND EXTRA_C_FLAGS ${FFT_LINKER_FLAGS})
 145         list(APPEND EXTRA_CXX_FLAGS ${FFT_LINKER_FLAGS})
 146
 147         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 148     else()
 149         include_directories(SYSTEM ${MKL_INCLUDE_DIR})
 150         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 151         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system: ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 152         # Convert the semi-colon separated list to a list of
 153         # command-line linker arguments so that code using our
 154         # pkgconfig setup can use it.
 155         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 156     endif()
 157
 158     # Check MKL works. If we were in a non-global scope, we wouldn't
 159     # have to play nicely.
 160     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 161     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 162     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 163     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 164
 165     check_function_exists(DftiCreateDescriptor TEST_MKL)
 166
 167     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 168     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 169
 170     if(NOT TEST_MKL)
 171         # Hack to help the user vary MKL settings until they work.
 172         # TODO Make this logic more useful.
 173         unset(TEST_MKL CACHE)
 174         message(FATAL_ERROR "Linking with MKL was requested, but was not successful: ${MKL_ERROR_MESSAGE}")
 175     endif()
 176
 177     # Set variables to signal that we have MKL available and should use it for FFTs.
 178     set(GMX_FFT_MKL 1)
 179     set(HAVE_LIBMKL 1)
 180
 181     set(FFT_STATUS_MESSAGE "Using external FFT library - Intel MKL")
 182 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 183     set(GMX_FFT_FFTPACK 1)
 184     set(FFT_STATUS_MESSAGE "Using internal FFT library - fftpack")
 185 else()
 186     gmx_invalid_option_value(GMX_FFT_LIBRARY)
 187 endif()
 188 gmx_check_if_changed(FFT_CHANGED GMX_FFT_LIBRARY)
 189 if (FFT_CHANGED)
 190     if(FFT_WARNING_MESSAGE)
 191         message(WARNING "${FFT_WARNING_MESSAGE}")
 192     endif()
 193     message(STATUS "${FFT_STATUS_MESSAGE}")
 194 endif()
 195
 196 # enable threaded fftw3 if we've found it
 197 if(FFTW3_THREADS OR FFTW3F_THREADS)
 198     add_definitions(-DFFT5D_FFTW_THREADS)
 199 endif()
 200