CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.16.3)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40 cmake_policy(SET CMP0048 NEW) # As of CMake 3.22, default is still "OLD"
  41
  42 # CMake modules/macros are in a subdirectory to keep this file cleaner
  43 # This needs to be set before project() in order to pick up toolchain files
  44 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  45
  46 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  47     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  48     # such as by defaulting to the Clang libc++ instead of libstdc++.
  49     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  50         "OS X deployment target affects default SDK version and compiler flags.")
  51     # By default, limit the binary architecture to a single 64-bit build.
  52     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  54         FORCE)
  55 endif()
  56
  57 # The GROMACS convention is that these are the version number of the next
  58 # release that is going to be made from this branch.
  59 project(Gromacs VERSION 2022.0)
  60
  61 set(CMAKE_CXX_STANDARD 17)
  62 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  63 set(CMAKE_CXX_EXTENSIONS OFF)
  64
  65 include(gmxManageCcache)
  66
  67 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  68 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  69 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  70
  71 find_package(LibStdCpp)
  72
  73 # Python is first referenced in gmxVersionInfo, so we perform the search early
  74 # to find a suitable installation for all components.
  75 include(gmxPythonDiscovery)
  76 # Set up common version variables, as well as general information about
  77 # the build tree (whether the build is from a source package or from a git
  78 # repository).  Also declares a few functions that will be used for generating
  79 # version info files later.
  80 include(gmxBuildTreeInfo)
  81 include(gmxVersionInfo)
  82
  83 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  84     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  85 endif()
  86 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  87     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  88 endif()
  89
  90 include(gmxBuildTypeReference)
  91 include(gmxBuildTypeProfile)
  92 include(gmxBuildTypeTSAN)
  93 include(gmxBuildTypeASAN)
  94 include(gmxBuildTypeMSAN)
  95 include(gmxBuildTypeUBSAN)
  96 include(gmxBuildTypeReleaseWithAssert)
  97
  98 if(NOT CMAKE_BUILD_TYPE)
  99     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
 100     # Set the possible values of build type for cmake-gui
 101     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 102         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 103 endif()
 104 if(CMAKE_CONFIGURATION_TYPES)
 105     # Add appropriate GROMACS-specific build types for the Visual
 106     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 107     # are already present by default).
 108     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 109     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 110     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 111         "List of configuration types"
 112         FORCE)
 113 endif()
 114 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 115
 116 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 117
 118 include(gmxCTestUtilities)
 119 gmx_ctest_init()
 120
 121 include(gmxCPackUtilities)
 122 gmx_cpack_init()
 123
 124 # Variables that accumulate stuff influencing the installed headers
 125 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 126 set(INSTALLED_HEADER_DEFINITIONS "")
 127
 128 ########################################################################
 129 # Global non-cache variables for implementing the build system
 130 ########################################################################
 131
 132 # These variables collect libraries that GROMACS requires for
 133 # linking. They should be appended to with list(APPEND ${name}
 134 # new-library) calls. They are:
 135 #  - Libraries that are required for libgromacs (only)
 136 set(GMX_EXTRA_LIBRARIES "")
 137 #  - Libraries that are required for all code in the repository
 138 set(GMX_COMMON_LIBRARIES "")
 139 #  - Libraries that all code linked against libgromacs needs
 140 #    (i.e., something that is exposed in installed headers).
 141 set(GMX_PUBLIC_LIBRARIES "")
 142
 143 ########################################################################
 144 # Check and warn if cache generated on a different host is being reused
 145 ########################################################################
 146 if(CMAKE_HOST_UNIX)
 147     execute_process(COMMAND hostname
 148                     OUTPUT_VARIABLE TMP_HOSTNAME
 149                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 150     # Only check for host name if not running in a CI environment, as the cache might
 151     # be reused there between different machines in different stages
 152     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 153             AND NOT DEFINED ENV{CI_JOB_ID})
 154         message(WARNING "
 155             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 156             is being reused! This could lead to inconsistencies; therefore, it is
 157             recommended to regenerate the cache!")
 158     endif()
 159     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 160             "Hostname of the machine where the cache was generated.")
 161 endif()
 162
 163 ########################################################################
 164 # Detect architecture before setting options so we can alter defaults
 165 ########################################################################
 166 # Detect the architecture the compiler is targetting, detect
 167 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 168 # to use if none is specified, and populate the cache option for CPU
 169 # SIMD.
 170 include(gmxDetectTargetArchitecture)
 171 gmx_detect_target_architecture()
 172
 173 ########################################################################
 174 # User input options                                                   #
 175 ########################################################################
 176 include(gmxOptionUtilities)
 177
 178 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 179
 180 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 181
 182 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 183 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 184
 185 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 186
 187 option(GMX_CP2K "Enable CP2K QM/MM interface (CP2K 8.1 or later is required)" OFF)
 188
 189 # We need to enable Fortran, because CP2K will be linked
 190 if(GMX_CP2K)
 191     enable_language(Fortran)
 192 endif()
 193
 194 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 195 mark_as_advanced(GMX_FAHCORE)
 196
 197 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 198 mark_as_advanced(GMX_COOL_QUOTES)
 199 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 200
 201 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 202
 203 gmx_option_multichoice(
 204     GMX_GPU
 205     "Framework for GPU acceleration"
 206     OFF
 207     OFF CUDA OpenCL SYCL)
 208
 209 gmx_option_multichoice(
 210     GMX_SIMD
 211     "SIMD instruction set for CPU kernels and compiler optimization"
 212     "AUTO"
 213     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
 214
 215 include(gmxTestIntelLLVM)
 216
 217 if (GMX_INTEL_LLVM)
 218     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 219 else()
 220     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 221 endif()
 222
 223 gmx_option_multichoice(
 224     GMX_FFT_LIBRARY
 225     "FFT library"
 226     "${GMX_FFT_LIBRARY_DEFAULT}"
 227     fftw3 mkl "fftpack[built-in]")
 228 gmx_dependent_option(
 229     GMX_BUILD_OWN_FFTW
 230     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 231     OFF
 232     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 233 gmx_dependent_option(
 234     GMX_DISABLE_FFTW_MEASURE
 235     "Do not optimize FFTW setups (not needed with SSE)"
 236     OFF
 237     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 238 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 239 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 240
 241 gmx_dependent_option(
 242     GMX_USE_HEFFTE
 243     "Use HeFFTe for FFT support. Used with CUDA backend"
 244     OFF
 245     "GMX_GPU STREQUAL CUDA;GMX_MPI")
 246
 247 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 248 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 249
 250 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 251
 252 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 253 mark_as_advanced(GMX_BROKEN_CALLOC)
 254
 255 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 256
 257 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 258
 259 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 260 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 261
 262 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 263 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 264
 265 option(GMX_BUILD_FOR_COVERAGE
 266        "Tune build for better code coverage metrics (e.g., disable asserts)"
 267        OFF)
 268 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 269
 270 option(GMX_DEVELOPER_BUILD
 271     "Enable Developer convenience features: always build unit-tests"
 272     OFF)
 273 mark_as_advanced(GMX_DEVELOPER_BUILD)
 274
 275 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 276 option(GMX_COMPILER_WARNINGS
 277     "Enable a default set of compiler warnings"
 278     ${GMX_COMPILER_WARNINGS_DEFAULT})
 279 mark_as_advanced(GMX_COMPILER_WARNINGS)
 280 # Always turn on compiler warnings with a developer build.
 281 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 282
 283 option(GMX_BUILD_SHARED_EXE
 284     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 285     ON)
 286 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 287
 288 option(GMX_PHYSICAL_VALIDATION
 289        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 290        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 291        OFF)
 292 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 293
 294 ######################################################################
 295 # Detect OpenMP support
 296 ######################################################################
 297 # The OpenMP detection _must_ come before tests for other CFLAGS.
 298 include(gmxManageOpenMP)
 299
 300
 301
 302 ######################################################################
 303 # Compiler tests
 304 # These need to be done early (before further tests).
 305 #####################################################################
 306
 307 include(gmxCFlags)
 308 gmx_c_flags()
 309
 310 # These variables should be used for CMake-style lists (ie. separated
 311 # by semicolons) of additional compiler flags which are not generated
 312 # in gmxCFlags nor are SIMD or MPI related.
 313 #
 314 # TODO These variables should be consolidated into
 315 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 316 # things that work in C compilation (e.g. merging from old branches)
 317 # might not also work for C++ compilation.
 318 set(EXTRA_C_FLAGS "")
 319 set(EXTRA_CXX_FLAGS "")
 320
 321 # Run through a number of tests for buggy compilers and other issues
 322 include(gmxTestCompilerProblems)
 323 gmx_test_compiler_problems()
 324
 325 # Implement double-precision option. This is complicated because we
 326 # need installed headers to use the precision mode of the build that
 327 # produced the library, but cannot use config.h in that case. We also
 328 # want such variables to always have a definition, because #if is more
 329 # robust than #ifdef. So, we put this value on the compiler command
 330 # line in all cases.
 331 if(GMX_DOUBLE)
 332     set(GMX_DOUBLE_VALUE 1)
 333 else()
 334     set(GMX_DOUBLE_VALUE 0)
 335 endif()
 336 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 337 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 338
 339 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 340 if(GMX_IMD AND WIN32)
 341     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 342 endif()
 343
 344
 345
 346 ########################################################################
 347 # Basic system tests (standard libraries, headers, functions, types)   #
 348 ########################################################################
 349 include(CheckIncludeFiles)
 350 include(CheckIncludeFileCXX)
 351 check_include_files(unistd.h     HAVE_UNISTD_H)
 352 check_include_files(pwd.h        HAVE_PWD_H)
 353 check_include_files(dirent.h     HAVE_DIRENT_H)
 354 check_include_files(time.h       HAVE_TIME_H)
 355 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 356 check_include_files(io.h         HAVE_IO_H)
 357 check_include_files(sched.h      HAVE_SCHED_H)
 358 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 359
 360 include(CheckCXXSymbolExists)
 361 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 362 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 363 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 364 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 365 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 366 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 367 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 368 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 369
 370 # We cannot check for the __builtins as symbols, but check if code compiles
 371 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 372 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 373 if(MSVC)
 374     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 375     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 376 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 377     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 378     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 379 endif()
 380
 381 include(CheckLibraryExists)
 382 find_library(HAVE_LIBM m)
 383 mark_as_advanced(HAVE_LIBM)
 384 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 385 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 386 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 387
 388 include(TestSchedAffinity)
 389 test_sched_affinity(HAVE_SCHED_AFFINITY)
 390
 391 # Aligned memory allocation. We need to check for both mm_malloc(),
 392 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 393 include(gmxTestMMMalloc)
 394 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 395 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 396 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 397 if(MSVC)
 398     # No need to waste time on this test on platforms where it will never be true
 399     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 400 endif()
 401
 402 include(TestBigEndian)
 403 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 404
 405 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 406
 407 ########################################################################
 408 #Process MPI settings
 409 ########################################################################
 410 include(gmxManageMPI)
 411
 412 ########################################################################
 413 #Process MiMiC settings
 414 ########################################################################
 415 include(gmxManageMimic)
 416
 417 ########################################################################
 418 #Process CP2K settings
 419 ########################################################################
 420 include(gmxManageCP2K)
 421
 422 ########################################################################
 423 #Process shared/static library settings
 424 ########################################################################
 425 include(gmxManageSharedLibraries)
 426
 427
 428 ########################################################################
 429 # Specify install locations
 430 ########################################################################
 431 # Use GNUInstallDirs to set paths on multiarch systems.
 432 include(GNUInstallDirs)
 433
 434 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 435 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 436
 437 # Internal convenience so we do not have to join two path segments in the code
 438 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 439
 440 # If the nesting level wrt. the installation root is changed,
 441 # gromacs-config.cmake.cmakein needs to be adapted.
 442 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 443
 444 # TODO: Make GMXRC adapt if this is changed
 445 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 446
 447 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 448
 449 # Binary and library suffix options
 450 include(gmxManageSuffixes)
 451
 452
 453 ########################################################################
 454 # Find external packages                                               #
 455 ########################################################################
 456
 457 # Unconditionally find the package, as it is also required for unit
 458 # tests. This exports LIBXML2_FOUND, which we should not use because
 459 # it does not tell us that linking will succeed. Instead, we test that
 460 # next.
 461 #if(DEFINED LIBXML2_LIBRARIES)
 462 #  set(LibXml2_FIND_QUIETLY TRUE)
 463 #endif()
 464 #find_package(LibXml2)
 465 #include(gmxTestLibXml2)
 466 #gmx_test_libxml2(HAVE_LIBXML2)
 467 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 468 #set(PKG_XML "")
 469 #mark_as_advanced(GMX_XML)
 470 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 471 #if(GMX_XML AND NOT HAVE_LIBXML2)
 472 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 473 #endif()
 474 #if(GMX_XML)
 475 #    include_directories(${LIBXML2_INCLUDE_DIR})
 476 #    set(PKG_XML libxml-2.0)
 477 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 478 #endif()
 479
 480 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 481
 482 if (GMX_HWLOC)
 483     # Find quietly the second time.
 484     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 485         set(HWLOC_FIND_QUIETLY TRUE)
 486     endif()
 487     find_package(HWLOC 1.5)
 488
 489     if (HWLOC_FOUND)
 490         if (HWLOC_LIBRARIES MATCHES ".a$")
 491             set(_STATIC_HWLOC TRUE)
 492         endif()
 493
 494         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 495         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 496             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 497             set(GMX_USE_HWLOC OFF)
 498         else()
 499             set(GMX_USE_HWLOC ON)
 500         endif()
 501
 502         if (GMX_USE_HWLOC)
 503             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 504             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 505         endif()
 506     elseif(GMX_HWLOC_FORCE)
 507         message(FATAL_ERROR "HWLOC package support required, but not found.")
 508     endif()
 509
 510     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 511         message(STATUS "Support for hwloc versions 1.x is deprecated")
 512     endif()
 513
 514     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 515 endif()
 516
 517 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 518 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 519 if(GMX_EXTERNAL_TINYXML2)
 520     # Find an external TinyXML-2 library.
 521     find_package(TinyXML-2 3.0.0)
 522     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 523     if(NOT HAVE_TINYXML2)
 524         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 525     endif()
 526 endif()
 527
 528 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 529 mark_as_advanced(GMX_EXTRAE)
 530
 531 if (GMX_EXTRAE)
 532   find_package(EXTRAE)
 533   if(EXTRAE_FOUND)
 534     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 535     set(HAVE_EXTRAE 1)
 536   else()
 537     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 538   endif()
 539 endif()
 540
 541 option(GMX_X11 "Use X window system" OFF)
 542 if (GMX_X11)
 543     find_package(X11)
 544     # X11 includes/libraries are only set in the ngmx subdirectory!
 545     if(NOT X11_FOUND)
 546         message(FATAL_ERROR
 547                 "X11 include files and/or libraries were not found. "
 548                 "Set GMX_X11=OFF to compile without X11 support. "
 549                 "gmx view will not be available.")
 550     endif()
 551     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 552 endif()
 553
 554 include(ThreadMPI)
 555 # Enable core threading facilities
 556 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 557 if(GMX_THREAD_MPI)
 558     # enable MPI functions
 559     tmpi_enable()
 560 endif()
 561 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 562 if (TMPI_ATOMICS_DISABLED)
 563    add_definitions(-DTMPI_ATOMICS_DISABLED)
 564 endif()
 565
 566 include(gmxManageTNG)
 567
 568 include(gmxManageLmfit)
 569
 570 include(gmxManageMuparser)
 571
 572 ##################################################
 573 # Process SIMD instruction settings
 574 ##################################################
 575 # This checks what flags to add in order to
 576 # support the SIMD instructions we need, it sets
 577 # correct defines for the SIMD instructions supported,
 578 # and adds advanced options to control accuracy
 579 # for SIMD math operations.
 580 include(gmxManageSimd)
 581 gmx_manage_simd()
 582
 583
 584 if(GMX_GPU)
 585
 586     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 587     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 588         include(gmxManageCuda)
 589     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 590         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 591             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 592             "future releases of GROMACS.")
 593         include(gmxManageOpenCL)
 594     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 595         include(gmxManageSYCL)
 596     endif()
 597     if(NOT GMX_OPENMP)
 598         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 599     endif()
 600
 601     if (GMX_OPENCL_NB_CLUSTER_SIZE)
 602         message(WARNING "GMX_OPENCL_NB_CLUSTER_SIZE is deprecated, use GMX_GPU_NB_CLUSTER_SIZE instead")
 603     endif()
 604     if (GMX_OPENCL_NB_CLUSTER_SIZE AND GMX_GPU_NB_CLUSTER_SIZE)
 605         if (NOT ${GMX_OPENCL_NB_CLUSTER_SIZE} EQUAL ${GMX_GPU_NB_CLUSTER_SIZE})
 606             message(FATAL_ERROR "Mismatching values passed to GMX_OPENCL_NB_CLUSTER_SIZE and GMX_GPU_NB_CLUSTER_SIZE; the former is deprecated, use only the latter!")
 607         endif()
 608     endif()
 609     # Only OpenCL and SYCL support changing the default cluster size
 610     if (${_gmx_gpu_uppercase} STREQUAL "CUDA")
 611         if (GMX_GPU_NB_CLUSTER_SIZE AND NOT "${GMX_GPU_NB_CLUSTER_SIZE}" EQUAL 8)
 612             message(FATAL_ERROR "Setting GMX_GPU_NB_CLUSTER_SIZE is not supported in CUDA (the default GMX_GPU_NB_CLUSTER_SIZE=8 is used)")
 613         endif()
 614     else()
 615         # use the legacy GMX_OPENCL_NB_CLUSTER_SIZE variable if set, otherwise set the defaults
 616         if (GMX_OPENCL_NB_CLUSTER_SIZE)
 617             set(_gmx_gpu_nb_cluster_size_value ${GMX_OPENCL_NB_CLUSTER_SIZE})
 618         else()
 619             # default cluster size is 8 with OpenCL and 4 with SYCL for now
 620             if(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 621                 set(_gmx_gpu_nb_cluster_size_value 8)
 622             elseif(GMX_GPU_SYCL)
 623                 if (GMX_SYCL_HIPSYCL AND NOT GMX_HIPSYCL_HAVE_LEVELZERO_TARGET)
 624                     set(_gmx_gpu_nb_cluster_size_value 8)
 625                 else()
 626                     # Either DPCPP or hipSYCL targeting Intel Level0
 627                     set(_gmx_gpu_nb_cluster_size_value 4)
 628                 endif()
 629             endif()
 630         endif()
 631         set(GMX_GPU_NB_CLUSTER_SIZE ${_gmx_gpu_nb_cluster_size_value} CACHE STRING "Cluster size used by the nonbonded kernel. Set to 4 for Intel GPUs.")
 632         mark_as_advanced(GMX_GPU_NB_CLUSTER_SIZE)
 633     endif()
 634
 635 endif()
 636
 637 # For build with CUDA and Lib-MPI, check if underlying MPI implementation is CUDA-aware
 638 # CUDA-aware MPI allows direct GPU communication without staging data through host
 639 if(GMX_GPU_CUDA AND GMX_LIB_MPI)
 640     include(gmxManageCudaAwareMPI)
 641 else()
 642     set(HAVE_CUDA_AWARE_MPI 0)
 643 endif()
 644
 645 if(CYGWIN)
 646     set(GMX_CYGWIN 1)
 647 endif()
 648
 649 if(GMX_USE_HEFFTE)
 650     if(NOT GMX_GPU_CUDA)
 651         message(FATAL_ERROR "HeFFTe support requires a CUDA build")
 652     endif()
 653     if(NOT GMX_LIB_MPI)
 654         message(FATAL_ERROR "HeFFTe support requires a library MPI build")
 655     endif()
 656     find_package(Heffte 2.1.0 REQUIRED CUDA)
 657 endif()
 658
 659 if(WIN32)
 660     set(GMX_NATIVE_WINDOWS 1)
 661     # This makes windows.h not declare min/max as macros that would break
 662     # C++ code using std::min/std::max.
 663     add_definitions(-DNOMINMAX)
 664 endif()
 665
 666 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 667 mark_as_advanced(GMX_BUILD_UNITTESTS)
 668 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 669
 670 ########################################################################
 671 # Our own GROMACS tests
 672 ########################################################################
 673
 674 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 675
 676 include(gmxTestInlineASM)
 677 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 678
 679 include(gmxSetBuildInformation)
 680 gmx_set_build_information()
 681
 682 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 683 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 684 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 685 mark_as_advanced(GMX_USE_RDTSCP)
 686
 687 include(gmxTestLargeFiles)
 688 gmx_test_large_files(GMX_LARGEFILES)
 689
 690 include(gmxTestSignal)
 691 gmx_test_sigusr1(HAVE_SIGUSR1)
 692
 693 include(gmxTestPipes)
 694 gmx_test_pipes(HAVE_PIPES)
 695
 696 include(gmxTestXDR)
 697 gmx_test_xdr(GMX_SYSTEM_XDR)
 698 # Darwin has system XDR, but it uses a three-argument flavour of
 699 # xdrproc_t that it guarantees will still work if you pass the normal
 700 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 701 # to do that, so it's simpler to just use our own XDR library.
 702 #
 703 # TODO It would be better to craft a cmake test which fails if such
 704 # XDR operations cause warnings, and succeeds otherwise, because it is
 705 # generally preferable to use system libraries where possible.
 706 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 707     set(GMX_INTERNAL_XDR 1)
 708 endif()
 709
 710 ##################################################
 711 # Process FFT library settings
 712 ##################################################
 713 include(gmxManageFFTLibraries)
 714
 715
 716 include(gmxManageLinearAlgebraLibraries)
 717
 718 include(gmxManagePluginSupport)
 719 gmx_manage_plugin_support()
 720
 721 if(GMX_USE_PLUGINS)
 722     if(NOT GMX_VMD_PLUGIN_PATH)
 723         find_package(VMD)
 724     endif()
 725 endif()
 726
 727 # People might want to customize the default location for the DSSP binary
 728 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 729     CACHE PATH
 730     "The default location to use for the DSSP binary")
 731 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 732
 733 # Link real-time library for POSIX timers. The check for clock_gettime
 734 # confirms the linkability of rt.
 735 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 736     list(APPEND GMX_EXTRA_LIBRARIES rt)
 737 endif()
 738
 739 # Math and thread libraries must often come after all others when linking...
 740 if (HAVE_LIBM)
 741     list(APPEND GMX_PUBLIC_LIBRARIES m)
 742 endif()
 743
 744 option(GMX_NACL "Configure for Native Client builds" OFF)
 745 if (GMX_NACL)
 746   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 747   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 748   # TODO: Is this still necessary with the check for its presence?
 749   set(GMX_USE_NICE 0)
 750   set(GMX_NO_RENAME 1)
 751 endif()
 752 mark_as_advanced(GMX_NACL)
 753
 754 if(GMX_FAHCORE)
 755   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 756       "Path to swindirect.h")
 757   include_directories(${COREWRAP_INCLUDE_DIR})
 758 endif()
 759
 760 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 761 mark_as_advanced(GMX_BUILD_HELP)
 762 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 763     message(FATAL_ERROR
 764         "Rebuilding shell completions or man pages is not supported for "
 765         "in-source builds from a source distribution. "
 766         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 767 endif()
 768
 769 if (GMX_BUILD_FOR_COVERAGE)
 770     # Set flags for coverage build here instead having to do so manually
 771     set(CMAKE_C_FLAGS "-g --coverage")
 772     set(CMAKE_CXX_FLAGS "-g --coverage")
 773 endif()
 774
 775 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 776 # these are set after everything else
 777 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 778     #TODO(#3672): Use target_link_libraries(... MPI::MPI_CXX) instead of ${MPI_CXX_LINK_FLAGS}
 779     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 780     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 781 else()
 782     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 783     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 784     foreach(build_type ${build_types_with_explicit_flags})
 785         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 786     endforeach()
 787     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 788     foreach(build_type ${build_types_with_explicit_flags})
 789         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 790     endforeach()
 791     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 792     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 793 endif()
 794 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 795 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 796
 797 ################################################################
 798 # Shared library load path settings
 799 ################################################################
 800 if(NOT GMX_BUILD_SHARED_EXE)
 801     # No rpath
 802     set(CMAKE_SKIP_RPATH TRUE)
 803     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 804     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 805 else()
 806     # The build folder always has bin/ and lib/; if we are also going to
 807     # install to lib/, then the installation RPATH works also in the build
 808     # tree.  This makes installation slightly faster (no need to rewrite the
 809     # RPATHs), and makes the binaries in the build tree relocatable.
 810     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 811         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 812         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 813     endif()
 814     # Set the RPATH as relative to the executable location to make the
 815     # binaries relocatable.
 816     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 817         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 818         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 819     else()
 820         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 821     endif()
 822     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 823     set(CMAKE_MACOSX_RPATH 1)
 824 endif()
 825
 826 #COPYING file: Only necessary for binary distributions.
 827 #Simpler to always install.
 828 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 829
 830 if (BUILD_TESTING)
 831     include(tests/CheckTarget.cmake)
 832 endif()
 833
 834 option(GMX_PYTHON_PACKAGE
 835        "Configure gmxapi Python package for use in build tree. Requires pybind11 installed for project Python interpreter."
 836        OFF)
 837 mark_as_advanced(GMX_PYTHON_PACKAGE)
 838
 839 find_package(ImageMagick QUIET COMPONENTS convert)
 840 include(gmxTestImageMagick)
 841 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 842 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 843 add_subdirectory(docs)
 844 add_subdirectory(share)
 845 add_subdirectory(scripts)
 846 add_subdirectory(api)
 847 add_subdirectory(src)
 848
 849 if (BUILD_TESTING)
 850     add_subdirectory(tests)
 851 endif()
 852
 853 if(GMX_PYTHON_PACKAGE)
 854     add_subdirectory(python_packaging)
 855 endif()
 856
 857 gmx_cpack_write_config()
 858
 859 #######################
 860 ## uninstall target
 861 #######################
 862 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 863                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 864                   IMMEDIATE @ONLY)
 865 ###########################
 866 ADD_CUSTOM_TARGET(uninstall
 867                   "${CMAKE_COMMAND}" -P
 868                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 869 ###########################
 870 set_directory_properties(PROPERTIES
 871             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")