cmake/FindSphinx.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2015,2018,2019,2020,2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Check the Python installation for sphinx-build, even if not on PATH.
  36 if(Python3_EXECUTABLE)
  37     execute_process(
  38         COMMAND ${Python3_EXECUTABLE} -c "import sys; print(sys.exec_prefix)"
  39         OUTPUT_VARIABLE _python_exec_prefix
  40         OUTPUT_STRIP_TRAILING_WHITESPACE
  41     )
  42     list(APPEND CMAKE_PROGRAM_PATH ${_python_exec_prefix})
  43     unset(_python_exec_prefix)
  44     execute_process(
  45         COMMAND ${Python3_EXECUTABLE} -m site --user-base
  46         OUTPUT_VARIABLE _python_user_base
  47         ERROR_QUIET
  48         OUTPUT_STRIP_TRAILING_WHITESPACE
  49     )
  50     if (_python_user_base)
  51         list(APPEND CMAKE_PROGRAM_PATH ${_python_user_base})
  52     endif ()
  53     unset(_python_user_base)
  54     execute_process(
  55         COMMAND ${Python3_EXECUTABLE} -c "import sys; print(sys.base_exec_prefix)"
  56         OUTPUT_VARIABLE _python_base_exec_prefix
  57         ERROR_QUIET
  58         OUTPUT_STRIP_TRAILING_WHITESPACE
  59     )
  60     if (_python_base_exec_prefix)
  61         list(APPEND CMAKE_PROGRAM_PATH ${_python_base_exec_prefix})
  62     endif ()
  63     unset(_python_base_exec_prefix)
  64 endif()
  65
  66 find_program(SPHINX_EXECUTABLE NAMES sphinx-build sphinx-build2
  67              HINTS ENV SPHINX_DIR
  68              PATH_SUFFIXES bin
  69              DOC "Sphinx documentation generator"
  70              )
  71 mark_as_advanced(SPHINX_EXECUTABLE)
  72
  73 # Detect Sphinx version
  74 if (SPHINX_EXECUTABLE AND NOT DEFINED SPHINX_EXECUTABLE_VERSION)
  75     execute_process(
  76         COMMAND ${SPHINX_EXECUTABLE} --version
  77         ERROR_VARIABLE  SPHINX_VERSION_OUTPUT_VARIABLE
  78         OUTPUT_VARIABLE SPHINX_VERSION_OUTPUT_VARIABLE
  79         RESULT_VARIABLE SPHINX_VERSION_RESULT_VARIABLE
  80         ERROR_QUIET
  81         OUTPUT_STRIP_TRAILING_WHITESPACE
  82         )
  83
  84     # Detect the sphinx version. First try to match the error message
  85     # from old versions that didn't even support --version, then try
  86     # to detect more modern sphinx versions. If nothing is found, then
  87     # the cache variable is set to an empty value.
  88     set(_version "")
  89     if(SPHINX_VERSION_OUTPUT_VARIABLE MATCHES "Sphinx v([0-9\.]+)\n.*")
  90         set(_version ${CMAKE_MATCH_1})
  91     elseif (SPHINX_VERSION_OUTPUT_VARIABLE MATCHES ".*build[ )]*(.*)")
  92         set(_version ${CMAKE_MATCH_1})
  93     endif()
  94
  95     set(SPHINX_EXECUTABLE_VERSION ${_version} CACHE INTERNAL "Version of ${SPHINX_EXECUTABLE}")
  96 endif()
  97
  98
  99 if (NOT Sphinx_pygments_FOUND)
 100     # Check if pygments module is available via the Unix error code (ie. 0
 101     # for success)
 102     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c"
 103         "import pygments"
 104         RESULT_VARIABLE _pygments_status
 105         ERROR_QUIET
 106         )
 107     if (_pygments_status EQUAL 0)
 108         set(Sphinx_pygments_FOUND TRUE CACHE BOOL "Whether pygments module is available for Sphinx")
 109     endif()
 110 endif()
 111
 112 include(FindPackageHandleStandardArgs)
 113
 114 find_package_handle_standard_args(Sphinx
 115     REQUIRED_VARS SPHINX_EXECUTABLE
 116     VERSION_VAR SPHINX_EXECUTABLE_VERSION
 117     HANDLE_COMPONENTS
 118     )