CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.13)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags.")
  50     # By default, limit the binary architecture to a single 64-bit build.
  51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  53         FORCE)
  54 endif()
  55
  56 project(Gromacs)
  57
  58 set(CMAKE_CXX_STANDARD 17)
  59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  60 set(CMAKE_CXX_EXTENSIONS OFF)
  61
  62 include(gmxManageCcache)
  63
  64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  67
  68 find_package(LibStdCpp)
  69
  70 # Python is first referenced in gmxVersionInfo, so we perform the search early
  71 # to find a suitable installation for all components.
  72 include(gmxPythonDiscovery)
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeUBSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191
 192 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 193
 194 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 195 mark_as_advanced(GMX_FAHCORE)
 196
 197 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 198 mark_as_advanced(GMX_COOL_QUOTES)
 199 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 200
 201 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 202
 203 gmx_option_multichoice(
 204     GMX_GPU
 205     "Framework for GPU acceleration"
 206     OFF
 207     OFF CUDA OpenCL SYCL)
 208
 209 gmx_option_multichoice(
 210     GMX_SIMD
 211     "SIMD instruction set for CPU kernels and compiler optimization"
 212     "AUTO"
 213     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD ARM_SVE IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 214
 215 if(GMX_TARGET_MIC)
 216     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 217 else()
 218     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 219 endif()
 220
 221 gmx_option_multichoice(
 222     GMX_FFT_LIBRARY
 223     "FFT library"
 224     "${GMX_FFT_LIBRARY_DEFAULT}"
 225     fftw3 mkl "fftpack[built-in]")
 226 gmx_dependent_option(
 227     GMX_BUILD_OWN_FFTW
 228     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 229     OFF
 230     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 231 gmx_dependent_option(
 232     GMX_DISABLE_FFTW_MEASURE
 233     "Do not optimize FFTW setups (not needed with SSE)"
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 237 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 238
 239 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 240 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 241
 242 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 243
 244 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 245 mark_as_advanced(GMX_BROKEN_CALLOC)
 246
 247 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 248
 249 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 250
 251 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 252
 253 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 254 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 255
 256 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 257 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 258
 259 option(GMX_BUILD_FOR_COVERAGE
 260        "Tune build for better code coverage metrics (e.g., disable asserts)"
 261        OFF)
 262 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 263
 264 option(GMX_DEVELOPER_BUILD
 265     "Enable Developer convenience features: always build unit-tests"
 266     OFF)
 267 mark_as_advanced(GMX_DEVELOPER_BUILD)
 268
 269 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 270 option(GMX_COMPILER_WARNINGS
 271     "Enable a default set of compiler warnings"
 272     ${GMX_COMPILER_WARNINGS_DEFAULT})
 273 mark_as_advanced(GMX_COMPILER_WARNINGS)
 274 # Always turn on compiler warnings with a developer build.
 275 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 276
 277 option(GMX_BUILD_SHARED_EXE
 278     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 279     ON)
 280 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 281
 282 option(GMX_PHYSICAL_VALIDATION
 283        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 284        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 285        OFF)
 286 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 287
 288 ######################################################################
 289 # Detect OpenMP support
 290 ######################################################################
 291 # The OpenMP detection _must_ come before tests for other CFLAGS.
 292 include(gmxManageOpenMP)
 293
 294
 295
 296 ######################################################################
 297 # Compiler tests
 298 # These need to be done early (before further tests).
 299 #####################################################################
 300
 301 include(gmxTestIntelLLVM)
 302 include(gmxCFlags)
 303 gmx_c_flags()
 304
 305 # These variables should be used for CMake-style lists (ie. separated
 306 # by semicolons) of additional compiler flags which are not generated
 307 # in gmxCFlags nor are SIMD or MPI related.
 308 #
 309 # TODO These variables should be consolidated into
 310 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 311 # things that work in C compilation (e.g. merging from old branches)
 312 # might not also work for C++ compilation.
 313 set(EXTRA_C_FLAGS "")
 314 set(EXTRA_CXX_FLAGS "")
 315
 316 # Run through a number of tests for buggy compilers and other issues
 317 include(gmxTestCompilerProblems)
 318 gmx_test_compiler_problems()
 319
 320 # Implement double-precision option. This is complicated because we
 321 # need installed headers to use the precision mode of the build that
 322 # produced the library, but cannot use config.h in that case. We also
 323 # want such variables to always have a definition, because #if is more
 324 # robust than #ifdef. So, we put this value on the compiler command
 325 # line in all cases.
 326 #
 327 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 328 # because no installed header needs it
 329 if(GMX_DOUBLE)
 330     set(GMX_DOUBLE_VALUE 1)
 331 else()
 332     set(GMX_DOUBLE_VALUE 0)
 333 endif()
 334 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 335 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 336
 337 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 338 if(GMX_IMD AND WIN32)
 339     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 340 endif()
 341
 342
 343
 344 ########################################################################
 345 # Basic system tests (standard libraries, headers, functions, types)   #
 346 ########################################################################
 347 include(CheckIncludeFiles)
 348 include(CheckIncludeFileCXX)
 349 check_include_files(unistd.h     HAVE_UNISTD_H)
 350 check_include_files(pwd.h        HAVE_PWD_H)
 351 check_include_files(dirent.h     HAVE_DIRENT_H)
 352 check_include_files(time.h       HAVE_TIME_H)
 353 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 354 check_include_files(io.h         HAVE_IO_H)
 355 check_include_files(sched.h      HAVE_SCHED_H)
 356 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 357
 358 include(CheckCXXSymbolExists)
 359 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 360 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 361 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 362 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 363 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 364 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 365 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 366 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 367
 368 # We cannot check for the __builtins as symbols, but check if code compiles
 369 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 370 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 371 if(MSVC)
 372     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 373     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 374 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 375     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 376     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 377 endif()
 378
 379 include(CheckLibraryExists)
 380 find_library(HAVE_LIBM m)
 381 mark_as_advanced(HAVE_LIBM)
 382 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 383 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 384 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 385
 386 include(TestSchedAffinity)
 387 test_sched_affinity(HAVE_SCHED_AFFINITY)
 388
 389 # Aligned memory allocation. We need to check for both mm_malloc(),
 390 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 391 include(gmxTestMMMalloc)
 392 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 393 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 394 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 395 if(MSVC)
 396     # No need to waste time on this test on platforms where it will never be true
 397     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 398 endif()
 399
 400 include(TestBigEndian)
 401 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 402
 403 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 404
 405 # Management of GROMACS options for specific toolchains should go
 406 # here. Because the initial settings for some of the main options have
 407 # already happened, but things like library detection and MPI compiler
 408 # feature detection have not, the docstrings for any over-rides of
 409 # GROMACS defaults or user settings will make sense. Also, any
 410 # toolchain-related reasons for choosing whether to detect various
 411 # things can be sorted out now, before the detection takes place.
 412 if(GMX_TARGET_FUJITSU_SPARC64)
 413     include(gmxManageFujitsuSparc64)
 414 endif()
 415
 416 ########################################################################
 417 #Process MPI settings
 418 ########################################################################
 419 include(gmxManageMPI)
 420
 421 ########################################################################
 422 #Process MiMiC settings
 423 ########################################################################
 424 include(gmxManageMimic)
 425
 426 ########################################################################
 427 #Process shared/static library settings
 428 ########################################################################
 429 include(gmxManageSharedLibraries)
 430
 431
 432 ########################################################################
 433 # Specify install locations
 434 ########################################################################
 435 # Use GNUInstallDirs to set paths on multiarch systems.
 436 include(GNUInstallDirs)
 437
 438 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 439 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 440
 441 # Internal convenience so we do not have to join two path segments in the code
 442 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 443
 444 # If the nesting level wrt. the installation root is changed,
 445 # gromacs-config.cmake.cmakein needs to be adapted.
 446 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 447
 448 # TODO: Make GMXRC adapt if this is changed
 449 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 450
 451 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 452
 453 # Binary and library suffix options
 454 include(gmxManageSuffixes)
 455
 456
 457 ########################################################################
 458 # Find external packages                                               #
 459 ########################################################################
 460
 461 # Unconditionally find the package, as it is also required for unit
 462 # tests. This exports LIBXML2_FOUND, which we should not use because
 463 # it does not tell us that linking will succeed. Instead, we test that
 464 # next.
 465 #if(DEFINED LIBXML2_LIBRARIES)
 466 #  set(LibXml2_FIND_QUIETLY TRUE)
 467 #endif()
 468 #find_package(LibXml2)
 469 #include(gmxTestLibXml2)
 470 #gmx_test_libxml2(HAVE_LIBXML2)
 471 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 472 #set(PKG_XML "")
 473 #mark_as_advanced(GMX_XML)
 474 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 475 #if(GMX_XML AND NOT HAVE_LIBXML2)
 476 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 477 #endif()
 478 #if(GMX_XML)
 479 #    include_directories(${LIBXML2_INCLUDE_DIR})
 480 #    set(PKG_XML libxml-2.0)
 481 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 482 #endif()
 483
 484 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 485
 486 if (GMX_HWLOC)
 487     # Find quietly the second time.
 488     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 489         set(HWLOC_FIND_QUIETLY TRUE)
 490     endif()
 491     find_package(HWLOC 1.5)
 492
 493     if (HWLOC_FOUND)
 494         if (HWLOC_LIBRARIES MATCHES ".a$")
 495             set(_STATIC_HWLOC TRUE)
 496         endif()
 497
 498         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 499         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 500             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 501             set(GMX_USE_HWLOC OFF)
 502         else()
 503             set(GMX_USE_HWLOC ON)
 504         endif()
 505
 506         if (GMX_USE_HWLOC)
 507             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 508             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 509         endif()
 510     elseif(GMX_HWLOC_FORCE)
 511         message(FATAL_ERROR "HWLOC package support required, but not found.")
 512     endif()
 513
 514     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 515         message(STATUS "Support for hwloc versions 1.x is deprecated")
 516     endif()
 517
 518     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 519 endif()
 520
 521 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 522 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 523 if(GMX_EXTERNAL_TINYXML2)
 524     # Find an external TinyXML-2 library.
 525     find_package(TinyXML-2 3.0.0)
 526     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 527     if(NOT HAVE_TINYXML2)
 528         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 529     endif()
 530 endif()
 531
 532 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 533 mark_as_advanced(GMX_EXTRAE)
 534
 535 if (GMX_EXTRAE)
 536   find_package(EXTRAE)
 537   if(EXTRAE_FOUND)
 538     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 539     set(HAVE_EXTRAE 1)
 540   else()
 541     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 542   endif()
 543 endif()
 544
 545 option(GMX_X11 "Use X window system" OFF)
 546 if (GMX_X11)
 547     find_package(X11)
 548     # X11 includes/libraries are only set in the ngmx subdirectory!
 549     if(NOT X11_FOUND)
 550         message(FATAL_ERROR
 551                 "X11 include files and/or libraries were not found. "
 552                 "Set GMX_X11=OFF to compile without X11 support. "
 553                 "gmx view will not be available.")
 554     endif()
 555     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 556 endif()
 557
 558 include(ThreadMPI)
 559 # Enable core threading facilities
 560 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 561 if(GMX_THREAD_MPI)
 562     # enable MPI functions
 563     tmpi_enable()
 564     set(MPI_IN_PLACE_EXISTS 1)
 565 endif()
 566 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 567 if (TMPI_ATOMICS_DISABLED)
 568    add_definitions(-DTMPI_ATOMICS_DISABLED)
 569 endif()
 570
 571 include(gmxManageTNG)
 572
 573 include(gmxManageLmfit)
 574
 575 if(GMX_GPU)
 576
 577     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 578     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 579         include(gmxManageCuda)
 580     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 581         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 582             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 583             "future releases of GROMACS.")
 584         include(gmxManageOpenCL)
 585     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 586         include(gmxManageSYCL)
 587     endif()
 588     if(NOT GMX_OPENMP)
 589         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 590     endif()
 591
 592 endif()
 593
 594 if(CYGWIN)
 595     set(GMX_CYGWIN 1)
 596 endif()
 597
 598 if(WIN32)
 599     set(GMX_NATIVE_WINDOWS 1)
 600     # This makes windows.h not declare min/max as macros that would break
 601     # C++ code using std::min/std::max.
 602     add_definitions(-DNOMINMAX)
 603 endif()
 604
 605 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 606 mark_as_advanced(GMX_BUILD_UNITTESTS)
 607 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 608
 609 ########################################################################
 610 # Our own GROMACS tests
 611 ########################################################################
 612
 613 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 614 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 615 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 616 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 617
 618 include(gmxTestInlineASM)
 619 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 620
 621 include(gmxSetBuildInformation)
 622 gmx_set_build_information()
 623
 624 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 625 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 626 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 627 mark_as_advanced(GMX_USE_RDTSCP)
 628
 629 include(gmxTestLargeFiles)
 630 gmx_test_large_files(GMX_LARGEFILES)
 631
 632 include(gmxTestSignal)
 633 gmx_test_sigusr1(HAVE_SIGUSR1)
 634
 635 include(gmxTestPipes)
 636 gmx_test_pipes(HAVE_PIPES)
 637
 638 include(gmxTestXDR)
 639 gmx_test_xdr(GMX_SYSTEM_XDR)
 640 # Darwin has system XDR, but it uses a three-argument flavour of
 641 # xdrproc_t that it guarantees will still work if you pass the normal
 642 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 643 # to do that, so it's simpler to just use our own XDR library.
 644 #
 645 # TODO It would be better to craft a cmake test which fails if such
 646 # XDR operations cause warnings, and succeeds otherwise, because it is
 647 # generally preferable to use system libraries where possible.
 648 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 649     set(GMX_INTERNAL_XDR 1)
 650 endif()
 651
 652
 653 ##################################################
 654 # Process SIMD instruction settings
 655 ##################################################
 656 # This checks what flags to add in order to
 657 # support the SIMD instructions we need, it sets
 658 # correct defines for the SIMD instructions supported,
 659 # and adds advanced options to control accuracy
 660 # for SIMD math operations.
 661 include(gmxManageSimd)
 662 gmx_manage_simd()
 663
 664 ##################################################
 665 # Process FFT library settings
 666 ##################################################
 667 include(gmxManageFFTLibraries)
 668
 669
 670 include(gmxManageLinearAlgebraLibraries)
 671
 672 include(gmxManagePluginSupport)
 673 gmx_manage_plugin_support()
 674
 675 if(GMX_USE_PLUGINS)
 676     if(NOT GMX_VMD_PLUGIN_PATH)
 677         find_package(VMD)
 678     endif()
 679 endif()
 680
 681 # People might want to customize the default location for the DSSP binary
 682 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 683     CACHE PATH
 684     "The default location to use for the DSSP binary")
 685 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 686
 687 # Link real-time library for POSIX timers. The check for clock_gettime
 688 # confirms the linkability of rt.
 689 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 690     list(APPEND GMX_EXTRA_LIBRARIES rt)
 691 endif()
 692
 693 # Math and thread libraries must often come after all others when linking...
 694 if (HAVE_LIBM)
 695     list(APPEND GMX_PUBLIC_LIBRARIES m)
 696 endif()
 697
 698 option(GMX_NACL "Configure for Native Client builds" OFF)
 699 if (GMX_NACL)
 700   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 701   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 702   # TODO: Is this still necessary with the check for its presence?
 703   set(GMX_USE_NICE 0)
 704   set(GMX_NO_RENAME 1)
 705 endif()
 706 mark_as_advanced(GMX_NACL)
 707
 708 if(GMX_FAHCORE)
 709   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 710       "Path to swindirect.h")
 711   include_directories(${COREWRAP_INCLUDE_DIR})
 712 endif()
 713
 714 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 715 mark_as_advanced(GMX_BUILD_HELP)
 716 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 717     message(FATAL_ERROR
 718         "Rebuilding shell completions or man pages is not supported for "
 719         "in-source builds from a source distribution. "
 720         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 721 endif()
 722
 723 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 724 # these are set after everything else
 725 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 726     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 727     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 728 else()
 729     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 730     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 731     foreach(build_type ${build_types_with_explicit_flags})
 732         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 733     endforeach()
 734     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 735     foreach(build_type ${build_types_with_explicit_flags})
 736         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 737     endforeach()
 738     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 739     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 740 endif()
 741 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 742 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 743
 744 ################################################################
 745 # Shared library load path settings
 746 ################################################################
 747 if(NOT GMX_BUILD_SHARED_EXE)
 748     # No rpath
 749     set(CMAKE_SKIP_RPATH TRUE)
 750     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 751     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 752 else()
 753     # The build folder always has bin/ and lib/; if we are also going to
 754     # install to lib/, then the installation RPATH works also in the build
 755     # tree.  This makes installation slightly faster (no need to rewrite the
 756     # RPATHs), and makes the binaries in the build tree relocatable.
 757     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 758         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 759         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 760     endif()
 761     # Set the RPATH as relative to the executable location to make the
 762     # binaries relocatable.
 763     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 764         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 765         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 766     else()
 767         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 768     endif()
 769     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 770     set(CMAKE_MACOSX_RPATH 1)
 771 endif()
 772
 773 #COPYING file: Only necessary for binary distributions.
 774 #Simpler to always install.
 775 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 776
 777 if (GMX_BUILD_FOR_COVERAGE)
 778     # Code heavy with asserts makes conditional coverage close to useless metric,
 779     # as by design most of the false branches are impossible to trigger in
 780     # correctly functioning code.  And the benefit of testing those that could
 781     # be triggered by using an API against its specification isn't usually
 782     # worth the effort.
 783     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 784 endif()
 785
 786 if (BUILD_TESTING)
 787     include(tests/CheckTarget.cmake)
 788 endif()
 789
 790 # TODO: Determine control flow and defaults for package installation and testing use cases.
 791 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 792 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 793 mark_as_advanced(GMX_PYTHON_PACKAGE)
 794
 795 if (NOT GMX_BUILD_MDRUN_ONLY)
 796     find_package(ImageMagick QUIET COMPONENTS convert)
 797     include(gmxTestImageMagick)
 798     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 799     # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 800     add_subdirectory(docs)
 801     add_subdirectory(share)
 802     add_subdirectory(scripts)
 803 endif()
 804 add_subdirectory(api)
 805 add_subdirectory(src)
 806
 807 if (BUILD_TESTING)
 808     add_subdirectory(tests)
 809 endif()
 810
 811 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 812     add_subdirectory(python_packaging)
 813 endif()
 814
 815 gmx_cpack_write_config()
 816
 817 #######################
 818 ## uninstall target
 819 #######################
 820 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 821                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 822                   IMMEDIATE @ONLY)
 823 ###########################
 824 ADD_CUSTOM_TARGET(uninstall
 825                   "${CMAKE_COMMAND}" -P
 826                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 827 ###########################
 828 set_directory_properties(PROPERTIES
 829             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")