cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Currently unused, but we plan to use -Wno-array-bounds
  72         # in Release to work around gcc-4.8 being a little too vocal
  73         # about some perfectly good code, while using RelWithAssert
  74         # (ie. without that suppression) in Jenkins.
  75         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  76
  77         # Modify the real CMake variables for compiler flags for all
  78         # builds and language types, and also those common to all
  79         # build types.
  80         foreach(build_type "" ${build_types_with_explicit_flags})
  81             if("${build_type}" STREQUAL "")
  82                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  83             else()
  84                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  85             endif()
  86
  87             # Append to the variables for the given build type for
  88             # each language, in the parent scope.
  89             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  90                 "${GMXC_${language}FLAGS${punctuation}${build_type}} ${CMAKE_${language}_FLAGS${punctuation}${build_type}}"
  91                 PARENT_SCOPE)
  92         endforeach()
  93     endforeach()
  94 endfunction()
  95
  96 # This is the actual exported function to be called
  97 MACRO(gmx_c_flags)
  98
  99     include(CheckCCompilerFlag)
 100     include(CheckCXXCompilerFlag)
 101
 102     # gcc
 103     if(CMAKE_COMPILER_IS_GNUCC)
 104         #flags are added in reverse order and -Wno* need to appear after -Wall
 105         if(NOT GMX_OPENMP)
 106             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 107         endif()
 108         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 109         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 110         # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 111         # the warnings are OK.
 112         GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 113         # Since gcc 4.8 strict - false postives with old gmx_fatal. TODO: Remove in master
 114         GMX_TEST_CFLAG(CFLAGS_WARN_UNINIT "-Wno-maybe-uninitialized" GMXC_CFLAGS)
 115         if(CYGWIN)
 116             GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 117         endif()
 118         # new in gcc 4.5
 119         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 120         GMX_TEST_CFLAG(CFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
 121                        GMXC_CFLAGS_RELEASE)
 122         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 123     endif()
 124     # g++
 125     if(CMAKE_COMPILER_IS_GNUCXX)
 126         if(NOT GMX_OPENMP)
 127             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 128         endif()
 129         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 130         # Problematic with CUDA
 131         # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 132         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 133         GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 134         # new in gcc 4.5
 135         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 136         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
 137                          GMXC_CXXFLAGS_RELEASE)
 138         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 139     endif()
 140
 141     # icc
 142     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 143         if (NOT WIN32)
 144             if(NOT GMX_OPENMP)
 145                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 146 # 3180: unrecognized OpenMP #pragma
 147                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 148                 else()
 149 # 161: unrecognized #pragma
 150                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd161" GMXC_CFLAGS)
 151                 endif()
 152             endif()
 153 # 111: statement is unreachable
 154 # 177: function ".." was declared but never referenced
 155 # 181: argument of type ".." is incompatible with format "..", expecting argument of type ".."
 156 # 193: zero used for undefined preprocessing identifier ".."
 157 # 271: trailing comma is nonstandard
 158 # 304: access control not specified ("public" by default)
 159 # 383: value copied to temporary, reference to temporary used
 160 # 424: extra ";" ignored
 161 # 444: destructor for base class ".." is not virtual
 162 # 522: function ".." redeclared "inline" after being called
 163 # 593: variable ".." was set but never used
 164 # 869: parameter ".." was never referenced
 165 # 981: operands are evaluated in unspecified order
 166 #1418: external function definition with no prior declaration
 167 #1419: external declaration in primary source file
 168 #1572: floating-point equality and inequality comparisons are unreliable
 169 #1599: declaration hides variable ".."
 170 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 171 #2415: variable ".." of static storage duration was declared but never referenced
 172 #2547: ".." was specified as both a system and non-system include directory
 173 #2557: comparison between signed and unsigned operands
 174 #3280: declaration hides member ".."
 175 #3346: dynamic exception specifications are deprecated
 176 #11074: Inlining inhibited by limit max-size(/max-total-size)
 177 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 178             GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd111 -wd177 -wd181 -wd193 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076" GMXC_CFLAGS)
 179             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 180             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CFLAGS_RELEASE)
 181         else()
 182             if(NOT GMX_OPENMP)
 183                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 184                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 185                 else()
 186                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd161" GMXC_CFLAGS)
 187                 endif()
 188             endif()
 189             GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd111 /wd177 /wd181 /wd193 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346" GMXC_CFLAGS)
 190             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 191         endif()
 192     endif()
 193
 194     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 195         if (NOT WIN32)
 196             if(NOT GMX_OPENMP)
 197                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 198                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 199                 else()
 200                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd161" GMXC_CXXFLAGS)
 201                 endif()
 202             endif()
 203 #All but the following warnings are identical for the C-compiler (see above)
 204 #1782: #pragma once is obsolete
 205 #2282: unrecognized GCC pragma
 206             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd111 -wd177 -wd181 -wd193 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076 -wd1782 -wd2282" GMXC_CXXFLAGS)
 207             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CXXFLAGS_RELEASE)
 208         else()
 209             if(NOT GMX_OPENMP)
 210                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 211                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 212                 else()
 213                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd161" GMXC_CXXFLAGS)
 214                 endif()
 215             endif()
 216             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd111 /wd177 /wd181 /wd193 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346 /wd1782 /wd2282" GMXC_CXXFLAGS)
 217             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 218         endif()
 219     endif()
 220
 221     # pgi
 222     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 223         GMX_TEST_CFLAG(CFLAGS_OPT "-fastsse" GMXC_CFLAGS_RELEASE)
 224     endif()
 225     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 226         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-fastsse" GMXC_CXXFLAGS_RELEASE)
 227     endif()
 228
 229     # Pathscale
 230     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 231         if(NOT GMX_OPENMP)
 232             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 233         endif()
 234         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 235         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 236                          GMXC_CFLAGS_RELEASE)
 237         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 238     endif()
 239     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 240         if(NOT GMX_OPENMP)
 241             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 242         endif()
 243         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 244         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 245                          GMXC_CXXFLAGS_RELEASE)
 246     endif()
 247
 248     # xlc
 249     # The suppressions below stop information messages about -O3
 250     # causing non-strict IEEE compliance that changes the semantics of
 251     # the program (duh; 1500-036), warnings about correct PBC-related use of
 252     # maximum array indices of DIM-sized C arrays (1500-010).
 253     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 254         GMX_TEST_CFLAG(CFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 255         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 256         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010" GMXC_CFLAGS)
 257     endif()
 258     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 259         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 260         GMX_TEST_CXXFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010" GMXC_CXXFLAGS)
 261     endif()
 262
 263     # msvc
 264     if (MSVC)
 265         # disable warnings for:
 266         #      forcing value to bool
 267         #      "this" in initializer list
 268         #      deprecated (posix, secure) functions
 269         #      truncation (double -> float)
 270         #      conversion from 'double' to 'real', possible loss of data
 271         #      unreferenced local variable (only C)
 272         #      conversion from 'size_t' to 'int', possible loss of data
 273         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 274         if(NOT CMAKE_CONFIGURATION_TYPES)
 275             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CFLAGS)
 276             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267" GMXC_CXXFLAGS)
 277         else() #Projects only use the C++ flags
 278             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CXXFLAGS)
 279         endif()
 280     endif()
 281
 282     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 283         if(NOT GMX_OPENMP)
 284             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 285         endif()
 286         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 287         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 288     endif()
 289
 290     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 291         if(NOT GMX_OPENMP)
 292             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 293         endif()
 294         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 295         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 296     endif()
 297
 298     # Fujitsu compilers on PrimeHPC/Sparc64
 299     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 300        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 301         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 302         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 303     endif()
 304
 305     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 306        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 307         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 308         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 309     endif()
 310
 311     # now actually set the flags:
 312     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 313         gmx_set_cmake_compiler_flags()
 314     endif()
 315 ENDMACRO(gmx_c_flags)
 316