src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \cond \internal \file scanner.l
  36  * \brief
  37  * Tokenizer for the selection language.
  38  *
  39  * \author Teemu Murtola <teemu.murtola@gmail.com>
  40  * \ingroup module_selection
  41  * \endcond
  42  */
  43 /*! \internal \file scanner.cpp
  44  * \brief
  45  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  46  *
  47  * \ingroup module_selection
  48  */
  49 %{
  50 #include "gromacs/legacyheaders/string2.h"
  51
  52 #include "parser.h"
  53 #include "scanner.h"
  54 #include "scanner_internal.h"
  55
  56 /* This macro is here to make the actions a bit shorter, since nearly every
  57  * action needs this call. */
  58 #define ADD_TOKEN _gmx_sel_lexer_add_token(yytext, yyleng, state)
  59
  60 %}
  61
  62 INTEGER    [[:digit:]]+
  63 DSEQ       ([[:digit:]]+)
  64 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  65 EXP        ([eE][+-]?{DSEQ})
  66 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  67 STRING     (\"([^\"\\\n]|(\\\"))*\")
  68 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  69 CMPOP      (([<>]=?)|([!=]=))
  70 COMMENT    (#.*)
  71
  72 %option nodefault
  73 %option noyywrap
  74 %option reentrant
  75 %option prefix="_gmx_sel_yy"
  76 %option header-file="scanner_flex.h"
  77 %option nounistd
  78 %option never-interactive
  79
  80 %s matchof
  81 %s matchbool
  82 %s cmdstart
  83 %x help
  84
  85 %%
  86
  87 %{
  88     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
  89     int              retval;
  90     /* Return a token if one is pending */
  91     retval = _gmx_sel_lexer_process_pending(yylval, state);
  92     if (retval != 0)
  93     {
  94         return retval;
  95     }
  96     /* Handle the start conditions for 'of' matching */
  97     if (state->bMatchOf)
  98     {
  99         BEGIN(matchof);
 100         state->bMatchOf = false;
 101     }
 102     else if (state->bMatchBool)
 103     {
 104         BEGIN(matchbool);
 105         state->bMatchBool = false;
 106     }
 107     else if (state->bCmdStart)
 108     {
 109         BEGIN(cmdstart);
 110         state->bCmdStart = false;
 111     }
 112     else if (YYSTATE != help)
 113     {
 114         BEGIN(0);
 115     }
 116 %}
 117
 118 {COMMENT}
 119 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 120 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 121 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 122
 123 \\\n            { _gmx_sel_lexer_add_token(" ", 1, state); }
 124 ";"|\n          {
 125                     if (yytext[0] == ';' || state->bInteractive)
 126                     {
 127                         rtrim(state->pselstr);
 128                         state->bCmdStart = true;
 129                         return CMD_SEP;
 130                     }
 131                     else
 132                     {
 133                         _gmx_sel_lexer_add_token(" ", 1, state);
 134                     }
 135                 }
 136
 137 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 138 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 139
 140 help            { if (YYSTATE == cmdstart) { BEGIN(help); } return HELP; }
 141 <help>{
 142 [[:blank:]]+
 143 {IDENTIFIER}    { yylval->str = gmx_strndup(yytext, yyleng); return HELP_TOPIC; }
 144 ";"|\n          { state->bCmdStart = true; return CMD_SEP; }
 145 .               { return INVALID; }
 146 }
 147
 148 <matchbool>{
 149 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 150 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 151 }
 152 group           { ADD_TOKEN; return GROUP; }
 153 to              { ADD_TOKEN; return TO; }
 154 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 155 and|"&&"        { ADD_TOKEN; return AND; }
 156 or|"||"         { ADD_TOKEN; return OR; }
 157 xor             { ADD_TOKEN; return XOR; }
 158 not|"!"         { ADD_TOKEN; return NOT; }
 159 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 160
 161 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yytext, yyleng, state); }
 162
 163 [[:blank:]]+    { _gmx_sel_lexer_add_token(" ", 1, state); }
 164 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 165 .               { ADD_TOKEN; return yytext[0]; }