cmake/gmxDetectSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Check the username performing the build, as well as date and time
  36 #
  37 # gmx_detect_simd(GMX_SUGGESTED_SIMD)
  38 #
  39 # Try to detect CPU information and suggest SIMD instructions
  40 # (such as SSE/AVX) that fits the current CPU. These functions assume
  41 # that gmx_detect_target_architecture() has already been run, so that
  42 # things like GMX_TARGET_X86 are already available.
  43 #
  44 # Sets ${GMX_SUGGESTED_SIMD} in the parent scope if
  45 # GMX_SIMD is not set (e.g. by the user, or a previous run
  46 # of CMake).
  47 #
  48
  49 # we rely on inline asm support for GNU!
  50 include(gmxTestInlineASM)
  51
  52 function(gmx_suggest_x86_simd _suggested_simd)
  53
  54     gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
  55
  56     if(GMX_X86_GCC_INLINE_ASM)
  57         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM")
  58     else()
  59         set(GCC_INLINE_ASM_DEFINE "")
  60     endif()
  61
  62     message(STATUS "Detecting best SIMD instructions for this CPU")
  63
  64     # Get CPU SIMD properties information
  65     set(_compile_definitions "${GCC_INLINE_ASM_DEFINE} -I${CMAKE_SOURCE_DIR}/src -DGMX_CPUID_STANDALONE")
  66     if(GMX_TARGET_X86)
  67         set(_compile_definitions "${_compile_definitions} -DGMX_TARGET_X86")
  68     endif()
  69     try_run(GMX_CPUID_RUN_SIMD GMX_CPUID_COMPILED
  70             ${CMAKE_BINARY_DIR}
  71             ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/gmx_cpuid.c
  72             COMPILE_DEFINITIONS ${_compile_definitions}
  73             RUN_OUTPUT_VARIABLE OUTPUT_TMP
  74             COMPILE_OUTPUT_VARIABLE GMX_CPUID_COMPILE_OUTPUT
  75             ARGS "-simd")
  76
  77     if(NOT GMX_CPUID_COMPILED)
  78         message(WARNING "Cannot compile CPUID code, which means no SIMD instructions.")
  79         message(STATUS "Compile output: ${GMX_CPUID_COMPILE_OUTPUT}")
  80         set(OUTPUT_TMP "None")
  81     elseif(NOT GMX_CPUID_RUN_SIMD EQUAL 0)
  82         message(WARNING "Cannot run CPUID code, which means no SIMD instructions.")
  83         message(STATUS "Run output: ${OUTPUT_TMP}")
  84         set(OUTPUT_TMP "None")
  85     endif(NOT GMX_CPUID_COMPILED)
  86
  87     string(STRIP "${OUTPUT_TMP}" OUTPUT_SIMD)
  88
  89     set(${_suggested_simd} "${OUTPUT_SIMD}" PARENT_SCOPE)
  90     message(STATUS "Detected best SIMD instructions for this CPU - ${OUTPUT_SIMD}")
  91 endfunction()
  92
  93 function(gmx_detect_simd _suggested_simd)
  94     if(NOT DEFINED GMX_SIMD)
  95         if(GMX_TARGET_BGQ)
  96             set(${_suggested_simd} "IBM_QPX")
  97         elseif(GMX_TARGET_FUJITSU_SPARC64)
  98             # HPC-ACE is always present. In the future we
  99             # should add detection for HPC-ACE2 here.
 100             set(${_suggested_simd} "Sparc64_HPC_ACE")
 101         elseif(GMX_TARGET_X86)
 102             gmx_suggest_x86_simd(${_suggested_simd})
 103         else()
 104             set(${_suggested_simd} "None")
 105         endif()
 106
 107         set(${_suggested_simd} ${${_suggested_simd}} PARENT_SCOPE)
 108     endif()
 109 endfunction()