CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsitencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 if(GMX_CPU_ACCELERATION)
 176     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 177     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 178     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 179     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 180 endif()
 181
 182 if(NOT GMX_TARGET_MIC)
 183     include(gmxDetectSimd)
 184     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 185 else()
 186     set(GMX_SUGGESTED_SIMD "None")
 187 endif()
 188
 189 gmx_option_multichoice(
 190     GMX_SIMD
 191     "SIMD instruction set for CPU kernels and compiler optimization"
 192     "${GMX_SUGGESTED_SIMD}"
 193     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 194
 195 gmx_option_multichoice(
 196     GMX_FFT_LIBRARY
 197     "FFT library"
 198     "fftw3"
 199     fftw3 mkl "fftpack[built-in]")
 200 gmx_dependent_option(
 201     GMX_BUILD_OWN_FFTW
 202     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 203     OFF
 204     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 205 gmx_dependent_option(
 206     GMX_DISABLE_FFTW_MEASURE
 207     "Do not optimize FFTW setups (not needed with SSE)"
 208     OFF
 209     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 210 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 211 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 212
 213 gmx_option_multichoice(
 214     GMX_QMMM_PROGRAM
 215     "QM package for QM/MM"
 216     None
 217     none gaussian mopac gamess orca)
 218
 219 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 220 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 221
 222 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 223
 224 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 225 mark_as_advanced(GMX_BROKEN_CALLOC)
 226 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 227 mark_as_advanced(GMX_LOAD_PLUGINS)
 228
 229 option(GMX_GPU  "Enable GPU acceleration" ON)
 230 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 231
 232 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 233
 234 if(UNIX)
 235     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 236 endif()
 237 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 238
 239 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 240 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 241
 242 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 243 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 244
 245 option(GMX_BUILD_FOR_COVERAGE
 246        "Tune build for better code coverage metrics (e.g., disable asserts)"
 247        OFF)
 248 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 249
 250 option(GMX_DEVELOPER_BUILD
 251     "Enable Developer convenience features: always build unit-tests"
 252     OFF)
 253 mark_as_advanced(GMX_DEVELOPER_BUILD)
 254
 255 ######################################################################
 256 # Detect OpenMP support
 257 ######################################################################
 258 # The OpenMP detection _must_ come before tests for other CFLAGS.
 259 include(gmxManageOpenMP)
 260
 261
 262
 263 ######################################################################
 264 # Compiler tests
 265 # These need to be done early (before further tests).
 266 #####################################################################
 267
 268 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 269 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 270 # invalid options with the Intel Compilers, and we have added a line
 271 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 272 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 273 # a semicolon. Since this is also used as a separator in lists inside CMake,
 274 # that string ends up being split into two separate patterns, and the last
 275 # part is just a single word that also matches other messages. We solved this
 276 # by replacing the semicolon with a period that matches any character.
 277 #
 278 # These files should be removed from the source tree when a CMake version that
 279 # includes the features in question becomes required for building GROMACS.
 280 include(CheckCCompilerFlag)
 281 include(CheckCXXCompilerFlag)
 282
 283 include(gmxCFlags)
 284 gmx_c_flags()
 285
 286 # This variable should be used for additional compiler flags which are not
 287 # generated in gmxCFlags nor are SIMD or MPI related.
 288 set(EXTRA_C_FLAGS "")
 289 set(EXTRA_CXX_FLAGS "")
 290
 291 # Run through a number of tests for buggy compilers and other issues
 292 include(gmxTestCompilerProblems)
 293 gmx_test_compiler_problems()
 294 # GMX_SIMD will not be set automatically until the second
 295 # pass (which is not strictly guaranteed to occur), so putting this
 296 # check here among logically-related tests is inefficient, but the
 297 # potential loss is likely zero.
 298 if(GMX_SIMD STREQUAL "AVX_256"
 299         AND CMAKE_COMPILER_IS_GNUCC
 300         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 301             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 302     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 303     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 304 endif()
 305
 306
 307 if(GMX_DOUBLE)
 308     add_definitions(-DGMX_DOUBLE)
 309     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 310     if(GMX_RELAXED_DOUBLE_PRECISION)
 311         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 312     endif()
 313 endif()
 314 if(GMX_SOFTWARE_INVSQRT)
 315     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 316 endif()
 317
 318 if(WIN32 AND NOT CYGWIN)
 319     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 320     add_definitions(-DGMX_HAVE_WINSOCK)
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337
 338 check_include_files(regex.h      HAVE_POSIX_REGEX)
 339 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 340 # TODO: It could be nice to inform the user if no regex support is found,
 341 # as selections won't be fully functional.
 342
 343 include(CheckFunctionExists)
 344 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 345 check_function_exists(memalign          HAVE_MEMALIGN)
 346 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 347 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 348 check_function_exists(fsync             HAVE_FSYNC)
 349 check_function_exists(_fileno           HAVE__FILENO)
 350 check_function_exists(fileno            HAVE_FILENO)
 351 check_function_exists(_commit           HAVE__COMMIT)
 352 check_function_exists(sigaction         HAVE_SIGACTION)
 353 check_function_exists(sysconf           HAVE_SYSCONF)
 354 check_function_exists(rsqrt             HAVE_RSQRT)
 355 check_function_exists(rsqrtf            HAVE_RSQRTF)
 356 check_function_exists(sqrtf             HAVE_SQRTF)
 357
 358 include(CheckLibraryExists)
 359 check_library_exists(m sqrt "" HAVE_LIBM)
 360 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 361
 362 include(TestSchedAffinity)
 363 test_sched_affinity(HAVE_SCHED_AFFINITY)
 364
 365 include(TestBigEndian)
 366 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 367
 368 # Management of GROMACS options for specific toolchains should go
 369 # here. Because the initial settings for some of the main options have
 370 # already happened, but things like library detection and MPI compiler
 371 # feature detection have not, the docstrings for any over-rides of
 372 # GROMACS defaults or user settings will make sense. Also, any
 373 # toolchain-related reasons for choosing whether to detect various
 374 # things can be sorted out now, before the detection takes place.
 375 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 376     include(gmxManageBlueGene)
 377 endif()
 378
 379 if(GMX_TARGET_FUJITSU_SPARC64)
 380     include(gmxManageFujitsuSparc64)
 381 endif()
 382
 383 ########################################################################
 384 #Process MPI settings
 385 ########################################################################
 386 include(gmxManageMPI)
 387
 388
 389 ########################################################################
 390 #Process shared/static library settings
 391 ########################################################################
 392 include(gmxManageSharedLibraries)
 393
 394
 395 ########################################################################
 396 # Find external packages                                               #
 397 ########################################################################
 398
 399 # Unconditionally find the package, as it is also required for unit
 400 # tests. This exports LIBXML2_FOUND, which we should not use because
 401 # it does not tell us that linking will succeed. Instead, we test that
 402 # next.
 403 if(DEFINED LIBXML2_LIBRARIES)
 404   set(LibXml2_FIND_QUIETLY TRUE)
 405 endif()
 406 find_package(LibXml2)
 407 include(gmxTestLibXml2)
 408 gmx_test_libxml2(HAVE_LIBXML2)
 409 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 410 set(PKG_XML "")
 411 mark_as_advanced(GMX_XML)
 412 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 413 #if(GMX_XML AND NOT HAVE_LIBXML2)
 414 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 415 #endif()
 416 #if(GMX_XML)
 417 #    include_directories(${LIBXML2_INCLUDE_DIR})
 418 #    set(PKG_XML libxml-2.0)
 419 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 420 #endif()
 421
 422 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 423 mark_as_advanced(GMX_EXTRAE)
 424
 425 if (GMX_EXTRAE)
 426   find_package(EXTRAE)
 427   if(EXTRAE_FOUND)
 428     include_directories(${EXTRAE_INCLUDE_DIR})
 429     set(HAVE_EXTRAE 1)
 430   else()
 431     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 432   endif()
 433 endif()
 434
 435 option(GMX_X11 "Use X window system" OFF)
 436 if (GMX_X11)
 437     find_package(X11)
 438     # X11 includes/libraries are only set in the ngmx subdirectory!
 439     if(NOT X11_FOUND)
 440         message(FATAL_ERROR
 441                 "X11 include files and/or libraries were not found. "
 442                 "Set GMX_X11=OFF to compile without X11 support. "
 443                 "gmx view will not be available.")
 444     endif()
 445     include_directories(${X11_INCLUDE_DIR})
 446 endif()
 447
 448 include(ThreadMPI)
 449 # Enable core threading facilities
 450 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 451 # Enable tMPI C++ support
 452 tmpi_enable_cxx()
 453 if(GMX_THREAD_MPI)
 454     # enable MPI functions
 455     tmpi_enable()
 456     set(GMX_MPI 1)
 457     set(MPI_IN_PLACE_EXISTS 1)
 458 endif()
 459 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 460 if (TMPI_ATOMICS_DISABLED)
 461    add_definitions(-DTMPI_ATOMICS_DISABLED)
 462 endif()
 463
 464 if(GMX_GPU)
 465     # now that we have detected the dependencies, do the second configure pass
 466     gmx_gpu_setup()
 467 endif()
 468
 469 if(CYGWIN)
 470     set(GMX_CYGWIN 1)
 471 endif()
 472
 473 if(WIN32 AND NOT CYGWIN)
 474     set(GMX_NATIVE_WINDOWS 1)
 475     # This makes windows.h not declare min/max as macros that would break
 476     # C++ code using std::min/std::max.
 477     add_definitions(-DNOMINMAX)
 478 endif()
 479
 480 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 481 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 482 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 483     find_package(Boost 1.44.0)
 484     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 485         set(Boost_FOUND FALSE)
 486     endif()
 487     # Print the notification only on first run, when determining the default
 488     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 489         message("Boost >= 1.44 not found. Using minimal internal version. "
 490                 "This may cause trouble if you plan on compiling/linking other "
 491                 "software that uses Boost against Gromacs.")
 492     endif()
 493 endif()
 494 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 495        ${Boost_FOUND})
 496 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 497     message(FATAL_ERROR
 498         "Boost >= 1.44 not found. "
 499         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 500         "version of Boost included with Gromacs.")
 501 endif()
 502
 503 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 504     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 505 endif()
 506 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 507 mark_as_advanced(GMX_BUILD_UNITTESTS)
 508 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 509 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 510     message(FATAL_ERROR
 511         "Cannot build unit tests without libxml2. "
 512         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 513 endif()
 514
 515 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 516     # TNG wants zlib if it is available
 517     find_package(ZLIB QUIET)
 518     include(gmxTestZLib)
 519     gmx_test_zlib(HAVE_ZLIB)
 520 endif()
 521
 522 ########################################################################
 523 # Our own GROMACS tests
 524 ########################################################################
 525
 526 add_definitions( -DHAVE_CONFIG_H )
 527 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 528 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 529 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 530 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 531
 532 include(gmxTestInlineASM)
 533 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 534
 535 include(gmxSetBuildInformation)
 536 gmx_set_build_information()
 537 # Turn on RDTSCP if:
 538 # - the build system's CPU supports it
 539 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 540 #   at this point means that the user set it).
 541 # Note: it's better to not use the later set value of GMX_SIMD because
 542 # it reflects the system's capability of both compiling and running AVX code.
 543 # TODO: After merge with 5.0 one could implement a cache variable dependency
 544 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 545 # after the first cmake pass.
 546 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 547     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 548 else()
 549     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 550 endif()
 551 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 552 mark_as_advanced(GMX_USE_RDTSCP)
 553 if(GMX_USE_RDTSCP)
 554     set(HAVE_RDTSCP 1)
 555 endif()
 556
 557 include(gmxTestFloatFormat)
 558 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 559                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 560                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 561
 562 include(gmxTestLargeFiles)
 563 gmx_test_large_files(GMX_LARGEFILES)
 564
 565 include(gmxTestSignal)
 566 gmx_test_sigusr1(HAVE_SIGUSR1)
 567
 568 include(gmxTestPipes)
 569 gmx_test_pipes(HAVE_PIPES)
 570
 571 include(gmxTestIsfinite)
 572 gmx_test_isfinite(HAVE_ISFINITE)
 573 gmx_test__isfinite(HAVE__ISFINITE)
 574 gmx_test__finite(HAVE__FINITE)
 575
 576 include(gmxTestCXX11)
 577 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 578 include(CMakeDependentOption)
 579 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 580 # entirely to keep the compilation environment uniform.
 581 cmake_dependent_option(GMX_CXX11
 582     "Use C++11 features"
 583     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 584 mark_as_advanced(GMX_CXX11)
 585 if(GMX_CXX11)
 586     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 587 endif()
 588
 589
 590 include(gmxTestXDR)
 591 gmx_test_xdr(GMX_SYSTEM_XDR)
 592 if(NOT GMX_SYSTEM_XDR)
 593     set(GMX_INTERNAL_XDR 1)
 594 endif()
 595
 596
 597 ##################################################
 598 # Process SIMD instruction settings
 599 ##################################################
 600 # This checks what flags to add in order to
 601 # support the SIMD instructions we need, and sets
 602 # correct defines for the SIMD instructions supported.
 603 include(gmxTestSimd)
 604 gmx_test_simd()
 605
 606
 607 # Process QM/MM Settings
 608 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 609     set(GMX_QMMM_GAUSSIAN 1)
 610 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 611     set(GMX_QMMM_MOPAC 1)
 612 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 613     set(GMX_QMMM_GAMESS 1)
 614 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 615     set(GMX_QMMM_ORCA 1)
 616 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 617     # nothing to do
 618 else()
 619     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 620 endif()
 621
 622
 623 ##################################################
 624 # Process FFT library settings
 625 ##################################################
 626 include(gmxManageFFTLibraries)
 627
 628
 629 include(gmxManageLinearAlgebraLibraries)
 630
 631 # Whether GROMACS will really try to compile support for VMD plugins
 632 set(GMX_USE_PLUGINS OFF)
 633
 634 if(GMX_LOAD_PLUGINS)
 635   if(CYGWIN OR NOT WIN32)
 636     # Native Windows does not have, nor need dlopen
 637     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 638     include(gmxTestdlopen)
 639     gmx_test_dlopen(HAVE_DLOPEN)
 640   endif()
 641
 642   # so, should we use plug-ins?
 643   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 644     if(NOT VMD_QUIETLY)
 645       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 646     endif()
 647     if(NOT GMX_VMD_PLUGIN_PATH)
 648       find_package(VMD)
 649     endif()
 650     set(GMX_USE_PLUGINS ON)
 651     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 652     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 653   else()
 654     set(PKG_DL_LIBS)
 655   endif()
 656 endif()
 657 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 658
 659 # Link real-time library for POSIX timers. The check for clock_gettime
 660 # confirms the linkability of rt.
 661 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 662     list(APPEND GMX_EXTRA_LIBRARIES rt)
 663 endif()
 664
 665 # Math and thread libraries must often come after all others when linking...
 666 if(HAVE_LIBM)
 667     list(APPEND GMX_EXTRA_LIBRARIES m)
 668 endif()
 669
 670 option(GMX_NACL "Configure for Native Client builds" OFF)
 671 if (GMX_NACL)
 672   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 673   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 674   set(GMX_NO_NICE 1)
 675   set(GMX_NO_RENAME 1)
 676 endif()
 677 mark_as_advanced(GMX_NACL)
 678
 679 if(GMX_FAHCORE)
 680   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 681       "Path to swindirect.h")
 682   include_directories(${COREWRAP_INCLUDE_DIR})
 683 endif()
 684
 685 # Value of AUTO tries to generate things, but will only produce warnings if
 686 # that fails.
 687 set(build_help_default AUTO)
 688 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 689     set(build_help_default OFF)
 690 endif()
 691 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 692 mark_as_advanced(GMX_BUILD_HELP)
 693 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 694     message(FATAL_ERROR
 695         "Rebuilding HTML and man pages or shell completions is not supported "
 696         "for in-source builds from a source distribution. "
 697         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 698 endif()
 699
 700 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 701 # these are set after everything else
 702 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 703     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 704     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 705     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 706     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 707 else()
 708     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 709     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 710     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 711     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 712     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 713     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 714     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 715     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 716     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 717 endif()
 718
 719 if(NOT GMX_OPENMP)
 720     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 721     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 722     unset(OpenMP_C_FLAGS CACHE)
 723     unset(OpenMP_CXX_FLAGS CACHE)
 724 else()
 725     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 726     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 727 endif()
 728
 729 ########################################################################
 730 # Specify install locations
 731 ########################################################################
 732 # Use GNUInstallDirs to set paths on multiarch systems.
 733 include(GNUInstallDirs)
 734
 735 # Customization for the installation tree paths.
 736 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 737     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 738 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 739     "Data installation directory under share/ (default: gromacs)")
 740 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 741
 742 # These variables are used internally to provide a central location for
 743 # customizing the install locations.
 744 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 745 set(BIN_INSTALL_DIR       bin)
 746 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 747 set(MAN_INSTALL_DIR       share/man)
 748 # If the nesting level wrt. the installation root is changed,
 749 # gromacs-config.cmake.cmakein needs to be adapted.
 750 set(CMAKE_INSTALL_DIR     share/cmake)
 751 # TODO: Make GMXRC adapt if this is changed
 752 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 753 set(INCL_INSTALL_DIR      include)
 754
 755 # These variables get written into config.h for use in finding the data
 756 # directories.
 757 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 758 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 759
 760 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 761
 762 # Binary and library suffix options
 763 include(gmxManageSuffixes)
 764
 765 ################################################################
 766 # Shared library load path settings
 767 ################################################################
 768 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 769 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 770 # was added.
 771 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 772    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 773     # The build folder always has bin/ and lib/; if we are also going to
 774     # install to lib/, then the installation RPATH works also in the build
 775     # tree.  This makes installation slightly faster (no need to rewrite the
 776     # RPATHs), and makes the binaries in the build tree relocatable.
 777     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 778         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 779     endif()
 780     # Set the RPATH as relative to the executable location to make the
 781     # binaries relocatable.
 782     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 783         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 784     else()
 785         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 786     endif()
 787     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 788     set(CMAKE_MACOSX_RPATH 1)
 789 else()
 790     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 791     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 792         # Set the RPATH options manually.
 793         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 794         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 795     else()
 796         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 797         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 798     endif()
 799 endif()
 800
 801 #COPYING file: Only necessary for binary distributions.
 802 #Simpler to always install.
 803 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 804
 805 if(GMX_EXTERNAL_BOOST)
 806     include_directories(${Boost_INCLUDE_DIRS})
 807     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 808 else()
 809     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 810     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 811     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 812     # typeid not supported for minimal internal version
 813     # (would add significant amount of code)
 814     add_definitions(-DBOOST_NO_TYPEID)
 815     if (NOT GMX_BUILD_MDRUN_ONLY)
 816         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 817                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 818                 COMPONENT development)
 819     endif()
 820 endif()
 821
 822 if (GMX_BUILD_FOR_COVERAGE)
 823     # Code heavy with asserts makes conditional coverage close to useless metric,
 824     # as by design most of the false branches are impossible to trigger in
 825     # correctly functioning code.  And the benefit of testing those that could
 826     # be triggered by using an API against its specification isn't usually
 827     # worth the effort.
 828     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 829 endif()
 830
 831 if (BUILD_TESTING)
 832     # "tests" target builds all the separate test binaries.
 833     add_custom_target(tests)
 834     # "run-ctest" is an internal target that actually runs the tests.
 835     # This is necessary to be able to add separate targets that execute as part
 836     # of 'make check', but are ensured to be executed after the actual tests.
 837     add_custom_target(run-ctest
 838                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 839                       COMMENT "Running all tests"
 840                       VERBATIM)
 841     add_dependencies(run-ctest tests)
 842     # "check" target builds and runs all tests.
 843     add_custom_target(check DEPENDS run-ctest)
 844 endif()
 845
 846 if (NOT GMX_BUILD_MDRUN_ONLY)
 847     add_subdirectory(docs)
 848     add_subdirectory(share)
 849     add_subdirectory(scripts)
 850 endif()
 851 add_subdirectory(src)
 852
 853 if (BUILD_TESTING)
 854     add_subdirectory(tests)
 855 endif()
 856
 857 gmx_cpack_write_config()
 858
 859 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 860 # Don't bother the user after the first configure pass.
 861 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 862     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 863 endif()
 864 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 865
 866 #######################
 867 ## uninstall target
 868 #######################
 869 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 870                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 871                   IMMEDIATE @ONLY)
 872 ###########################
 873 ADD_CUSTOM_TARGET(uninstall
 874                   "${CMAKE_COMMAND}" -P
 875                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 876 ###########################
 877 set_directory_properties(PROPERTIES
 878             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")