CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.16.3)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags.")
  50     # By default, limit the binary architecture to a single 64-bit build.
  51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  53         FORCE)
  54 endif()
  55
  56 project(Gromacs)
  57
  58 set(CMAKE_CXX_STANDARD 17)
  59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  60 set(CMAKE_CXX_EXTENSIONS OFF)
  61
  62 include(gmxManageCcache)
  63
  64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  67
  68 find_package(LibStdCpp)
  69
  70 # Python is first referenced in gmxVersionInfo, so we perform the search early
  71 # to find a suitable installation for all components.
  72 include(gmxPythonDiscovery)
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeUBSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 178
 179 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 180 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 181
 182 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 183
 184 option(GMX_CP2K "Enable CP2K QM/MM interface (CP2K 8.1 or later is required)" OFF)
 185
 186 # We need to enable Fortran, because CP2K will be linked
 187 if(GMX_CP2K)
 188     enable_language(Fortran)
 189 endif()
 190
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 199
 200 gmx_option_multichoice(
 201     GMX_GPU
 202     "Framework for GPU acceleration"
 203     OFF
 204     OFF CUDA OpenCL SYCL)
 205
 206 gmx_option_multichoice(
 207     GMX_SIMD
 208     "SIMD instruction set for CPU kernels and compiler optimization"
 209     "AUTO"
 210     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
 211
 212 include(gmxTestIntelLLVM)
 213
 214 if (GMX_INTEL_LLVM)
 215     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 216 else()
 217     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 218 endif()
 219
 220 gmx_option_multichoice(
 221     GMX_FFT_LIBRARY
 222     "FFT library"
 223     "${GMX_FFT_LIBRARY_DEFAULT}"
 224     fftw3 mkl "fftpack[built-in]")
 225 gmx_dependent_option(
 226     GMX_BUILD_OWN_FFTW
 227     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 228     OFF
 229     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 230 gmx_dependent_option(
 231     GMX_DISABLE_FFTW_MEASURE
 232     "Do not optimize FFTW setups (not needed with SSE)"
 233     OFF
 234     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 235 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 236 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 237
 238 gmx_dependent_option(
 239     GMX_USE_HEFFTE
 240     "Use HeFFTe for FFT support. Used with CUDA backend"
 241     OFF
 242     "GMX_GPU STREQUAL CUDA;GMX_MPI")
 243
 244 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 245 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 246
 247 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 248
 249 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 250 mark_as_advanced(GMX_BROKEN_CALLOC)
 251
 252 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 253
 254 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 255
 256 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 257 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 258
 259 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 260 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 261
 262 option(GMX_BUILD_FOR_COVERAGE
 263        "Tune build for better code coverage metrics (e.g., disable asserts)"
 264        OFF)
 265 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 266
 267 option(GMX_DEVELOPER_BUILD
 268     "Enable Developer convenience features: always build unit-tests"
 269     OFF)
 270 mark_as_advanced(GMX_DEVELOPER_BUILD)
 271
 272 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 273 option(GMX_COMPILER_WARNINGS
 274     "Enable a default set of compiler warnings"
 275     ${GMX_COMPILER_WARNINGS_DEFAULT})
 276 mark_as_advanced(GMX_COMPILER_WARNINGS)
 277 # Always turn on compiler warnings with a developer build.
 278 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 279
 280 option(GMX_BUILD_SHARED_EXE
 281     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 282     ON)
 283 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 284
 285 option(GMX_PHYSICAL_VALIDATION
 286        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 287        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 288        OFF)
 289 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 290
 291 ######################################################################
 292 # Detect OpenMP support
 293 ######################################################################
 294 # The OpenMP detection _must_ come before tests for other CFLAGS.
 295 include(gmxManageOpenMP)
 296
 297
 298
 299 ######################################################################
 300 # Compiler tests
 301 # These need to be done early (before further tests).
 302 #####################################################################
 303
 304 include(gmxCFlags)
 305 gmx_c_flags()
 306
 307 # These variables should be used for CMake-style lists (ie. separated
 308 # by semicolons) of additional compiler flags which are not generated
 309 # in gmxCFlags nor are SIMD or MPI related.
 310 #
 311 # TODO These variables should be consolidated into
 312 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 313 # things that work in C compilation (e.g. merging from old branches)
 314 # might not also work for C++ compilation.
 315 set(EXTRA_C_FLAGS "")
 316 set(EXTRA_CXX_FLAGS "")
 317
 318 # Run through a number of tests for buggy compilers and other issues
 319 include(gmxTestCompilerProblems)
 320 gmx_test_compiler_problems()
 321
 322 # Implement double-precision option. This is complicated because we
 323 # need installed headers to use the precision mode of the build that
 324 # produced the library, but cannot use config.h in that case. We also
 325 # want such variables to always have a definition, because #if is more
 326 # robust than #ifdef. So, we put this value on the compiler command
 327 # line in all cases.
 328 if(GMX_DOUBLE)
 329     set(GMX_DOUBLE_VALUE 1)
 330 else()
 331     set(GMX_DOUBLE_VALUE 0)
 332 endif()
 333 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 334 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 335
 336 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 337 if(GMX_IMD AND WIN32)
 338     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 339 endif()
 340
 341
 342
 343 ########################################################################
 344 # Basic system tests (standard libraries, headers, functions, types)   #
 345 ########################################################################
 346 include(CheckIncludeFiles)
 347 include(CheckIncludeFileCXX)
 348 check_include_files(unistd.h     HAVE_UNISTD_H)
 349 check_include_files(pwd.h        HAVE_PWD_H)
 350 check_include_files(dirent.h     HAVE_DIRENT_H)
 351 check_include_files(time.h       HAVE_TIME_H)
 352 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 353 check_include_files(io.h         HAVE_IO_H)
 354 check_include_files(sched.h      HAVE_SCHED_H)
 355 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 356
 357 include(CheckCXXSymbolExists)
 358 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 359 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 360 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 361 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 362 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 363 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 364 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 365 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 366
 367 # We cannot check for the __builtins as symbols, but check if code compiles
 368 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 369 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 370 if(MSVC)
 371     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 372     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 373 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 374     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 375     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 376 endif()
 377
 378 include(CheckLibraryExists)
 379 find_library(HAVE_LIBM m)
 380 mark_as_advanced(HAVE_LIBM)
 381 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 382 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 383 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 384
 385 include(TestSchedAffinity)
 386 test_sched_affinity(HAVE_SCHED_AFFINITY)
 387
 388 # Aligned memory allocation. We need to check for both mm_malloc(),
 389 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 390 include(gmxTestMMMalloc)
 391 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 392 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 393 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 394 if(MSVC)
 395     # No need to waste time on this test on platforms where it will never be true
 396     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 397 endif()
 398
 399 include(TestBigEndian)
 400 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 401
 402 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 403
 404 ########################################################################
 405 #Process MPI settings
 406 ########################################################################
 407 include(gmxManageMPI)
 408
 409 ########################################################################
 410 #Process MiMiC settings
 411 ########################################################################
 412 include(gmxManageMimic)
 413
 414 ########################################################################
 415 #Process CP2K settings
 416 ########################################################################
 417 include(gmxManageCP2K)
 418
 419 ########################################################################
 420 #Process shared/static library settings
 421 ########################################################################
 422 include(gmxManageSharedLibraries)
 423
 424
 425 ########################################################################
 426 # Specify install locations
 427 ########################################################################
 428 # Use GNUInstallDirs to set paths on multiarch systems.
 429 include(GNUInstallDirs)
 430
 431 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 432 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 433
 434 # Internal convenience so we do not have to join two path segments in the code
 435 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 436
 437 # If the nesting level wrt. the installation root is changed,
 438 # gromacs-config.cmake.cmakein needs to be adapted.
 439 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 440
 441 # TODO: Make GMXRC adapt if this is changed
 442 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 443
 444 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 445
 446 # Binary and library suffix options
 447 include(gmxManageSuffixes)
 448
 449
 450 ########################################################################
 451 # Find external packages                                               #
 452 ########################################################################
 453
 454 # Unconditionally find the package, as it is also required for unit
 455 # tests. This exports LIBXML2_FOUND, which we should not use because
 456 # it does not tell us that linking will succeed. Instead, we test that
 457 # next.
 458 #if(DEFINED LIBXML2_LIBRARIES)
 459 #  set(LibXml2_FIND_QUIETLY TRUE)
 460 #endif()
 461 #find_package(LibXml2)
 462 #include(gmxTestLibXml2)
 463 #gmx_test_libxml2(HAVE_LIBXML2)
 464 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 465 #set(PKG_XML "")
 466 #mark_as_advanced(GMX_XML)
 467 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 468 #if(GMX_XML AND NOT HAVE_LIBXML2)
 469 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 470 #endif()
 471 #if(GMX_XML)
 472 #    include_directories(${LIBXML2_INCLUDE_DIR})
 473 #    set(PKG_XML libxml-2.0)
 474 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 475 #endif()
 476
 477 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 478
 479 if (GMX_HWLOC)
 480     # Find quietly the second time.
 481     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 482         set(HWLOC_FIND_QUIETLY TRUE)
 483     endif()
 484     find_package(HWLOC 1.5)
 485
 486     if (HWLOC_FOUND)
 487         if (HWLOC_LIBRARIES MATCHES ".a$")
 488             set(_STATIC_HWLOC TRUE)
 489         endif()
 490
 491         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 492         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 493             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 494             set(GMX_USE_HWLOC OFF)
 495         else()
 496             set(GMX_USE_HWLOC ON)
 497         endif()
 498
 499         if (GMX_USE_HWLOC)
 500             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 501             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 502         endif()
 503     elseif(GMX_HWLOC_FORCE)
 504         message(FATAL_ERROR "HWLOC package support required, but not found.")
 505     endif()
 506
 507     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 508         message(STATUS "Support for hwloc versions 1.x is deprecated")
 509     endif()
 510
 511     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 512 endif()
 513
 514 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 515 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 516 if(GMX_EXTERNAL_TINYXML2)
 517     # Find an external TinyXML-2 library.
 518     find_package(TinyXML-2 3.0.0)
 519     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 520     if(NOT HAVE_TINYXML2)
 521         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 522     endif()
 523 endif()
 524
 525 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 526 mark_as_advanced(GMX_EXTRAE)
 527
 528 if (GMX_EXTRAE)
 529   find_package(EXTRAE)
 530   if(EXTRAE_FOUND)
 531     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 532     set(HAVE_EXTRAE 1)
 533   else()
 534     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 535   endif()
 536 endif()
 537
 538 option(GMX_X11 "Use X window system" OFF)
 539 if (GMX_X11)
 540     find_package(X11)
 541     # X11 includes/libraries are only set in the ngmx subdirectory!
 542     if(NOT X11_FOUND)
 543         message(FATAL_ERROR
 544                 "X11 include files and/or libraries were not found. "
 545                 "Set GMX_X11=OFF to compile without X11 support. "
 546                 "gmx view will not be available.")
 547     endif()
 548     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 549 endif()
 550
 551 include(ThreadMPI)
 552 # Enable core threading facilities
 553 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 554 if(GMX_THREAD_MPI)
 555     # enable MPI functions
 556     tmpi_enable()
 557 endif()
 558 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 559 if (TMPI_ATOMICS_DISABLED)
 560    add_definitions(-DTMPI_ATOMICS_DISABLED)
 561 endif()
 562
 563 include(gmxManageTNG)
 564
 565 include(gmxManageLmfit)
 566
 567 include(gmxManageMuparser)
 568
 569 ##################################################
 570 # Process SIMD instruction settings
 571 ##################################################
 572 # This checks what flags to add in order to
 573 # support the SIMD instructions we need, it sets
 574 # correct defines for the SIMD instructions supported,
 575 # and adds advanced options to control accuracy
 576 # for SIMD math operations.
 577 include(gmxManageSimd)
 578 gmx_manage_simd()
 579
 580
 581 if(GMX_GPU)
 582
 583     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 584     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 585         include(gmxManageCuda)
 586     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 587         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 588             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 589             "future releases of GROMACS.")
 590         include(gmxManageOpenCL)
 591     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 592         include(gmxManageSYCL)
 593     endif()
 594     if(NOT GMX_OPENMP)
 595         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 596     endif()
 597
 598     if (GMX_OPENCL_NB_CLUSTER_SIZE)
 599         message(WARNING "GMX_OPENCL_NB_CLUSTER_SIZE is deprecated, use GMX_GPU_NB_CLUSTER_SIZE instead")
 600     endif()
 601     if (GMX_OPENCL_NB_CLUSTER_SIZE AND GMX_GPU_NB_CLUSTER_SIZE)
 602         if (NOT ${GMX_OPENCL_NB_CLUSTER_SIZE} EQUAL ${GMX_GPU_NB_CLUSTER_SIZE})
 603             message(FATAL_ERROR "Mismatching values passed to GMX_OPENCL_NB_CLUSTER_SIZE and GMX_GPU_NB_CLUSTER_SIZE; the former is deprecated, use only the latter!")
 604         endif()
 605     endif()
 606     # Only OpenCL and SYCL support changing the default cluster size
 607     if (${_gmx_gpu_uppercase} STREQUAL "CUDA")
 608         if (GMX_GPU_NB_CLUSTER_SIZE AND NOT "${GMX_GPU_NB_CLUSTER_SIZE}" EQUAL 8)
 609             message(FATAL_ERROR "Setting GMX_GPU_NB_CLUSTER_SIZE is not supported in CUDA (the default GMX_GPU_NB_CLUSTER_SIZE=8 is used)")
 610         endif()
 611     else()
 612         # use the legacy GMX_OPENCL_NB_CLUSTER_SIZE variable if set, otherwise set the defaults
 613         if (GMX_OPENCL_NB_CLUSTER_SIZE)
 614             set(_gmx_gpu_nb_cluster_size_value ${GMX_OPENCL_NB_CLUSTER_SIZE})
 615         else()
 616             # default cluster size is 8 with OpenCL and 4 with SYCL for now
 617             if(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 618                 set(_gmx_gpu_nb_cluster_size_value 8)
 619             elseif(GMX_GPU_SYCL)
 620                 if (GMX_SYCL_HIPSYCL AND NOT GMX_HIPSYCL_HAVE_LEVELZERO_TARGET)
 621                     set(_gmx_gpu_nb_cluster_size_value 8)
 622                 else()
 623                     # Either DPCPP or hipSYCL targeting Intel Level0
 624                     set(_gmx_gpu_nb_cluster_size_value 4)
 625                 endif()
 626             endif()
 627         endif()
 628         set(GMX_GPU_NB_CLUSTER_SIZE ${_gmx_gpu_nb_cluster_size_value} CACHE STRING "Cluster size used by the nonbonded kernel. Set to 4 for Intel GPUs.")
 629         mark_as_advanced(GMX_GPU_NB_CLUSTER_SIZE)
 630     endif()
 631
 632 endif()
 633
 634 # For build with CUDA and Lib-MPI, check if underlying MPI implementation is CUDA-aware
 635 # CUDA-aware MPI allows direct GPU communication without staging data through host
 636 if(GMX_GPU_CUDA AND GMX_LIB_MPI)
 637     include(gmxManageCudaAwareMPI)
 638 else()
 639     set(HAVE_CUDA_AWARE_MPI 0)
 640 endif()
 641
 642 if(CYGWIN)
 643     set(GMX_CYGWIN 1)
 644 endif()
 645
 646 if(GMX_USE_HEFFTE)
 647     if(NOT GMX_GPU_CUDA)
 648         message(FATAL_ERROR "HeFFTe support requires a CUDA build")
 649     endif()
 650     if(NOT GMX_LIB_MPI)
 651         message(FATAL_ERROR "HeFFTe support requires a library MPI build")
 652     endif()
 653     find_package(Heffte 2.1.0 REQUIRED CUDA)
 654 endif()
 655
 656 if(WIN32)
 657     set(GMX_NATIVE_WINDOWS 1)
 658     # This makes windows.h not declare min/max as macros that would break
 659     # C++ code using std::min/std::max.
 660     add_definitions(-DNOMINMAX)
 661 endif()
 662
 663 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 664 mark_as_advanced(GMX_BUILD_UNITTESTS)
 665 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 666
 667 ########################################################################
 668 # Our own GROMACS tests
 669 ########################################################################
 670
 671 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 672
 673 include(gmxTestInlineASM)
 674 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 675
 676 include(gmxSetBuildInformation)
 677 gmx_set_build_information()
 678
 679 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 680 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 681 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 682 mark_as_advanced(GMX_USE_RDTSCP)
 683
 684 include(gmxTestLargeFiles)
 685 gmx_test_large_files(GMX_LARGEFILES)
 686
 687 include(gmxTestSignal)
 688 gmx_test_sigusr1(HAVE_SIGUSR1)
 689
 690 include(gmxTestPipes)
 691 gmx_test_pipes(HAVE_PIPES)
 692
 693 include(gmxTestXDR)
 694 gmx_test_xdr(GMX_SYSTEM_XDR)
 695 # Darwin has system XDR, but it uses a three-argument flavour of
 696 # xdrproc_t that it guarantees will still work if you pass the normal
 697 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 698 # to do that, so it's simpler to just use our own XDR library.
 699 #
 700 # TODO It would be better to craft a cmake test which fails if such
 701 # XDR operations cause warnings, and succeeds otherwise, because it is
 702 # generally preferable to use system libraries where possible.
 703 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 704     set(GMX_INTERNAL_XDR 1)
 705 endif()
 706
 707 ##################################################
 708 # Process FFT library settings
 709 ##################################################
 710 include(gmxManageFFTLibraries)
 711
 712
 713 include(gmxManageLinearAlgebraLibraries)
 714
 715 include(gmxManagePluginSupport)
 716 gmx_manage_plugin_support()
 717
 718 if(GMX_USE_PLUGINS)
 719     if(NOT GMX_VMD_PLUGIN_PATH)
 720         find_package(VMD)
 721     endif()
 722 endif()
 723
 724 # People might want to customize the default location for the DSSP binary
 725 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 726     CACHE PATH
 727     "The default location to use for the DSSP binary")
 728 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 729
 730 # Link real-time library for POSIX timers. The check for clock_gettime
 731 # confirms the linkability of rt.
 732 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 733     list(APPEND GMX_EXTRA_LIBRARIES rt)
 734 endif()
 735
 736 # Math and thread libraries must often come after all others when linking...
 737 if (HAVE_LIBM)
 738     list(APPEND GMX_PUBLIC_LIBRARIES m)
 739 endif()
 740
 741 option(GMX_NACL "Configure for Native Client builds" OFF)
 742 if (GMX_NACL)
 743   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 744   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 745   # TODO: Is this still necessary with the check for its presence?
 746   set(GMX_USE_NICE 0)
 747   set(GMX_NO_RENAME 1)
 748 endif()
 749 mark_as_advanced(GMX_NACL)
 750
 751 if(GMX_FAHCORE)
 752   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 753       "Path to swindirect.h")
 754   include_directories(${COREWRAP_INCLUDE_DIR})
 755 endif()
 756
 757 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 758 mark_as_advanced(GMX_BUILD_HELP)
 759 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 760     message(FATAL_ERROR
 761         "Rebuilding shell completions or man pages is not supported for "
 762         "in-source builds from a source distribution. "
 763         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 764 endif()
 765
 766 if (GMX_BUILD_FOR_COVERAGE)
 767     # Set flags for coverage build here instead having to do so manually
 768     set(CMAKE_C_FLAGS "-g --coverage")
 769     set(CMAKE_CXX_FLAGS "-g --coverage")
 770 endif()
 771
 772 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 773 # these are set after everything else
 774 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 775     #TODO(#3672): Use target_link_libraries(... MPI::MPI_CXX) instead of ${MPI_CXX_LINK_FLAGS}
 776     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 777     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 778 else()
 779     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 780     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 781     foreach(build_type ${build_types_with_explicit_flags})
 782         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 783     endforeach()
 784     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 785     foreach(build_type ${build_types_with_explicit_flags})
 786         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 787     endforeach()
 788     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 789     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 790 endif()
 791 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 792 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 793
 794 ################################################################
 795 # Shared library load path settings
 796 ################################################################
 797 if(NOT GMX_BUILD_SHARED_EXE)
 798     # No rpath
 799     set(CMAKE_SKIP_RPATH TRUE)
 800     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 801     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 802 else()
 803     # The build folder always has bin/ and lib/; if we are also going to
 804     # install to lib/, then the installation RPATH works also in the build
 805     # tree.  This makes installation slightly faster (no need to rewrite the
 806     # RPATHs), and makes the binaries in the build tree relocatable.
 807     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 808         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 809         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 810     endif()
 811     # Set the RPATH as relative to the executable location to make the
 812     # binaries relocatable.
 813     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 814         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 815         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 816     else()
 817         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 818     endif()
 819     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 820     set(CMAKE_MACOSX_RPATH 1)
 821 endif()
 822
 823 #COPYING file: Only necessary for binary distributions.
 824 #Simpler to always install.
 825 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 826
 827 if (BUILD_TESTING)
 828     include(tests/CheckTarget.cmake)
 829 endif()
 830
 831 option(GMX_PYTHON_PACKAGE
 832        "Configure gmxapi Python package for use in build tree. Requires pybind11 installed for project Python interpreter."
 833        OFF)
 834 mark_as_advanced(GMX_PYTHON_PACKAGE)
 835
 836 find_package(ImageMagick QUIET COMPONENTS convert)
 837 include(gmxTestImageMagick)
 838 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 839 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 840 add_subdirectory(docs)
 841 add_subdirectory(share)
 842 add_subdirectory(scripts)
 843 add_subdirectory(api)
 844 add_subdirectory(src)
 845
 846 if (BUILD_TESTING)
 847     add_subdirectory(tests)
 848 endif()
 849
 850 if(GMX_PYTHON_PACKAGE)
 851     add_subdirectory(python_packaging)
 852 endif()
 853
 854 gmx_cpack_write_config()
 855
 856 #######################
 857 ## uninstall target
 858 #######################
 859 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 860                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 861                   IMMEDIATE @ONLY)
 862 ###########################
 863 ADD_CUSTOM_TARGET(uninstall
 864                   "${CMAKE_COMMAND}" -P
 865                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 866 ###########################
 867 set_directory_properties(PROPERTIES
 868             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")