cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Currently unused, but we plan to use -Wno-array-bounds
  72         # in Release to work around gcc-4.8 being a little too vocal
  73         # about some perfectly good code, while using RelWithAssert
  74         # (ie. without that suppression) in Jenkins.
  75         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  76
  77         # Modify the real CMake variables for compiler flags for all
  78         # builds and language types, and also those common to all
  79         # build types.
  80         foreach(build_type "" ${build_types_with_explicit_flags})
  81             if("${build_type}" STREQUAL "")
  82                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  83             else()
  84                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  85             endif()
  86
  87             # Append to the variables for the given build type for
  88             # each language, in the parent scope. We add our new variables at the end, so
  89             # compiler-specific choices are more likely to override default CMake choices.
  90             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  91             # set of our optimization flags detected in this file, rather than having -O2 override them.
  92             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  93                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  94                 PARENT_SCOPE)
  95         endforeach()
  96     endforeach()
  97 endfunction()
  98
  99 # This is the actual exported function to be called
 100 MACRO(gmx_c_flags)
 101
 102     include(CheckCCompilerFlag)
 103     include(CheckCXXCompilerFlag)
 104
 105     # gcc
 106     if(CMAKE_COMPILER_IS_GNUCC)
 107         #flags are added in reverse order and -Wno* need to appear after -Wall
 108         if(NOT GMX_OPENMP)
 109             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 110         endif()
 111         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 112         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 113         # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 114         # the warnings are OK.
 115         GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 116         # Since gcc 4.8 strict - false postives with old gmx_fatal. TODO: Remove in master
 117         GMX_TEST_CFLAG(CFLAGS_WARN_UNINIT "-Wno-maybe-uninitialized" GMXC_CFLAGS)
 118         if(CYGWIN)
 119             GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 120         endif()
 121         # new in gcc 4.5
 122         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 123         GMX_TEST_CFLAG(CFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
 124                        GMXC_CFLAGS_RELEASE)
 125         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 126     endif()
 127     # g++
 128     if(CMAKE_COMPILER_IS_GNUCXX)
 129         if(NOT GMX_OPENMP)
 130             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 131         endif()
 132         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 133         # Problematic with CUDA
 134         # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 135         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 136         GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 137         # new in gcc 4.5
 138         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 139         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
 140                          GMXC_CXXFLAGS_RELEASE)
 141         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 142     endif()
 143
 144     # icc
 145     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 146         if (NOT WIN32)
 147             if(NOT GMX_OPENMP)
 148                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 149 # 3180: unrecognized OpenMP #pragma
 150                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 151                 else()
 152 # 161: unrecognized #pragma
 153                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd161" GMXC_CFLAGS)
 154                 endif()
 155             endif()
 156 # 111: statement is unreachable
 157 # 177: function ".." was declared but never referenced
 158 # 181: argument of type ".." is incompatible with format "..", expecting argument of type ".."
 159 # 193: zero used for undefined preprocessing identifier ".."
 160 # 271: trailing comma is nonstandard
 161 # 304: access control not specified ("public" by default)
 162 # 383: value copied to temporary, reference to temporary used
 163 # 424: extra ";" ignored
 164 # 444: destructor for base class ".." is not virtual
 165 # 522: function ".." redeclared "inline" after being called
 166 # 593: variable ".." was set but never used
 167 # 869: parameter ".." was never referenced
 168 # 981: operands are evaluated in unspecified order
 169 #1418: external function definition with no prior declaration
 170 #1419: external declaration in primary source file
 171 #1572: floating-point equality and inequality comparisons are unreliable
 172 #1599: declaration hides variable ".."
 173 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 174 #2415: variable ".." of static storage duration was declared but never referenced
 175 #2547: ".." was specified as both a system and non-system include directory
 176 #2557: comparison between signed and unsigned operands
 177 #3280: declaration hides member ".."
 178 #3346: dynamic exception specifications are deprecated
 179 #11074: Inlining inhibited by limit max-size(/max-total-size)
 180 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 181             GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd111 -wd177 -wd181 -wd193 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076" GMXC_CFLAGS)
 182             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 183             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CFLAGS_RELEASE)
 184         else()
 185             if(NOT GMX_OPENMP)
 186                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 187                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 188                 else()
 189                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd161" GMXC_CFLAGS)
 190                 endif()
 191             endif()
 192             GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd111 /wd177 /wd181 /wd193 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346" GMXC_CFLAGS)
 193             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 194         endif()
 195     endif()
 196
 197     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 198         if (NOT WIN32)
 199             if(NOT GMX_OPENMP)
 200                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 201                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 202                 else()
 203                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd161" GMXC_CXXFLAGS)
 204                 endif()
 205             endif()
 206 #All but the following warnings are identical for the C-compiler (see above)
 207 #1782: #pragma once is obsolete
 208 #2282: unrecognized GCC pragma
 209             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd111 -wd177 -wd181 -wd193 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076 -wd1782 -wd2282" GMXC_CXXFLAGS)
 210             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CXXFLAGS_RELEASE)
 211         else()
 212             if(NOT GMX_OPENMP)
 213                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 214                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 215                 else()
 216                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd161" GMXC_CXXFLAGS)
 217                 endif()
 218             endif()
 219             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd111 /wd177 /wd181 /wd193 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346 /wd1782 /wd2282" GMXC_CXXFLAGS)
 220             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 221         endif()
 222     endif()
 223
 224     # pgi
 225     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 226         GMX_TEST_CFLAG(CFLAGS_OPT "-fastsse" GMXC_CFLAGS_RELEASE)
 227     endif()
 228     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 229         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-fastsse" GMXC_CXXFLAGS_RELEASE)
 230     endif()
 231
 232     # Pathscale
 233     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 234         if(NOT GMX_OPENMP)
 235             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 236         endif()
 237         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 238         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 239                          GMXC_CFLAGS_RELEASE)
 240         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 241     endif()
 242     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 243         if(NOT GMX_OPENMP)
 244             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 245         endif()
 246         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 247         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 248                          GMXC_CXXFLAGS_RELEASE)
 249     endif()
 250
 251     # xlc
 252     # The suppressions below stop information messages about -O3
 253     # causing non-strict IEEE compliance that changes the semantics of
 254     # the program (duh; 1500-036), warnings about correct PBC-related use of
 255     # maximum array indices of DIM-sized C arrays (1500-010).
 256     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 257         GMX_TEST_CFLAG(CFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 258         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 259         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010" GMXC_CFLAGS)
 260     endif()
 261     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 262         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 263         GMX_TEST_CXXFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010" GMXC_CXXFLAGS)
 264     endif()
 265
 266     # msvc
 267     if (MSVC)
 268         # disable warnings for:
 269         #      forcing value to bool
 270         #      "this" in initializer list
 271         #      deprecated (posix, secure) functions
 272         #      truncation (double -> float)
 273         #      conversion from 'double' to 'real', possible loss of data
 274         #      unreferenced local variable (only C)
 275         #      conversion from 'size_t' to 'int', possible loss of data
 276         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 277         if(NOT CMAKE_CONFIGURATION_TYPES)
 278             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CFLAGS)
 279             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267" GMXC_CXXFLAGS)
 280         else() #Projects only use the C++ flags
 281             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CXXFLAGS)
 282         endif()
 283     endif()
 284
 285     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 286         if(NOT GMX_OPENMP)
 287             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 288         endif()
 289         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 290         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 291     endif()
 292
 293     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 294         if(NOT GMX_OPENMP)
 295             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 296         endif()
 297         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 298         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 299     endif()
 300
 301     # Fujitsu compilers on PrimeHPC/Sparc64
 302     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 303        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 304         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 305         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 306     endif()
 307
 308     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 309        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 310         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 311         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 312     endif()
 313
 314     # now actually set the flags:
 315     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 316         gmx_set_cmake_compiler_flags()
 317     endif()
 318 ENDMACRO(gmx_c_flags)
 319