CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set(CPACK_PACKAGE_NAME "gromacs")
  87 set(CPACK_PACKAGE_VERSION_MAJOR ${GMX_VERSION_MAJOR})
  88 set(CPACK_PACKAGE_VERSION_MINOR ${GMX_VERSION_MINOR})
  89 set(CPACK_PACKAGE_VERSION_PATCH ${GMX_VERSION_PATCH})
  90 set(CPACK_PACKAGE_VERSION       ${GMX_VERSION_STRING})
  91 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  92 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  93 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  94 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  95 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  96 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  97 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  98 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
  99 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 100 # CPack source archives include only the directories we list here.
 101 # This variable is a list of pairs of names of source and destination
 102 # directories. Most of these are used for content GROMACS generates as
 103 # part of the configuration or build.
 104 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/docs/man/man1;docs/man/man1;${CMAKE_BINARY_DIR}/docs/man/man7;docs/man/man7;${CMAKE_BINARY_DIR}/docs/old-html/final;docs/old-html/final;${CMAKE_BINARY_DIR}/docs/install-guide/final;/")
 105 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 106 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 107
 108 #must come after all cpack settings!
 109 include(CPack)
 110
 111 # Set a default valgrind suppression file.
 112 # This unfortunately needs to duplicate information from CTest to work as
 113 # expected...
 114 set(MEMORYCHECK_SUPPRESSIONS_FILE
 115     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 116     CACHE FILEPATH
 117     "File that contains suppressions for the memory checker")
 118 include(CTest)
 119
 120 # Variables that accumulate stuff influencing the installed headers
 121 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 122 set(INSTALLED_HEADER_DEFINITIONS "")
 123
 124 ########################################################################
 125 # Check and warn if cache generated on a different host is being reused
 126 ########################################################################
 127 if(CMAKE_HOST_UNIX)
 128     execute_process(COMMAND hostname
 129                     OUTPUT_VARIABLE TMP_HOSTNAME
 130                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 131     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 132         message(WARNING "
 133             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 134             is being reused! This could lead to inconsitencies; therefore, it is
 135             recommended to regenerate the cache!")
 136     endif()
 137     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 138             "Hostname of the machine where the cache was generated.")
 139 endif()
 140
 141 ########################################################################
 142 # User input options                                                   #
 143 ########################################################################
 144 include(gmxOptionUtilities)
 145
 146 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 147
 148 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 149 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 150 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 151 gmx_dependent_option(
 152     GMX_MPI_IN_PLACE
 153     "Enable MPI_IN_PLACE for MPIs that have it defined"
 154     ON
 155     GMX_MPI)
 156 mark_as_advanced(GMX_MPI_IN_PLACE)
 157 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 158 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 159 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 160 mark_as_advanced(GMX_FAHCORE)
 161
 162 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 163 mark_as_advanced(GMX_COOL_QUOTES)
 164 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 165
 166 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 167 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 168 if(MSVC)
 169     set(REQUIRED_CUDA_VERSION 4.1)
 170 else()
 171     set(REQUIRED_CUDA_VERSION 4.0)
 172 endif()
 173 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 174 include(gmxManageGPU)
 175
 176 # Detect the architecture the compiler is targetting, detect
 177 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 178 # to use if none is specified, and populate the cache option for CPU
 179 # SIMD.
 180 include(gmxDetectTargetArchitecture)
 181 gmx_detect_target_architecture()
 182
 183 if(GMX_CPU_ACCELERATION)
 184     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 185     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 186     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 187     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 188 endif()
 189
 190 if(NOT GMX_TARGET_MIC)
 191     include(gmxDetectSimd)
 192     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 193 else()
 194     set(GMX_SUGGESTED_SIMD "None")
 195 endif()
 196
 197 gmx_option_multichoice(
 198     GMX_SIMD
 199     "SIMD instruction set for CPU kernels and compiler optimization"
 200     "${GMX_SUGGESTED_SIMD}"
 201     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 202
 203 gmx_option_multichoice(
 204     GMX_FFT_LIBRARY
 205     "FFT library"
 206     "fftw3"
 207     fftw3 mkl "fftpack[built-in]")
 208 gmx_dependent_option(
 209     GMX_BUILD_OWN_FFTW
 210     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 211     OFF
 212     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 213 gmx_dependent_option(
 214     GMX_DISABLE_FFTW_MEASURE
 215     "Do not optimize FFTW setups (not needed with SSE)"
 216     OFF
 217     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 218 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 219 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 220
 221 gmx_option_multichoice(
 222     GMX_QMMM_PROGRAM
 223     "QM package for QM/MM"
 224     None
 225     none gaussian mopac gamess orca)
 226
 227 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 228 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 229
 230 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 231
 232 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 233 mark_as_advanced(GMX_BROKEN_CALLOC)
 234 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 235 mark_as_advanced(GMX_LOAD_PLUGINS)
 236
 237 option(GMX_GPU  "Enable GPU acceleration" ON)
 238 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 239
 240 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 241
 242 if(UNIX)
 243     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 244 endif()
 245 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 246
 247 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 248 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 249
 250 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 251 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 252
 253 option(GMX_BUILD_FOR_COVERAGE
 254        "Tune build for better code coverage metrics (e.g., disable asserts)"
 255        OFF)
 256 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 257
 258 option(GMX_DEVELOPER_BUILD
 259     "Enable Developer convenience features: always build unit-tests"
 260     OFF)
 261 mark_as_advanced(GMX_DEVELOPER_BUILD)
 262
 263 ######################################################################
 264 # Detect OpenMP support
 265 ######################################################################
 266 # The OpenMP detection _must_ come before tests for other CFLAGS.
 267 include(gmxManageOpenMP)
 268
 269
 270
 271 ######################################################################
 272 # Compiler tests
 273 # These need to be done early (before further tests).
 274 #####################################################################
 275
 276 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 277 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 278 # invalid options with the Intel Compilers, and we have added a line
 279 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 280 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 281 # a semicolon. Since this is also used as a separator in lists inside CMake,
 282 # that string ends up being split into two separate patterns, and the last
 283 # part is just a single word that also matches other messages. We solved this
 284 # by replacing the semicolon with a period that matches any character.
 285 #
 286 # These files should be removed from the source tree when a CMake version that
 287 # includes the features in question becomes required for building GROMACS.
 288 include(CheckCCompilerFlag)
 289 include(CheckCXXCompilerFlag)
 290
 291 include(gmxCFlags)
 292 gmx_c_flags()
 293
 294 # This variable should be used for additional compiler flags which are not
 295 # generated in gmxCFlags nor are SIMD or MPI related.
 296 set(EXTRA_C_FLAGS "")
 297 set(EXTRA_CXX_FLAGS "")
 298
 299 # Run through a number of tests for buggy compilers and other issues
 300 include(gmxTestCompilerProblems)
 301 gmx_test_compiler_problems()
 302 # GMX_SIMD will not be set automatically until the second
 303 # pass (which is not strictly guaranteed to occur), so putting this
 304 # check here among logically-related tests is inefficient, but the
 305 # potential loss is likely zero.
 306 if(GMX_SIMD STREQUAL "AVX_256"
 307         AND CMAKE_COMPILER_IS_GNUCC
 308         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 309             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 310     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 311     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 312 endif()
 313
 314
 315 if(GMX_DOUBLE)
 316     add_definitions(-DGMX_DOUBLE)
 317     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 318 endif()
 319 if(GMX_SOFTWARE_INVSQRT)
 320     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 321 endif()
 322
 323 if(WIN32 AND NOT CYGWIN)
 324     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 325     mark_as_advanced(GMX_WSOCKLIB_PATH)
 326     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 327     if(WSOCK32_LIBRARY)
 328         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 329         add_definitions(-DGMX_HAVE_WINSOCK)
 330     else()
 331         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 332     endif(WSOCK32_LIBRARY)
 333 endif()
 334
 335
 336
 337 ########################################################################
 338 # Basic system tests (standard libraries, headers, functions, types)   #
 339 ########################################################################
 340 include(CheckIncludeFiles)
 341 include(CheckIncludeFileCXX)
 342 check_include_files(unistd.h     HAVE_UNISTD_H)
 343 check_include_files(pwd.h        HAVE_PWD_H)
 344 check_include_files(dirent.h     HAVE_DIRENT_H)
 345 check_include_files(time.h       HAVE_TIME_H)
 346 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 347 check_include_files(io.h         HAVE_IO_H)
 348 check_include_files(sched.h      HAVE_SCHED_H)
 349
 350 check_include_files(regex.h      HAVE_POSIX_REGEX)
 351 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 352 # TODO: It could be nice to inform the user if no regex support is found,
 353 # as selections won't be fully functional.
 354
 355 include(CheckFunctionExists)
 356 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 357 check_function_exists(memalign          HAVE_MEMALIGN)
 358 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 359 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 360 check_function_exists(fsync             HAVE_FSYNC)
 361 check_function_exists(_fileno           HAVE__FILENO)
 362 check_function_exists(fileno            HAVE_FILENO)
 363 check_function_exists(_commit           HAVE__COMMIT)
 364 check_function_exists(sigaction         HAVE_SIGACTION)
 365 check_function_exists(sysconf           HAVE_SYSCONF)
 366 check_function_exists(rsqrt             HAVE_RSQRT)
 367 check_function_exists(rsqrtf            HAVE_RSQRTF)
 368 check_function_exists(sqrtf             HAVE_SQRTF)
 369
 370 include(CheckLibraryExists)
 371 check_library_exists(m sqrt "" HAVE_LIBM)
 372 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 373
 374 include(TestSchedAffinity)
 375 test_sched_affinity(HAVE_SCHED_AFFINITY)
 376
 377 include(TestBigEndian)
 378 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 379
 380 # Management of GROMACS options for specific toolchains should go
 381 # here. Because the initial settings for some of the main options have
 382 # already happened, but things like library detection and MPI compiler
 383 # feature detection have not, the docstrings for any over-rides of
 384 # GROMACS defaults or user settings will make sense. Also, any
 385 # toolchain-related reasons for choosing whether to detect various
 386 # things can be sorted out now, before the detection takes place.
 387 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 388     include(gmxManageBlueGene)
 389 endif()
 390
 391 ########################################################################
 392 #Process MPI settings
 393 ########################################################################
 394 include(gmxManageMPI)
 395
 396
 397 ########################################################################
 398 #Process shared/static library settings
 399 ########################################################################
 400 include(gmxManageSharedLibraries)
 401
 402
 403 ########################################################################
 404 # Find external packages                                               #
 405 ########################################################################
 406
 407 # Unconditionally find the package, as it is also required for unit
 408 # tests. This exports LIBXML2_FOUND, which we should not use because
 409 # it does not tell us that linking will succeed. Instead, we test that
 410 # next.
 411 if(DEFINED LIBXML2_LIBRARIES)
 412   set(LibXml2_FIND_QUIETLY TRUE)
 413 endif()
 414 find_package(LibXml2)
 415 include(gmxTestLibXml2)
 416 gmx_test_libxml2(HAVE_LIBXML2)
 417 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 418 set(PKG_XML "")
 419 mark_as_advanced(GMX_XML)
 420 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 421 #if(GMX_XML AND NOT HAVE_LIBXML2)
 422 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 423 #endif()
 424 #if(GMX_XML)
 425 #    include_directories(${LIBXML2_INCLUDE_DIR})
 426 #    set(PKG_XML libxml-2.0)
 427 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 428 #endif()
 429
 430 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 431 mark_as_advanced(GMX_EXTRAE)
 432
 433 if (GMX_EXTRAE)
 434   find_package(EXTRAE)
 435   if(EXTRAE_FOUND)
 436     include_directories(${EXTRAE_INCLUDE_DIR})
 437     set(HAVE_EXTRAE 1)
 438   else()
 439     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 440   endif()
 441 endif()
 442
 443 option(GMX_X11 "Use X window system" OFF)
 444 if (GMX_X11)
 445     find_package(X11)
 446     # X11 includes/libraries are only set in the ngmx subdirectory!
 447     if(NOT X11_FOUND)
 448         message(FATAL_ERROR
 449                 "X11 include files and/or libraries were not found. "
 450                 "Set GMX_X11=OFF to compile without X11 support. "
 451                 "gmx view will not be available.")
 452     endif()
 453     include_directories(${X11_INCLUDE_DIR})
 454 endif()
 455
 456 include(ThreadMPI)
 457 # Enable core threading facilities
 458 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 459 # Enable tMPI C++ support
 460 tmpi_enable_cxx()
 461 if(GMX_THREAD_MPI)
 462     # enable MPI functions
 463     tmpi_enable()
 464     set(GMX_MPI 1)
 465     set(MPI_IN_PLACE_EXISTS 1)
 466 endif()
 467 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 468 if (TMPI_ATOMICS_DISABLED)
 469    add_definitions(-DTMPI_ATOMICS_DISABLED)
 470 endif()
 471
 472 if(GMX_GPU)
 473     # now that we have detected the dependencies, do the second configure pass
 474     gmx_gpu_setup()
 475 endif()
 476
 477 if(CYGWIN)
 478     set(GMX_CYGWIN 1)
 479 endif()
 480
 481 if(WIN32 AND NOT CYGWIN)
 482     set(GMX_NATIVE_WINDOWS 1)
 483     # This makes windows.h not declare min/max as macros that would break
 484     # C++ code using std::min/std::max.
 485     add_definitions(-DNOMINMAX)
 486 endif()
 487
 488 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 489 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 490 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 491     find_package(Boost 1.44.0)
 492     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 493         set(Boost_FOUND FALSE)
 494     endif()
 495     # Print the notification only on first run, when determining the default
 496     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 497         message("Boost >= 1.44 not found. Using minimal internal version. "
 498                 "This may cause trouble if you plan on compiling/linking other "
 499                 "software that uses Boost against Gromacs.")
 500     endif()
 501 endif()
 502 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 503        ${Boost_FOUND})
 504 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 505     message(FATAL_ERROR
 506         "Boost >= 1.44 not found. "
 507         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 508         "version of Boost included with Gromacs.")
 509 endif()
 510
 511 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 512     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 513 endif()
 514 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 515 mark_as_advanced(GMX_BUILD_UNITTESTS)
 516 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 517 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 518     message(FATAL_ERROR
 519         "Cannot build unit tests without libxml2. "
 520         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 521 endif()
 522
 523 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 524     # TNG wants zlib if it is available
 525     find_package(ZLIB QUIET)
 526     include(gmxTestZLib)
 527     gmx_test_zlib(HAVE_ZLIB)
 528 endif()
 529
 530 ########################################################################
 531 # Our own GROMACS tests
 532 ########################################################################
 533
 534 add_definitions( -DHAVE_CONFIG_H )
 535 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 536 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 537 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 538 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 539
 540 include(gmxTestInlineASM)
 541 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 542
 543 include(gmxSetBuildInformation)
 544 gmx_set_build_information()
 545 # Turn on RDTSCP if:
 546 # - the build system's CPU supports it
 547 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 548 #   at this point means that the user set it).
 549 # Note: it's better to not use the later set value of GMX_SIMD because
 550 # it reflects the system's capability of both compiling and running AVX code.
 551 # TODO: After merge with 5.0 one could implement a cache variable dependency
 552 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 553 # after the first cmake pass.
 554 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 555     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 556 else()
 557     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 558 endif()
 559 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 560 mark_as_advanced(GMX_USE_RDTSCP)
 561 if(GMX_USE_RDTSCP)
 562     set(HAVE_RDTSCP 1)
 563 endif()
 564
 565 include(gmxTestFloatFormat)
 566 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 567                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 568                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 569
 570 include(gmxTestLargeFiles)
 571 gmx_test_large_files(GMX_LARGEFILES)
 572
 573 include(gmxTestSignal)
 574 gmx_test_sigusr1(HAVE_SIGUSR1)
 575
 576 include(gmxTestPipes)
 577 gmx_test_pipes(HAVE_PIPES)
 578
 579 include(gmxTestIsfinite)
 580 gmx_test_isfinite(HAVE_ISFINITE)
 581 gmx_test__isfinite(HAVE__ISFINITE)
 582 gmx_test__finite(HAVE__FINITE)
 583
 584 include(gmxTestCXX11)
 585 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 586 include(CMakeDependentOption)
 587 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 588 # entirely to keep the compilation environment uniform.
 589 cmake_dependent_option(GMX_CXX11
 590     "Use C++11 features"
 591     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 592 mark_as_advanced(GMX_CXX11)
 593 if(GMX_CXX11)
 594     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 595 endif()
 596
 597
 598 include(gmxTestXDR)
 599 gmx_test_xdr(GMX_SYSTEM_XDR)
 600 if(NOT GMX_SYSTEM_XDR)
 601     set(GMX_INTERNAL_XDR 1)
 602 endif()
 603
 604
 605 ##################################################
 606 # Process SIMD instruction settings
 607 ##################################################
 608 # This checks what flags to add in order to
 609 # support the SIMD instructions we need, and sets
 610 # correct defines for the SIMD instructions supported.
 611 include(gmxTestSimd)
 612 gmx_test_simd()
 613
 614
 615 # Process QM/MM Settings
 616 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 617     set(GMX_QMMM_GAUSSIAN 1)
 618 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 619     set(GMX_QMMM_MOPAC 1)
 620 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 621     set(GMX_QMMM_GAMESS 1)
 622 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 623     set(GMX_QMMM_ORCA 1)
 624 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 625     # nothing to do
 626 else()
 627     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 628 endif()
 629
 630
 631 ##################################################
 632 # Process FFT library settings
 633 ##################################################
 634 include(gmxManageFFTLibraries)
 635
 636
 637 include(gmxManageLinearAlgebraLibraries)
 638
 639 # Whether GROMACS will really try to compile support for VMD plugins
 640 set(GMX_USE_PLUGINS OFF)
 641
 642 if(GMX_LOAD_PLUGINS)
 643   if(CYGWIN OR NOT WIN32)
 644     # Native Windows does not have, nor need dlopen
 645     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 646     include(gmxTestdlopen)
 647     gmx_test_dlopen(HAVE_DLOPEN)
 648   endif()
 649
 650   # so, should we use plug-ins?
 651   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 652     if(NOT VMD_QUIETLY)
 653       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 654     endif()
 655     if(NOT GMX_VMD_PLUGIN_PATH)
 656       find_package(VMD)
 657     endif()
 658     set(GMX_USE_PLUGINS ON)
 659     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 660     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 661   else()
 662     set(PKG_DL_LIBS)
 663   endif()
 664 endif()
 665 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 666
 667 # Link real-time library for POSIX timers. The check for clock_gettime
 668 # confirms the linkability of rt.
 669 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 670     list(APPEND GMX_EXTRA_LIBRARIES rt)
 671 endif()
 672
 673 # Math and thread libraries must often come after all others when linking...
 674 if(HAVE_LIBM)
 675     list(APPEND GMX_EXTRA_LIBRARIES m)
 676 endif()
 677
 678 option(GMX_NACL "Configure for Native Client builds" OFF)
 679 if (GMX_NACL)
 680   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 681   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 682   set(GMX_NO_NICE 1)
 683   set(GMX_NO_RENAME 1)
 684 endif()
 685 mark_as_advanced(GMX_NACL)
 686
 687 if(GMX_FAHCORE)
 688   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 689       "Path to swindirect.h")
 690   include_directories(${COREWRAP_INCLUDE_DIR})
 691 endif()
 692
 693 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 694 mark_as_advanced(GMX_BUILD_HELP)
 695 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 696     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 697
 698     message(FATAL_ERROR
 699         "Rebuilding HTML and man pages is not supported for in-source "
 700         "builds from a source distribution. "
 701         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 702 endif()
 703
 704 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 705 # these are set after everything else
 706 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 707     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 708     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 709     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 710     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 711 else()
 712     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 713     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 714     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 715     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 716     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 717     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 718     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 719     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 720     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 721 endif()
 722
 723 if(NOT GMX_OPENMP)
 724     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 725     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 726     unset(OpenMP_C_FLAGS CACHE)
 727     unset(OpenMP_CXX_FLAGS CACHE)
 728 else()
 729     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 730     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 731 endif()
 732
 733 ########################################################################
 734 # Specify install locations
 735 ########################################################################
 736 # Use GNUInstallDirs to set paths on multiarch systems.
 737 include(GNUInstallDirs)
 738
 739 # Customization for the installation tree paths.
 740 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 741     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 742 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 743     "Data installation directory under share/ (default: gromacs)")
 744 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 745
 746 # These variables are used internally to provide a central location for
 747 # customizing the install locations.
 748 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 749 set(BIN_INSTALL_DIR       bin)
 750 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 751 set(MAN_INSTALL_DIR       share/man)
 752 # If the nesting level wrt. the installation root is changed,
 753 # gromacs-config.cmake.cmakein needs to be adapted.
 754 set(CMAKE_INSTALL_DIR     share/cmake)
 755 # TODO: Make GMXRC adapt if this is changed
 756 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 757 set(INCL_INSTALL_DIR      include)
 758
 759 # These variables get written into config.h for use in finding the data
 760 # directories.
 761 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 762 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 763
 764 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 765
 766 # Binary and library suffix options
 767 include(gmxManageSuffixes)
 768
 769 ################################################################
 770 # Shared library load path settings
 771 ################################################################
 772 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 773 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 774 # was added.
 775 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 776    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 777     # The build folder always has bin/ and lib/; if we are also going to
 778     # install to lib/, then the installation RPATH works also in the build
 779     # tree.  This makes installation slightly faster (no need to rewrite the
 780     # RPATHs), and makes the binaries in the build tree relocatable.
 781     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 782         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 783     endif()
 784     # Set the RPATH as relative to the executable location to make the
 785     # binaries relocatable.
 786     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 787         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 788     else()
 789         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 790     endif()
 791     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 792     set(CMAKE_MACOSX_RPATH 1)
 793 else()
 794     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 795     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 796         # Set the RPATH options manually.
 797         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 798         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 799     else()
 800         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 801         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 802     endif()
 803 endif()
 804
 805 #COPYING file: Only necessary for binary distributions.
 806 #Simpler to always install.
 807 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 808
 809 if(GMX_EXTERNAL_BOOST)
 810     include_directories(${Boost_INCLUDE_DIRS})
 811     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 812 else()
 813     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 814     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 815     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 816     # typeid not supported for minimal internal version
 817     # (would add significant amount of code)
 818     add_definitions(-DBOOST_NO_TYPEID)
 819     if (NOT GMX_BUILD_MDRUN_ONLY)
 820         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 821                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 822                 COMPONENT development)
 823     endif()
 824 endif()
 825
 826 if (GMX_BUILD_FOR_COVERAGE)
 827     # Code heavy with asserts makes conditional coverage close to useless metric,
 828     # as by design most of the false branches are impossible to trigger in
 829     # correctly functioning code.  And the benefit of testing those that could
 830     # be triggered by using an API against its specification isn't usually
 831     # worth the effort.
 832     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 833 endif()
 834
 835 if (BUILD_TESTING)
 836     # "tests" target builds all the separate test binaries.
 837     add_custom_target(tests)
 838     # "run-ctest" is an internal target that actually runs the tests.
 839     # This is necessary to be able to add separate targets that execute as part
 840     # of 'make check', but are ensured to be executed after the actual tests.
 841     add_custom_target(run-ctest
 842                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 843                       COMMENT "Running all tests"
 844                       VERBATIM)
 845     add_dependencies(run-ctest tests)
 846     # "check" target builds and runs all tests.
 847     add_custom_target(check DEPENDS run-ctest)
 848 endif()
 849
 850 if (NOT GMX_BUILD_MDRUN_ONLY)
 851     add_subdirectory(docs)
 852     add_subdirectory(share)
 853     add_subdirectory(scripts)
 854 endif()
 855 add_subdirectory(src)
 856
 857 if (BUILD_TESTING)
 858     add_subdirectory(tests)
 859 endif()
 860
 861 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 862 # Don't bother the user after the first configure pass.
 863 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 864     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 865 endif()
 866 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 867
 868 #######################
 869 ## uninstall target
 870 #######################
 871 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 872                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 873                   IMMEDIATE @ONLY)
 874 ###########################
 875 ADD_CUSTOM_TARGET(uninstall
 876                   "${CMAKE_COMMAND}" -P
 877                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 878 ###########################
 879 set_directory_properties(PROPERTIES
 880             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")