src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 if(GMX_USE_TNG)
  49     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  50            OFF)
  51     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  52     if(GMX_EXTERNAL_TNG)
  53         find_package(TNG_IO 1.6.0)
  54         if(NOT TNG_IO_FOUND)
  55             message(FATAL_ERROR
  56                 "TNG >= 1.6.0 not found. "
  57                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  58         endif()
  59         include_directories(${TNG_IO_INCLUDE_DIRS})
  60     endif()
  61     if(NOT GMX_EXTERNAL_TNG)
  62         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  63         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  64         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  65         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  66
  67         if (HAVE_ZLIB)
  68             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  69             include_directories(${ZLIB_INCLUDE_DIRS})
  70         endif()
  71     endif()
  72 else()
  73     # We still need to get tng/tng_io_fwd.h from somewhere!
  74     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  75 endif()
  76
  77 add_subdirectory(gmxlib)
  78 add_subdirectory(mdlib)
  79 add_subdirectory(gmxpreprocess)
  80 add_subdirectory(commandline)
  81 add_subdirectory(fft)
  82 add_subdirectory(linearalgebra)
  83 add_subdirectory(math)
  84 add_subdirectory(random)
  85 add_subdirectory(onlinehelp)
  86 add_subdirectory(options)
  87 add_subdirectory(pbcutil)
  88 add_subdirectory(timing)
  89 add_subdirectory(topology)
  90 add_subdirectory(utility)
  91 add_subdirectory(fileio)
  92 add_subdirectory(swap)
  93 add_subdirectory(essentialdynamics)
  94 add_subdirectory(pulling)
  95 add_subdirectory(simd)
  96 add_subdirectory(imd)
  97 if (NOT GMX_BUILD_MDRUN_ONLY)
  98     add_subdirectory(legacyheaders)
  99     add_subdirectory(gmxana)
 100     add_subdirectory(statistics)
 101     add_subdirectory(analysisdata)
 102     add_subdirectory(selection)
 103     add_subdirectory(trajectoryanalysis)
 104     add_subdirectory(tools)
 105 endif()
 106
 107 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 108
 109 # This would be the standard way to include thread_mpi, but
 110 # we want libgromacs to link the functions directly
 111 #if(GMX_THREAD_MPI)
 112 #    add_subdirectory(thread_mpi)
 113 #endif()
 114 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 115
 116 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 117 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 118
 119 set(LIBGROMACS_HEADERS
 120     analysisdata.h
 121     commandline.h
 122     options.h
 123     selection.h
 124     trajectoryanalysis.h
 125     utility.h)
 126 configure_file(version.h.cmakein version.h)
 127 gmx_install_headers("" ${LIBGROMACS_HEADERS})
 128 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
 129
 130 # This code is here instead of utility/CMakeLists.txt, because CMake
 131 # custom commands and source file properties can only be set in the directory
 132 # that contains the target that uses them.
 133 # TODO: Generate a header instead that can be included from baseversion.c.
 134 # That probably simplifies things somewhat.
 135 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 136 gmx_configure_version_file(
 137     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 138     REMOTE_HASH SOURCE_FILE)
 139 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 140
 141 # apply gcc 4.4.x bug workaround
 142 if(GMX_USE_GCC44_BUG_WORKAROUND)
 143    include(gmxGCC44O3BugWorkaround)
 144    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 145    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 146    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 147 endif()
 148
 149 if (GMX_GPU)
 150     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES}
 151             OPTIONS
 152             RELWITHDEBINFO -g
 153             DEBUG -g -D_DEBUG_=1)
 154 else()
 155     add_library(libgromacs ${LIBGROMACS_SOURCES})
 156 endif()
 157
 158 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 159 # is a generated source file. These are awkward to suppress inline, so
 160 # we do it in the compilation command (after testing that the compiler
 161 # supports the suppressions). Setting the properties only works after
 162 # the related target has been created, e.g. after when the file is
 163 # used with add_library().
 164 include(CheckCXXCompilerFlag)
 165 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 166 if (HAS_NO_UNUSED_PARAMETER)
 167     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 168 endif()
 169 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 170 if (HAS_NO_DEPRECATED_REGISTER)
 171     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 172 else()
 173     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 174     if (HAS_NO_DEPRECATED)
 175         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 176     endif()
 177 endif()
 178 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 179
 180 target_link_libraries(libgromacs
 181                       ${EXTRAE_LIBRARIES}
 182                       ${GMX_EXTRA_LIBRARIES}
 183                       ${TNG_IO_LIBRARIES}
 184                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 185                       ${XML_LIBRARIES}
 186                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 187 set_target_properties(libgromacs PROPERTIES
 188                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 189                       SOVERSION ${LIBRARY_SOVERSION}
 190                       VERSION ${LIBRARY_VERSION}
 191                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 192
 193 # Only install the library in mdrun-only mode if it is actually necessary
 194 # for the binary
 195 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 196     install(TARGETS libgromacs
 197             EXPORT libgromacs
 198             DESTINATION ${LIB_INSTALL_DIR}
 199             COMPONENT libraries)
 200 endif()
 201
 202 if (NOT GMX_BUILD_MDRUN_ONLY)
 203     include(InstallLibInfo.cmake)
 204 endif()
 205
 206 if (INSTALL_CUDART_LIB) #can be set manual by user
 207     if (GMX_GPU)
 208         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 209             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 210             if(IS_CUDART) #libcuda should not be installed
 211                 #install also name-links (linker uses those)
 212                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 213                 install(FILES ${CUDA_LIBS} DESTINATION
 214                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 215             endif()
 216         endforeach()
 217     else()
 218         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 219     endif()
 220 endif()