src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 if(GMX_USE_TNG)
  49     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  50            OFF)
  51     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  52     if(GMX_EXTERNAL_TNG)
  53         find_package(TNG_IO 1.6.0)
  54         if(NOT TNG_IO_FOUND)
  55             message(FATAL_ERROR
  56                 "TNG >= 1.6.0 not found. "
  57                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  58         endif()
  59         include_directories(${TNG_IO_INCLUDE_DIRS})
  60     endif()
  61     if(NOT GMX_EXTERNAL_TNG)
  62         # TNG wants zlib if it is available
  63         find_package(ZLIB QUIET)
  64         include(gmxTestZLib)
  65         gmx_test_zlib(HAVE_ZLIB)
  66
  67         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  68         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  69         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  70         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  71
  72         if (HAVE_ZLIB)
  73             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  74         endif()
  75     endif()
  76 else()
  77     # We still need to get tng/tng_io_fwd.h from somewhere!
  78     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  79 endif()
  80
  81 add_subdirectory(gmxlib)
  82 add_subdirectory(mdlib)
  83 add_subdirectory(gmxpreprocess)
  84 add_subdirectory(commandline)
  85 add_subdirectory(fft)
  86 add_subdirectory(linearalgebra)
  87 add_subdirectory(math)
  88 add_subdirectory(random)
  89 add_subdirectory(onlinehelp)
  90 add_subdirectory(options)
  91 add_subdirectory(timing)
  92 add_subdirectory(utility)
  93 add_subdirectory(fileio)
  94 add_subdirectory(swap)
  95 add_subdirectory(essentialdynamics)
  96 add_subdirectory(pulling)
  97 add_subdirectory(simd)
  98 add_subdirectory(imd)
  99 if (NOT GMX_BUILD_MDRUN_ONLY)
 100     add_subdirectory(legacyheaders)
 101     add_subdirectory(gmxana)
 102     add_subdirectory(statistics)
 103     add_subdirectory(analysisdata)
 104     add_subdirectory(selection)
 105     add_subdirectory(trajectoryanalysis)
 106     add_subdirectory(tools)
 107 endif()
 108
 109 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 110
 111 # This would be the standard way to include thread_mpi, but
 112 # we want libgromacs to link the functions directly
 113 #if(GMX_THREAD_MPI)
 114 #    add_subdirectory(thread_mpi)
 115 #endif()
 116 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 117
 118 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 119 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 120
 121 file(GLOB LIBGROMACS_HEADERS *.h)
 122 configure_file(version.h.cmakein version.h)
 123 gmx_install_headers("" ${LIBGROMACS_HEADERS})
 124 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
 125
 126 # Add target that generates baseversion-gen.c every time make is run
 127 # if git version info is requested, or create it statically.
 128 # This code is here instead of utility/CMakeLists.txt because CMake
 129 # ignores set_source_file_properties from subdirectories.
 130 set(GENERATED_VERSION_FILE
 131     ${CMAKE_CURRENT_BINARY_DIR}/utility/baseversion-gen.c)
 132 set(GENERATED_VERSION_FILE_SOURCE
 133     ${CMAKE_CURRENT_SOURCE_DIR}/utility/baseversion-gen.c.cmakein)
 134 if (GMX_GIT_VERSION_INFO)
 135     add_custom_target(gmx-version ALL
 136             COMMAND ${CMAKE_COMMAND}
 137                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
 138                 -D PROJECT_VERSION="${PROJECT_VERSION}"
 139                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
 140                 -D VERSION_CMAKEIN=${GENERATED_VERSION_FILE_SOURCE}
 141                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
 142                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
 143             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 144             DEPENDS ${GENERATED_VERSION_FILE_SOURCE}
 145             COMMENT "Generating git version information")
 146     set_source_files_properties(${GENERATED_VERSION_FILE}
 147                                 PROPERTIES GENERATED true)
 148 else()
 149     set(GMX_PROJECT_VERSION_STR ${PROJECT_VERSION})
 150     configure_file(${GENERATED_VERSION_FILE_SOURCE} ${GENERATED_VERSION_FILE})
 151 endif()
 152 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 153
 154 # apply gcc 4.4.x bug workaround
 155 if(GMX_USE_GCC44_BUG_WORKAROUND)
 156    include(gmxGCC44O3BugWorkaround)
 157    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 158    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 159    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 160 endif()
 161
 162 add_library(libgromacs ${LIBGROMACS_SOURCES})
 163 if (GMX_GIT_VERSION_INFO)
 164     add_dependencies(libgromacs gmx-version)
 165 endif()
 166
 167 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 168 # is a generated source file. These are awkward to suppress inline, so
 169 # we do it in the compilation command (after testing that the compiler
 170 # supports the suppressions). Setting the properties only works after
 171 # the related target has been created, e.g. after when the file is
 172 # used with add_library().
 173 include(CheckCXXCompilerFlag)
 174 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 175 if (HAS_NO_UNUSED_PARAMETER)
 176     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 177 endif()
 178 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 179 if (HAS_NO_DEPRECATED_REGISTER)
 180     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 181 else()
 182     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 183     if (HAS_NO_DEPRECATED)
 184         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 185     endif()
 186 endif()
 187 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 188
 189 target_link_libraries(libgromacs
 190                       ${EXTRAE_LIBRARIES}
 191                       ${GMX_GPU_LIBRARIES}
 192                       ${GMX_EXTRA_LIBRARIES}
 193                       ${TNG_IO_LIBRARIES}
 194                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 195                       ${XML_LIBRARIES}
 196                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 197 set_target_properties(libgromacs PROPERTIES
 198                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 199                       SOVERSION ${LIBRARY_SOVERSION}
 200                       VERSION ${LIBRARY_VERSION}
 201                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 202
 203 # Only install the library in mdrun-only mode if it is actually necessary
 204 # for the binary
 205 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 206     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 207 endif()
 208
 209 if (NOT GMX_BUILD_MDRUN_ONLY)
 210     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 211                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 212     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 213             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 214             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 215             COMPONENT development)
 216 endif()
 217
 218 if (INSTALL_CUDART_LIB) #can be set manual by user
 219     if (GMX_GPU)
 220         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 221             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 222             if(IS_CUDART) #libcuda should not be installed
 223                 #install also name-links (linker uses those)
 224                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 225                 install(FILES ${CUDA_LIBS} DESTINATION
 226                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 227             endif()
 228         endforeach()
 229     else()
 230         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 231     endif()
 232 endif()