CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.9.6)
  38 if(POLICY CMP0074) #3.12
  39     cmake_policy(SET CMP0074 NEW)
  40 endif()
  41 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  48     # Providing a default value >=10.9 helps to find modern C++ compatibility,
  49     # such as by defaulting to the Clang libc++ instead of libstdc++.
  50     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.9 CACHE STRING
  51         "OS X deployment target affects default SDK version and compiler flags."
  52         FORCE)
  53     # By default, limit the binary architecture to a single 64-bit build.
  54     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  55         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  56         FORCE)
  57 endif()
  58
  59 project(Gromacs)
  60
  61 set(CMAKE_CXX_STANDARD 14)
  62 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  63 set(CMAKE_CXX_EXTENSIONS OFF)
  64
  65 include(gmxManageCcache)
  66
  67 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  68 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  69 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  70
  71 find_package(LibStdCpp)
  72
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeReleaseWithAssert)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  96     # Set the possible values of build type for cmake-gui
  97     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  98         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  99 endif()
 100 if(CMAKE_CONFIGURATION_TYPES)
 101     # Add appropriate GROMACS-specific build types for the Visual
 102     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 103     # are already present by default).
 104     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 105     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 106     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 107         "List of configuration types"
 108         FORCE)
 109 endif()
 110 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 111
 112 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 113
 114 include(gmxCTestUtilities)
 115 gmx_ctest_init()
 116
 117 include(gmxCPackUtilities)
 118 gmx_cpack_init()
 119
 120 # Variables that accumulate stuff influencing the installed headers
 121 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 122 set(INSTALLED_HEADER_DEFINITIONS "")
 123
 124 ########################################################################
 125 # Global non-cache variables for implementing the build system
 126 ########################################################################
 127
 128 # These variables collect libraries that GROMACS requires for
 129 # linking. They should be appended to with list(APPEND ${name}
 130 # new-library) calls. They are:
 131 #  - Libraries that are required for libgromacs (only)
 132 set(GMX_EXTRA_LIBRARIES "")
 133 #  - Libraries that are required for all code in the repository
 134 set(GMX_COMMON_LIBRARIES "")
 135 #  - Libraries that all code linked against libgromacs needs
 136 #    (i.e., something that is exposed in installed headers).
 137 set(GMX_PUBLIC_LIBRARIES "")
 138
 139 ########################################################################
 140 # Check and warn if cache generated on a different host is being reused
 141 ########################################################################
 142 if(CMAKE_HOST_UNIX)
 143     execute_process(COMMAND hostname
 144                     OUTPUT_VARIABLE TMP_HOSTNAME
 145                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 146     # Only check for host name if not running in a CI environment, as the cache might
 147     # be reused there between different machines in different stages
 148     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 149             AND NOT DEFINED ENV{CI_JOB_ID})
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsistencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # Detect architecture before setting options so we can alter defaults
 161 ########################################################################
 162 # Detect the architecture the compiler is targetting, detect
 163 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 164 # to use if none is specified, and populate the cache option for CPU
 165 # SIMD.
 166 include(gmxDetectTargetArchitecture)
 167 gmx_detect_target_architecture()
 168
 169 ########################################################################
 170 # User input options                                                   #
 171 ########################################################################
 172 include(gmxOptionUtilities)
 173
 174 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 175
 176 # Fujitsu only has SIMD in double precision, so this will be faster
 177 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 178 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 179 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 180 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 181
 182 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 183 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 184 gmx_dependent_option(
 185     GMX_MPI_IN_PLACE
 186     "Enable MPI_IN_PLACE for MPIs that have it defined"
 187     ON
 188     GMX_MPI)
 189 mark_as_advanced(GMX_MPI_IN_PLACE)
 190
 191 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 192
 193 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 194 mark_as_advanced(GMX_FAHCORE)
 195
 196 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 197 mark_as_advanced(GMX_COOL_QUOTES)
 198 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 199
 200 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 201
 202 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 203
 204 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 205 set(REQUIRED_CUDA_VERSION 9.0)
 206 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 207
 208 # OpenCL required version: 1.2 or newer
 209 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 210 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 211 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 212
 213 if(NOT GMX_USE_OPENCL)
 214     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 215     include(gmxManageGPU)
 216     set(GMX_USE_CUDA ${GMX_GPU})
 217     if(GMX_GPU)
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 219     else()
 220         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 221     endif()
 222 else()
 223     #Now the OpenCL path (for both AMD and NVIDIA)
 224     if(GMX_GPU)
 225         include(gmxManageOpenCL)
 226         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 227     else()
 228         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 229     endif()
 230 endif()
 231
 232 gmx_option_multichoice(
 233     GMX_SIMD
 234     "SIMD instruction set for CPU kernels and compiler optimization"
 235     "AUTO"
 236     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 237
 238 if(GMX_TARGET_MIC)
 239     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 240 else()
 241     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 242 endif()
 243
 244 gmx_option_multichoice(
 245     GMX_FFT_LIBRARY
 246     "FFT library"
 247     "${GMX_FFT_LIBRARY_DEFAULT}"
 248     fftw3 mkl "fftpack[built-in]")
 249 gmx_dependent_option(
 250     GMX_BUILD_OWN_FFTW
 251     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 252     OFF
 253     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 254 gmx_dependent_option(
 255     GMX_DISABLE_FFTW_MEASURE
 256     "Do not optimize FFTW setups (not needed with SSE)"
 257     OFF
 258     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 259 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 260 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 261
 262 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 264
 265 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 266
 267 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 268 mark_as_advanced(GMX_BROKEN_CALLOC)
 269
 270 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 271
 272 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 273
 274 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 275
 276 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 277 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 278
 279 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 280 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 281
 282 option(GMX_BUILD_FOR_COVERAGE
 283        "Tune build for better code coverage metrics (e.g., disable asserts)"
 284        OFF)
 285 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 286
 287 option(GMX_DEVELOPER_BUILD
 288     "Enable Developer convenience features: always build unit-tests"
 289     OFF)
 290 mark_as_advanced(GMX_DEVELOPER_BUILD)
 291
 292 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 293 option(GMX_COMPILER_WARNINGS
 294     "Enable a default set of compiler warnings"
 295     ${GMX_COMPILER_WARNINGS_DEFAULT})
 296 mark_as_advanced(GMX_COMPILER_WARNINGS)
 297 # Always turn on compiler warnings with a developer build.
 298 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 299
 300 option(GMX_BUILD_SHARED_EXE
 301     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 302     ON)
 303 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 304
 305 option(GMX_PHYSICAL_VALIDATION
 306        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 307        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 308        OFF)
 309 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 310
 311 ######################################################################
 312 # Detect OpenMP support
 313 ######################################################################
 314 # The OpenMP detection _must_ come before tests for other CFLAGS.
 315 include(gmxManageOpenMP)
 316
 317
 318
 319 ######################################################################
 320 # Compiler tests
 321 # These need to be done early (before further tests).
 322 #####################################################################
 323
 324 include(gmxCFlags)
 325 gmx_c_flags()
 326
 327 # These variables should be used for CMake-style lists (ie. separated
 328 # by semicolons) of additional compiler flags which are not generated
 329 # in gmxCFlags nor are SIMD or MPI related.
 330 #
 331 # TODO These variables should be consolidated into
 332 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 333 # things that work in C compilation (e.g. merging from old branches)
 334 # might not also work for C++ compilation.
 335 set(EXTRA_C_FLAGS "")
 336 set(EXTRA_CXX_FLAGS "")
 337
 338 # Run through a number of tests for buggy compilers and other issues
 339 include(gmxTestCompilerProblems)
 340 gmx_test_compiler_problems()
 341
 342 # Implement double-precision option. This is complicated because we
 343 # need installed headers to use the precision mode of the build that
 344 # produced the library, but cannot use config.h in that case. We also
 345 # want such variables to always have a definition, because #if is more
 346 # robust than #ifdef. So, we put this value on the compiler command
 347 # line in all cases.
 348 #
 349 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 350 # because no installed header needs it
 351 if(GMX_DOUBLE)
 352     set(GMX_DOUBLE_VALUE 1)
 353 else()
 354     set(GMX_DOUBLE_VALUE 0)
 355 endif()
 356 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 357 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 358
 359 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 360 if(GMX_IMD AND WIN32)
 361     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 362 endif()
 363
 364
 365
 366 ########################################################################
 367 # Basic system tests (standard libraries, headers, functions, types)   #
 368 ########################################################################
 369 include(CheckIncludeFiles)
 370 include(CheckIncludeFileCXX)
 371 check_include_files(unistd.h     HAVE_UNISTD_H)
 372 check_include_files(pwd.h        HAVE_PWD_H)
 373 check_include_files(dirent.h     HAVE_DIRENT_H)
 374 check_include_files(time.h       HAVE_TIME_H)
 375 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 376 check_include_files(io.h         HAVE_IO_H)
 377 check_include_files(sched.h      HAVE_SCHED_H)
 378 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 379
 380 include(CheckCXXSymbolExists)
 381 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 382 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 383 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 384 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 385 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 386 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 387 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 388 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 389
 390 # We cannot check for the __builtins as symbols, but check if code compiles
 391 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 392 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 393 if(MSVC)
 394     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 395     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 396 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 397     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 398     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 399 endif()
 400
 401 include(CheckLibraryExists)
 402 find_library(HAVE_LIBM m)
 403 mark_as_advanced(HAVE_LIBM)
 404 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 405 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 406 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 407
 408 include(TestSchedAffinity)
 409 test_sched_affinity(HAVE_SCHED_AFFINITY)
 410
 411 # Aligned memory allocation. We need to check for both mm_malloc(),
 412 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 413 include(gmxTestMMMalloc)
 414 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 415 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 416 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 417 if(MSVC)
 418     # No need to waste time on this test on platforms where it will never be true
 419     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 420 endif()
 421
 422 include(TestBigEndian)
 423 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 424
 425 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 426
 427 # Management of GROMACS options for specific toolchains should go
 428 # here. Because the initial settings for some of the main options have
 429 # already happened, but things like library detection and MPI compiler
 430 # feature detection have not, the docstrings for any over-rides of
 431 # GROMACS defaults or user settings will make sense. Also, any
 432 # toolchain-related reasons for choosing whether to detect various
 433 # things can be sorted out now, before the detection takes place.
 434 if(GMX_TARGET_FUJITSU_SPARC64)
 435     include(gmxManageFujitsuSparc64)
 436 endif()
 437
 438 ########################################################################
 439 #Process MPI settings
 440 ########################################################################
 441 include(gmxManageMPI)
 442
 443 ########################################################################
 444 #Process MiMiC settings
 445 ########################################################################
 446 include(gmxManageMimic)
 447
 448 ########################################################################
 449 #Process shared/static library settings
 450 ########################################################################
 451 include(gmxManageSharedLibraries)
 452
 453
 454 ########################################################################
 455 # Find external packages                                               #
 456 ########################################################################
 457
 458 # Unconditionally find the package, as it is also required for unit
 459 # tests. This exports LIBXML2_FOUND, which we should not use because
 460 # it does not tell us that linking will succeed. Instead, we test that
 461 # next.
 462 #if(DEFINED LIBXML2_LIBRARIES)
 463 #  set(LibXml2_FIND_QUIETLY TRUE)
 464 #endif()
 465 #find_package(LibXml2)
 466 #include(gmxTestLibXml2)
 467 #gmx_test_libxml2(HAVE_LIBXML2)
 468 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 469 #set(PKG_XML "")
 470 #mark_as_advanced(GMX_XML)
 471 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 472 #if(GMX_XML AND NOT HAVE_LIBXML2)
 473 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 474 #endif()
 475 #if(GMX_XML)
 476 #    include_directories(${LIBXML2_INCLUDE_DIR})
 477 #    set(PKG_XML libxml-2.0)
 478 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 479 #endif()
 480
 481 gmx_option_trivalue(
 482     GMX_HWLOC
 483     "Use hwloc portable hardware locality library"
 484     "AUTO")
 485
 486 if (GMX_HWLOC)
 487     # Find quietly the second time.
 488     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 489         set(HWLOC_FIND_QUIETLY TRUE)
 490     endif()
 491     find_package(HWLOC 1.5)
 492
 493     if (HWLOC_FOUND)
 494         if (HWLOC_LIBRARIES MATCHES ".a$")
 495             set(_STATIC_HWLOC TRUE)
 496         endif()
 497
 498         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 499         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 500             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 501             set(GMX_USE_HWLOC OFF)
 502         else()
 503             set(GMX_USE_HWLOC ON)
 504         endif()
 505
 506         if (GMX_USE_HWLOC)
 507             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 508             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 509         endif()
 510     elseif(GMX_HWLOC_FORCE)
 511         message(FATAL_ERROR "HWLOC package support required, but not found.")
 512     endif()
 513
 514     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 515 endif()
 516
 517 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 518 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 519 if(GMX_EXTERNAL_TINYXML2)
 520     # Find an external TinyXML-2 library.
 521     find_package(TinyXML-2 3.0.0)
 522     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 523     if(NOT HAVE_TINYXML2)
 524         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 525     endif()
 526 endif()
 527
 528 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 529 mark_as_advanced(GMX_EXTRAE)
 530
 531 if (GMX_EXTRAE)
 532   find_package(EXTRAE)
 533   if(EXTRAE_FOUND)
 534     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 535     set(HAVE_EXTRAE 1)
 536   else()
 537     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 538   endif()
 539 endif()
 540
 541 option(GMX_X11 "Use X window system" OFF)
 542 if (GMX_X11)
 543     find_package(X11)
 544     # X11 includes/libraries are only set in the ngmx subdirectory!
 545     if(NOT X11_FOUND)
 546         message(FATAL_ERROR
 547                 "X11 include files and/or libraries were not found. "
 548                 "Set GMX_X11=OFF to compile without X11 support. "
 549                 "gmx view will not be available.")
 550     endif()
 551     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 552 endif()
 553
 554 include(ThreadMPI)
 555 # Enable core threading facilities
 556 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 557 if(GMX_THREAD_MPI)
 558     # enable MPI functions
 559     tmpi_enable()
 560     set(MPI_IN_PLACE_EXISTS 1)
 561 endif()
 562 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 563 if (TMPI_ATOMICS_DISABLED)
 564    add_definitions(-DTMPI_ATOMICS_DISABLED)
 565 endif()
 566
 567 include(gmxManageTNG)
 568
 569 include(gmxManageLmfit)
 570
 571 if(GMX_GPU)
 572     # now that we have detected the dependencies, do the second configure pass
 573     gmx_gpu_setup()
 574     if (GMX_CLANG_CUDA)
 575         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 576         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 577     endif()
 578 endif()
 579
 580 if(CYGWIN)
 581     set(GMX_CYGWIN 1)
 582 endif()
 583
 584 if(WIN32)
 585     set(GMX_NATIVE_WINDOWS 1)
 586     # This makes windows.h not declare min/max as macros that would break
 587     # C++ code using std::min/std::max.
 588     add_definitions(-DNOMINMAX)
 589 endif()
 590
 591 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 592 mark_as_advanced(GMX_BUILD_UNITTESTS)
 593 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 594
 595 ########################################################################
 596 # Our own GROMACS tests
 597 ########################################################################
 598
 599 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 600 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 601 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 602
 603 include(gmxTestInlineASM)
 604 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 605
 606 include(gmxSetBuildInformation)
 607 gmx_set_build_information()
 608
 609 gmx_option_multichoice(
 610     GMX_USE_RDTSCP
 611     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 612     "AUTO"
 613     OFF ON AUTO DETECT)
 614 mark_as_advanced(GMX_USE_RDTSCP)
 615
 616 macro(gmx_check_rdtscp)
 617     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 618         set(HAVE_RDTSCP 1)
 619         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 620     else()
 621         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 622     endif()
 623 endmacro()
 624
 625 set(HAVE_RDTSCP 0)
 626 if (GMX_USE_RDTSCP STREQUAL "ON")
 627     set(HAVE_RDTSCP 1)
 628 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 629     gmx_check_rdtscp()
 630 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 631     # If the user specified automated SIMD selection, that the choice
 632     # is made based on detection on the build host. If so, then RDTSCP
 633     # should be chosen the same way.
 634     #
 635     # If the user specified an AVX SIMD level (e.g. when
 636     # cross-compiling GROMACS) then they will get our best guess, ie
 637     # that in practice AVX mostly correlates with rdtscp (and anyway
 638     # is only relevant in rather old x86 hardware).
 639     if (GMX_SIMD STREQUAL "AUTO")
 640         gmx_check_rdtscp()
 641     elseif (GMX_SIMD MATCHES "AVX")
 642         set(HAVE_RDTSCP 1)
 643     endif()
 644 endif()
 645 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 646 if (HAVE_RDTSCP_CHANGED)
 647     if (HAVE_RDTSCP)
 648         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 649     else()
 650         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 651     endif()
 652 endif()
 653
 654 include(gmxTestLargeFiles)
 655 gmx_test_large_files(GMX_LARGEFILES)
 656
 657 include(gmxTestSignal)
 658 gmx_test_sigusr1(HAVE_SIGUSR1)
 659
 660 include(gmxTestPipes)
 661 gmx_test_pipes(HAVE_PIPES)
 662
 663 include(gmxTestXDR)
 664 gmx_test_xdr(GMX_SYSTEM_XDR)
 665 # Darwin has system XDR, but it uses a three-argument flavour of
 666 # xdrproc_t that it guarantees will still work if you pass the normal
 667 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 668 # to do that, so it's simpler to just use our own XDR library.
 669 #
 670 # TODO It would be better to craft a cmake test which fails if such
 671 # XDR operations cause warnings, and succeeds otherwise, because it is
 672 # generally preferable to use system libraries where possible.
 673 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 674     set(GMX_INTERNAL_XDR 1)
 675 endif()
 676
 677
 678 ##################################################
 679 # Process SIMD instruction settings
 680 ##################################################
 681 # This checks what flags to add in order to
 682 # support the SIMD instructions we need, it sets
 683 # correct defines for the SIMD instructions supported,
 684 # and adds advanced options to control accuracy
 685 # for SIMD math operations.
 686 include(gmxManageSimd)
 687 gmx_manage_simd()
 688
 689 ##################################################
 690 # Process FFT library settings
 691 ##################################################
 692 include(gmxManageFFTLibraries)
 693
 694
 695 include(gmxManageLinearAlgebraLibraries)
 696
 697 include(gmxManagePluginSupport)
 698
 699 if (GMX_USE_PLUGINS)
 700     if(NOT GMX_VMD_PLUGIN_PATH)
 701         find_package(VMD)
 702     endif()
 703 endif()
 704
 705 # Link real-time library for POSIX timers. The check for clock_gettime
 706 # confirms the linkability of rt.
 707 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 708     list(APPEND GMX_EXTRA_LIBRARIES rt)
 709 endif()
 710
 711 # Math and thread libraries must often come after all others when linking...
 712 if (HAVE_LIBM)
 713     list(APPEND GMX_PUBLIC_LIBRARIES m)
 714 endif()
 715
 716 option(GMX_NACL "Configure for Native Client builds" OFF)
 717 if (GMX_NACL)
 718   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 719   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 720   # TODO: Is this still necessary with the check for its presence?
 721   set(GMX_USE_NICE 0)
 722   set(GMX_NO_RENAME 1)
 723 endif()
 724 mark_as_advanced(GMX_NACL)
 725
 726 if(GMX_FAHCORE)
 727   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 728       "Path to swindirect.h")
 729   include_directories(${COREWRAP_INCLUDE_DIR})
 730 endif()
 731
 732 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 733 # produce warnings if that fails.
 734 set(build_help_default AUTO)
 735 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 736     set(build_help_default OFF)
 737 endif()
 738 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 739 mark_as_advanced(GMX_BUILD_HELP)
 740 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 741     message(FATAL_ERROR
 742         "Rebuilding shell completions or man pages is not supported for "
 743         "in-source builds from a source distribution. "
 744         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 745 endif()
 746
 747 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 748 # these are set after everything else
 749 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 750     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 751     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 752 else()
 753     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 754     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 755     foreach(build_type ${build_types_with_explicit_flags})
 756         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 757     endforeach()
 758     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 759     foreach(build_type ${build_types_with_explicit_flags})
 760         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 761     endforeach()
 762     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 763     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 764 endif()
 765 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 766 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 767
 768 ########################################################################
 769 # Specify install locations
 770 ########################################################################
 771 # Use GNUInstallDirs to set paths on multiarch systems.
 772 include(GNUInstallDirs)
 773
 774 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 775 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 776
 777 # Internal convenience so we do not have to join two path segments in the code
 778 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 779
 780 # If the nesting level wrt. the installation root is changed,
 781 # gromacs-config.cmake.cmakein needs to be adapted.
 782 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 783
 784 # TODO: Make GMXRC adapt if this is changed
 785 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 786 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 787
 788 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 789
 790 # Binary and library suffix options
 791 include(gmxManageSuffixes)
 792
 793 ################################################################
 794 # Shared library load path settings
 795 ################################################################
 796 if(NOT GMX_BUILD_SHARED_EXE)
 797     # No rpath
 798     set(CMAKE_SKIP_RPATH TRUE)
 799     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 800     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 801 else()
 802     # The build folder always has bin/ and lib/; if we are also going to
 803     # install to lib/, then the installation RPATH works also in the build
 804     # tree.  This makes installation slightly faster (no need to rewrite the
 805     # RPATHs), and makes the binaries in the build tree relocatable.
 806     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 807         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 808         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 809     endif()
 810     # Set the RPATH as relative to the executable location to make the
 811     # binaries relocatable.
 812     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 813         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 814         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 815     else()
 816         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 817     endif()
 818     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 819     set(CMAKE_MACOSX_RPATH 1)
 820 endif()
 821
 822 #COPYING file: Only necessary for binary distributions.
 823 #Simpler to always install.
 824 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 825
 826 if (GMX_BUILD_FOR_COVERAGE)
 827     # Code heavy with asserts makes conditional coverage close to useless metric,
 828     # as by design most of the false branches are impossible to trigger in
 829     # correctly functioning code.  And the benefit of testing those that could
 830     # be triggered by using an API against its specification isn't usually
 831     # worth the effort.
 832     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 833 endif()
 834
 835 if (BUILD_TESTING)
 836     include(tests/CheckTarget.cmake)
 837 endif()
 838
 839 # TODO: Determine control flow and defaults for package installation and testing use cases.
 840 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 841 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 842 mark_as_advanced(GMX_PYTHON_PACKAGE)
 843
 844 if (NOT GMX_BUILD_MDRUN_ONLY)
 845     # Note: Though only documented as an output variable, PYTHON_EXECUTABLE is
 846     # also effective as a CMake input variable to effectively hint the location
 847     # of the Python interpreter. This may be helpful in environments with both
 848     # Python 2 and Python 3 on the default PATH.
 849     # Ref: https://cmake.org/cmake/help/latest/module/FindPythonInterp.html
 850     if(FIND_PACKAGE_MESSAGE_DETAILS_PythonInterp)
 851         # Keep quiet on subsequent runs of cmake
 852         set(PythonInterp_FIND_QUIETLY ON)
 853     endif()
 854     # Older CMake versions might not search for Python newer than 3.7.
 855     set(Python_ADDITIONAL_VERSIONS 3.8)
 856     if(GMX_PYTHON_PACKAGE)
 857         find_package(PythonInterp 3.6 REQUIRED)
 858         # Note: PythonLibs will be found later by pybind11.
 859         # TODO: (Issue #2998) When CMake >= 3.12 is required, update detection.
 860         # I.e.  find_package(Python3 3.6 COMPONENTS Interpreter Development REQUIRED)
 861     else()
 862         find_package(PythonInterp 3.6)
 863     endif()
 864     find_package(ImageMagick QUIET COMPONENTS convert)
 865     include(gmxTestImageMagick)
 866     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 867     # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 868     add_subdirectory(docs)
 869     add_subdirectory(share)
 870     add_subdirectory(scripts)
 871 endif()
 872 add_subdirectory(src)
 873
 874 if (BUILD_TESTING)
 875     add_subdirectory(tests)
 876 endif()
 877
 878 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 879     add_subdirectory(python_packaging)
 880 endif()
 881
 882 gmx_cpack_write_config()
 883
 884 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 885 # Don't bother the user after the first configure pass.
 886 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 887     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 888 endif()
 889 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 890
 891 #######################
 892 ## uninstall target
 893 #######################
 894 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 895                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 896                   IMMEDIATE @ONLY)
 897 ###########################
 898 ADD_CUSTOM_TARGET(uninstall
 899                   "${CMAKE_COMMAND}" -P
 900                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 901 ###########################
 902 set_directory_properties(PROPERTIES
 903             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")