CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.16.3)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags.")
  50     # By default, limit the binary architecture to a single 64-bit build.
  51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  53         FORCE)
  54 endif()
  55
  56 project(Gromacs)
  57
  58 set(CMAKE_CXX_STANDARD 17)
  59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  60 set(CMAKE_CXX_EXTENSIONS OFF)
  61
  62 include(gmxManageCcache)
  63
  64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  67
  68 find_package(LibStdCpp)
  69
  70 # Python is first referenced in gmxVersionInfo, so we perform the search early
  71 # to find a suitable installation for all components.
  72 include(gmxPythonDiscovery)
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeUBSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 178
 179 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 180 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 181
 182 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 183
 184 option(GMX_CP2K "Enable CP2K QM/MM interface (CP2K 8.1 or later is required)" OFF)
 185
 186 # We need to enable Fortran, because CP2K will be linked
 187 if(GMX_CP2K)
 188     enable_language(Fortran)
 189 endif()
 190
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 199
 200 gmx_option_multichoice(
 201     GMX_GPU
 202     "Framework for GPU acceleration"
 203     OFF
 204     OFF CUDA OpenCL SYCL)
 205
 206 gmx_option_multichoice(
 207     GMX_SIMD
 208     "SIMD instruction set for CPU kernels and compiler optimization"
 209     "AUTO"
 210     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
 211
 212 set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 213
 214 gmx_option_multichoice(
 215     GMX_FFT_LIBRARY
 216     "FFT library"
 217     "${GMX_FFT_LIBRARY_DEFAULT}"
 218     fftw3 mkl "fftpack[built-in]")
 219 gmx_dependent_option(
 220     GMX_BUILD_OWN_FFTW
 221     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 222     OFF
 223     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 224 gmx_dependent_option(
 225     GMX_DISABLE_FFTW_MEASURE
 226     "Do not optimize FFTW setups (not needed with SSE)"
 227     OFF
 228     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 229 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 230 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 231
 232 gmx_dependent_option(
 233     GMX_USE_HEFFTE
 234     "Use HeFFTe for FFT support. Used with CUDA backend"
 235     OFF
 236     "GMX_GPU STREQUAL CUDA;GMX_MPI")
 237
 238 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 239 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 240
 241 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 242
 243 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 244 mark_as_advanced(GMX_BROKEN_CALLOC)
 245
 246 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 247
 248 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 249
 250 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 251 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 252
 253 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 254 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 255
 256 option(GMX_BUILD_FOR_COVERAGE
 257        "Tune build for better code coverage metrics (e.g., disable asserts)"
 258        OFF)
 259 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 260
 261 option(GMX_DEVELOPER_BUILD
 262     "Enable Developer convenience features: always build unit-tests"
 263     OFF)
 264 mark_as_advanced(GMX_DEVELOPER_BUILD)
 265
 266 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 267 option(GMX_COMPILER_WARNINGS
 268     "Enable a default set of compiler warnings"
 269     ${GMX_COMPILER_WARNINGS_DEFAULT})
 270 mark_as_advanced(GMX_COMPILER_WARNINGS)
 271 # Always turn on compiler warnings with a developer build.
 272 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 273
 274 option(GMX_BUILD_SHARED_EXE
 275     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 276     ON)
 277 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 278
 279 option(GMX_PHYSICAL_VALIDATION
 280        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 281        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 282        OFF)
 283 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 284
 285 ######################################################################
 286 # Detect OpenMP support
 287 ######################################################################
 288 # The OpenMP detection _must_ come before tests for other CFLAGS.
 289 include(gmxManageOpenMP)
 290
 291
 292
 293 ######################################################################
 294 # Compiler tests
 295 # These need to be done early (before further tests).
 296 #####################################################################
 297
 298 include(gmxTestIntelLLVM)
 299 include(gmxCFlags)
 300 gmx_c_flags()
 301
 302 # These variables should be used for CMake-style lists (ie. separated
 303 # by semicolons) of additional compiler flags which are not generated
 304 # in gmxCFlags nor are SIMD or MPI related.
 305 #
 306 # TODO These variables should be consolidated into
 307 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 308 # things that work in C compilation (e.g. merging from old branches)
 309 # might not also work for C++ compilation.
 310 set(EXTRA_C_FLAGS "")
 311 set(EXTRA_CXX_FLAGS "")
 312
 313 # Run through a number of tests for buggy compilers and other issues
 314 include(gmxTestCompilerProblems)
 315 gmx_test_compiler_problems()
 316
 317 # Implement double-precision option. This is complicated because we
 318 # need installed headers to use the precision mode of the build that
 319 # produced the library, but cannot use config.h in that case. We also
 320 # want such variables to always have a definition, because #if is more
 321 # robust than #ifdef. So, we put this value on the compiler command
 322 # line in all cases.
 323 if(GMX_DOUBLE)
 324     set(GMX_DOUBLE_VALUE 1)
 325 else()
 326     set(GMX_DOUBLE_VALUE 0)
 327 endif()
 328 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 329 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 330
 331 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 332 if(GMX_IMD AND WIN32)
 333     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 334 endif()
 335
 336
 337
 338 ########################################################################
 339 # Basic system tests (standard libraries, headers, functions, types)   #
 340 ########################################################################
 341 include(CheckIncludeFiles)
 342 include(CheckIncludeFileCXX)
 343 check_include_files(unistd.h     HAVE_UNISTD_H)
 344 check_include_files(pwd.h        HAVE_PWD_H)
 345 check_include_files(dirent.h     HAVE_DIRENT_H)
 346 check_include_files(time.h       HAVE_TIME_H)
 347 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 348 check_include_files(io.h         HAVE_IO_H)
 349 check_include_files(sched.h      HAVE_SCHED_H)
 350 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 351
 352 include(CheckCXXSymbolExists)
 353 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 354 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 355 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 356 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 357 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 358 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 359 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 360 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 361
 362 # We cannot check for the __builtins as symbols, but check if code compiles
 363 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 364 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 365 if(MSVC)
 366     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 367     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 368 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 369     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 370     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 371 endif()
 372
 373 include(CheckLibraryExists)
 374 find_library(HAVE_LIBM m)
 375 mark_as_advanced(HAVE_LIBM)
 376 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 377 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 378 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 379
 380 include(TestSchedAffinity)
 381 test_sched_affinity(HAVE_SCHED_AFFINITY)
 382
 383 # Aligned memory allocation. We need to check for both mm_malloc(),
 384 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 385 include(gmxTestMMMalloc)
 386 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 387 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 388 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 389 if(MSVC)
 390     # No need to waste time on this test on platforms where it will never be true
 391     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 392 endif()
 393
 394 include(TestBigEndian)
 395 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 396
 397 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 398
 399 ########################################################################
 400 #Process MPI settings
 401 ########################################################################
 402 include(gmxManageMPI)
 403
 404 ########################################################################
 405 #Process MiMiC settings
 406 ########################################################################
 407 include(gmxManageMimic)
 408
 409 ########################################################################
 410 #Process CP2K settings
 411 ########################################################################
 412 include(gmxManageCP2K)
 413
 414 ########################################################################
 415 #Process shared/static library settings
 416 ########################################################################
 417 include(gmxManageSharedLibraries)
 418
 419
 420 ########################################################################
 421 # Specify install locations
 422 ########################################################################
 423 # Use GNUInstallDirs to set paths on multiarch systems.
 424 include(GNUInstallDirs)
 425
 426 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 427 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 428
 429 # Internal convenience so we do not have to join two path segments in the code
 430 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 431
 432 # If the nesting level wrt. the installation root is changed,
 433 # gromacs-config.cmake.cmakein needs to be adapted.
 434 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 435
 436 # TODO: Make GMXRC adapt if this is changed
 437 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 438
 439 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 440
 441 # Binary and library suffix options
 442 include(gmxManageSuffixes)
 443
 444
 445 ########################################################################
 446 # Find external packages                                               #
 447 ########################################################################
 448
 449 # Unconditionally find the package, as it is also required for unit
 450 # tests. This exports LIBXML2_FOUND, which we should not use because
 451 # it does not tell us that linking will succeed. Instead, we test that
 452 # next.
 453 #if(DEFINED LIBXML2_LIBRARIES)
 454 #  set(LibXml2_FIND_QUIETLY TRUE)
 455 #endif()
 456 #find_package(LibXml2)
 457 #include(gmxTestLibXml2)
 458 #gmx_test_libxml2(HAVE_LIBXML2)
 459 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 460 #set(PKG_XML "")
 461 #mark_as_advanced(GMX_XML)
 462 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 463 #if(GMX_XML AND NOT HAVE_LIBXML2)
 464 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 465 #endif()
 466 #if(GMX_XML)
 467 #    include_directories(${LIBXML2_INCLUDE_DIR})
 468 #    set(PKG_XML libxml-2.0)
 469 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 470 #endif()
 471
 472 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 473
 474 if (GMX_HWLOC)
 475     # Find quietly the second time.
 476     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 477         set(HWLOC_FIND_QUIETLY TRUE)
 478     endif()
 479     find_package(HWLOC 1.5)
 480
 481     if (HWLOC_FOUND)
 482         if (HWLOC_LIBRARIES MATCHES ".a$")
 483             set(_STATIC_HWLOC TRUE)
 484         endif()
 485
 486         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 487         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 488             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 489             set(GMX_USE_HWLOC OFF)
 490         else()
 491             set(GMX_USE_HWLOC ON)
 492         endif()
 493
 494         if (GMX_USE_HWLOC)
 495             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 496             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 497         endif()
 498     elseif(GMX_HWLOC_FORCE)
 499         message(FATAL_ERROR "HWLOC package support required, but not found.")
 500     endif()
 501
 502     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 503         message(STATUS "Support for hwloc versions 1.x is deprecated")
 504     endif()
 505
 506     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 507 endif()
 508
 509 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 510 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 511 if(GMX_EXTERNAL_TINYXML2)
 512     # Find an external TinyXML-2 library.
 513     find_package(TinyXML-2 3.0.0)
 514     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 515     if(NOT HAVE_TINYXML2)
 516         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 517     endif()
 518 endif()
 519
 520 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 521 mark_as_advanced(GMX_EXTRAE)
 522
 523 if (GMX_EXTRAE)
 524   find_package(EXTRAE)
 525   if(EXTRAE_FOUND)
 526     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 527     set(HAVE_EXTRAE 1)
 528   else()
 529     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 530   endif()
 531 endif()
 532
 533 option(GMX_X11 "Use X window system" OFF)
 534 if (GMX_X11)
 535     find_package(X11)
 536     # X11 includes/libraries are only set in the ngmx subdirectory!
 537     if(NOT X11_FOUND)
 538         message(FATAL_ERROR
 539                 "X11 include files and/or libraries were not found. "
 540                 "Set GMX_X11=OFF to compile without X11 support. "
 541                 "gmx view will not be available.")
 542     endif()
 543     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 544 endif()
 545
 546 include(ThreadMPI)
 547 # Enable core threading facilities
 548 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 549 if(GMX_THREAD_MPI)
 550     # enable MPI functions
 551     tmpi_enable()
 552 endif()
 553 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 554 if (TMPI_ATOMICS_DISABLED)
 555    add_definitions(-DTMPI_ATOMICS_DISABLED)
 556 endif()
 557
 558 include(gmxManageTNG)
 559
 560 include(gmxManageLmfit)
 561
 562 include(gmxManageMuparser)
 563
 564 if(GMX_GPU)
 565
 566     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 567     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 568         include(gmxManageCuda)
 569     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 570         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 571             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 572             "future releases of GROMACS.")
 573         include(gmxManageOpenCL)
 574     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 575         include(gmxManageSYCL)
 576     endif()
 577     if(NOT GMX_OPENMP)
 578         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 579     endif()
 580
 581     if (GMX_OPENCL_NB_CLUSTER_SIZE)
 582         message(WARNING "GMX_OPENCL_NB_CLUSTER_SIZE is deprecated, use GMX_GPU_NB_CLUSTER_SIZE instead")
 583     endif()
 584     if (GMX_OPENCL_NB_CLUSTER_SIZE AND GMX_GPU_NB_CLUSTER_SIZE)
 585         if (NOT ${GMX_OPENCL_NB_CLUSTER_SIZE} EQUAL ${GMX_GPU_NB_CLUSTER_SIZE})
 586             message(FATAL_ERROR "Mismatching values passed to GMX_OPENCL_NB_CLUSTER_SIZE and GMX_GPU_NB_CLUSTER_SIZE; the former is deprecated, use only the latter!")
 587         endif()
 588     endif()
 589     # Only OpenCL and SYCL support changing the default cluster size
 590     if (${_gmx_gpu_uppercase} STREQUAL "CUDA")
 591         if (GMX_GPU_NB_CLUSTER_SIZE AND NOT "${GMX_GPU_NB_CLUSTER_SIZE}" EQUAL 8)
 592             message(FATAL_ERROR "Setting GMX_GPU_NB_CLUSTER_SIZE is not supported in CUDA (the default GMX_GPU_NB_CLUSTER_SIZE=8 is used)")
 593         endif()
 594     else()
 595         # use the legacy GMX_OPENCL_NB_CLUSTER_SIZE variable if set, otherwise set the defaults
 596         if (GMX_OPENCL_NB_CLUSTER_SIZE)
 597             set(_gmx_gpu_nb_cluster_size_value ${GMX_OPENCL_NB_CLUSTER_SIZE})
 598         else()
 599             # default cluster size is 8 with OpenCL and 4 with SYCL for now
 600             if(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 601                 set(_gmx_gpu_nb_cluster_size_value 8)
 602             elseif(GMX_GPU_SYCL)
 603                 if (GMX_SYCL_HIPSYCL AND NOT GMX_HIPSYCL_HAVE_LEVELZERO_TARGET)
 604                     set(_gmx_gpu_nb_cluster_size_value 8)
 605                 else()
 606                     # Either DPCPP or hipSYCL targeting Intel Level0
 607                     set(_gmx_gpu_nb_cluster_size_value 4)
 608                 endif()
 609             endif()
 610         endif()
 611         set(GMX_GPU_NB_CLUSTER_SIZE ${_gmx_gpu_nb_cluster_size_value} CACHE STRING "Cluster size used by the nonbonded kernel. Set to 4 for Intel GPUs.")
 612         mark_as_advanced(GMX_GPU_NB_CLUSTER_SIZE)
 613     endif()
 614
 615 endif()
 616
 617 # For build with CUDA and Lib-MPI, check if underlying MPI implementation is CUDA-aware
 618 # CUDA-aware MPI allows direct GPU communication without staging data through host
 619 if(GMX_GPU_CUDA AND GMX_LIB_MPI)
 620     include(gmxManageCudaAwareMPI)
 621 else()
 622     set(HAVE_CUDA_AWARE_MPI 0)
 623 endif()
 624
 625 if(CYGWIN)
 626     set(GMX_CYGWIN 1)
 627 endif()
 628
 629 if(GMX_USE_HEFFTE)
 630     if(NOT GMX_GPU_CUDA)
 631         message(FATAL_ERROR "HeFFTe support requires a CUDA build")
 632     endif()
 633     if(NOT GMX_LIB_MPI)
 634         message(FATAL_ERROR "HeFFTe support requires a library MPI build")
 635     endif()
 636     find_package(Heffte 2.1.0 REQUIRED CUDA)
 637 endif()
 638
 639 if(WIN32)
 640     set(GMX_NATIVE_WINDOWS 1)
 641     # This makes windows.h not declare min/max as macros that would break
 642     # C++ code using std::min/std::max.
 643     add_definitions(-DNOMINMAX)
 644 endif()
 645
 646 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 647 mark_as_advanced(GMX_BUILD_UNITTESTS)
 648 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 649
 650 ########################################################################
 651 # Our own GROMACS tests
 652 ########################################################################
 653
 654 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 655
 656 include(gmxTestInlineASM)
 657 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 658
 659 include(gmxSetBuildInformation)
 660 gmx_set_build_information()
 661
 662 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 663 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 664 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 665 mark_as_advanced(GMX_USE_RDTSCP)
 666
 667 include(gmxTestLargeFiles)
 668 gmx_test_large_files(GMX_LARGEFILES)
 669
 670 include(gmxTestSignal)
 671 gmx_test_sigusr1(HAVE_SIGUSR1)
 672
 673 include(gmxTestPipes)
 674 gmx_test_pipes(HAVE_PIPES)
 675
 676 include(gmxTestXDR)
 677 gmx_test_xdr(GMX_SYSTEM_XDR)
 678 # Darwin has system XDR, but it uses a three-argument flavour of
 679 # xdrproc_t that it guarantees will still work if you pass the normal
 680 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 681 # to do that, so it's simpler to just use our own XDR library.
 682 #
 683 # TODO It would be better to craft a cmake test which fails if such
 684 # XDR operations cause warnings, and succeeds otherwise, because it is
 685 # generally preferable to use system libraries where possible.
 686 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 687     set(GMX_INTERNAL_XDR 1)
 688 endif()
 689
 690
 691 ##################################################
 692 # Process SIMD instruction settings
 693 ##################################################
 694 # This checks what flags to add in order to
 695 # support the SIMD instructions we need, it sets
 696 # correct defines for the SIMD instructions supported,
 697 # and adds advanced options to control accuracy
 698 # for SIMD math operations.
 699 include(gmxManageSimd)
 700 gmx_manage_simd()
 701
 702 ##################################################
 703 # Process FFT library settings
 704 ##################################################
 705 include(gmxManageFFTLibraries)
 706
 707
 708 include(gmxManageLinearAlgebraLibraries)
 709
 710 include(gmxManagePluginSupport)
 711 gmx_manage_plugin_support()
 712
 713 if(GMX_USE_PLUGINS)
 714     if(NOT GMX_VMD_PLUGIN_PATH)
 715         find_package(VMD)
 716     endif()
 717 endif()
 718
 719 # People might want to customize the default location for the DSSP binary
 720 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 721     CACHE PATH
 722     "The default location to use for the DSSP binary")
 723 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 724
 725 # Link real-time library for POSIX timers. The check for clock_gettime
 726 # confirms the linkability of rt.
 727 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 728     list(APPEND GMX_EXTRA_LIBRARIES rt)
 729 endif()
 730
 731 # Math and thread libraries must often come after all others when linking...
 732 if (HAVE_LIBM)
 733     list(APPEND GMX_PUBLIC_LIBRARIES m)
 734 endif()
 735
 736 option(GMX_NACL "Configure for Native Client builds" OFF)
 737 if (GMX_NACL)
 738   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 739   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 740   # TODO: Is this still necessary with the check for its presence?
 741   set(GMX_USE_NICE 0)
 742   set(GMX_NO_RENAME 1)
 743 endif()
 744 mark_as_advanced(GMX_NACL)
 745
 746 if(GMX_FAHCORE)
 747   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 748       "Path to swindirect.h")
 749   include_directories(${COREWRAP_INCLUDE_DIR})
 750 endif()
 751
 752 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 753 mark_as_advanced(GMX_BUILD_HELP)
 754 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 755     message(FATAL_ERROR
 756         "Rebuilding shell completions or man pages is not supported for "
 757         "in-source builds from a source distribution. "
 758         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 759 endif()
 760
 761 if (GMX_BUILD_FOR_COVERAGE)
 762     # Set flags for coverage build here instead having to do so manually
 763     set(CMAKE_C_FLAGS "-g --coverage")
 764     set(CMAKE_CXX_FLAGS "-g --coverage")
 765 endif()
 766
 767 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 768 # these are set after everything else
 769 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 770     #TODO(#3672): Use target_link_libraries(... MPI::MPI_CXX) instead of ${MPI_CXX_LINK_FLAGS}
 771     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 772     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 773 else()
 774     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 775     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 776     foreach(build_type ${build_types_with_explicit_flags})
 777         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 778     endforeach()
 779     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 780     foreach(build_type ${build_types_with_explicit_flags})
 781         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 782     endforeach()
 783     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 784     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
 785 endif()
 786 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 787 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 788
 789 ################################################################
 790 # Shared library load path settings
 791 ################################################################
 792 if(NOT GMX_BUILD_SHARED_EXE)
 793     # No rpath
 794     set(CMAKE_SKIP_RPATH TRUE)
 795     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 796     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 797 else()
 798     # The build folder always has bin/ and lib/; if we are also going to
 799     # install to lib/, then the installation RPATH works also in the build
 800     # tree.  This makes installation slightly faster (no need to rewrite the
 801     # RPATHs), and makes the binaries in the build tree relocatable.
 802     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 803         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 804         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 805     endif()
 806     # Set the RPATH as relative to the executable location to make the
 807     # binaries relocatable.
 808     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 809         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 810         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 811     else()
 812         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 813     endif()
 814     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 815     set(CMAKE_MACOSX_RPATH 1)
 816 endif()
 817
 818 #COPYING file: Only necessary for binary distributions.
 819 #Simpler to always install.
 820 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 821
 822 if (BUILD_TESTING)
 823     include(tests/CheckTarget.cmake)
 824 endif()
 825
 826 # TODO: Determine control flow and defaults for package installation and testing use cases.
 827 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 828 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 829 mark_as_advanced(GMX_PYTHON_PACKAGE)
 830
 831 find_package(ImageMagick QUIET COMPONENTS convert)
 832 include(gmxTestImageMagick)
 833 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 834 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 835 add_subdirectory(docs)
 836 add_subdirectory(share)
 837 add_subdirectory(scripts)
 838 add_subdirectory(api)
 839 add_subdirectory(src)
 840
 841 if (BUILD_TESTING)
 842     add_subdirectory(tests)
 843 endif()
 844
 845 if(GMX_PYTHON_PACKAGE)
 846     add_subdirectory(python_packaging)
 847 endif()
 848
 849 gmx_cpack_write_config()
 850
 851 #######################
 852 ## uninstall target
 853 #######################
 854 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 855                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 856                   IMMEDIATE @ONLY)
 857 ###########################
 858 ADD_CUSTOM_TARGET(uninstall
 859                   "${CMAKE_COMMAND}" -P
 860                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 861 ###########################
 862 set_directory_properties(PROPERTIES
 863             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")