CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # acceleration possibilities on that hardware, suggest an acceleration
 189 # to use if none is specified, and populate the cache option for CPU
 190 # accleration.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectAcceleration)
 194 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 195
 196 gmx_option_multichoice(
 197     GMX_CPU_ACCELERATION
 198     "Acceleration for CPU kernels and compiler optimization"
 199     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 200     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 201
 202 gmx_option_multichoice(
 203     GMX_FFT_LIBRARY
 204     "FFT library"
 205     "fftw3"
 206     fftw3 mkl "fftpack[built-in]")
 207 gmx_dependent_option(
 208     GMX_BUILD_OWN_FFTW
 209     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 210     OFF
 211     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 212 gmx_dependent_option(
 213     GMX_DISABLE_FFTW_MEASURE
 214     "Do not optimize FFTW setups (not needed with SSE)"
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 218 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 219
 220 gmx_option_multichoice(
 221     GMX_QMMM_PROGRAM
 222     "QM package for QM/MM"
 223     None
 224     none gaussian mopac gamess orca)
 225
 226 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 227 mark_as_advanced(GMX_BROKEN_CALLOC)
 228 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 229 mark_as_advanced(GMX_LOAD_PLUGINS)
 230
 231 option(GMX_GPU  "Enable GPU acceleration" ON)
 232 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 233
 234 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 235
 236 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 237 mark_as_advanced(GMX_GIT_VERSION_INFO)
 238
 239 if(UNIX)
 240     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 241 endif()
 242 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 243
 244 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 245 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 246
 247 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 248 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 249
 250 option(GMX_BUILD_FOR_COVERAGE
 251        "Tune build for better code coverage metrics (e.g., disable asserts)"
 252        OFF)
 253 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 254
 255
 256 ######################################################################
 257 # Detect OpenMP support
 258 ######################################################################
 259 # The OpenMP detection _must_ come before tests for other CFLAGS.
 260 include(gmxManageOpenMP)
 261
 262
 263
 264 ######################################################################
 265 # Compiler tests
 266 # These need to be done early (before further tests).
 267 #####################################################################
 268
 269 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 270 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 271 # invalid options with the Intel Compilers.
 272 # These files should be removed from the source tree when a CMake version that
 273 # includes the features in question becomes required for building GROMACS.
 274 include(CheckCCompilerFlag)
 275 include(CheckCXXCompilerFlag)
 276
 277
 278 include(gmxCFlags)
 279 gmx_c_flags()
 280
 281 # This variable should be used for additional compiler flags which are not
 282 # generated in gmxCFlags nor are acceleration or MPI related.
 283 set(EXTRA_C_FLAGS "")
 284 set(EXTRA_CXX_FLAGS "")
 285
 286 # Run through a number of tests for buggy compilers and other issues
 287 include(gmxTestCompilerProblems)
 288 gmx_test_compiler_problems()
 289
 290
 291 set(PKG_CFLAGS "")
 292 if(GMX_DOUBLE)
 293     add_definitions(-DGMX_DOUBLE)
 294     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 295 endif(GMX_DOUBLE)
 296 if(GMX_SOFTWARE_INVSQRT)
 297   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 298 endif(GMX_SOFTWARE_INVSQRT)
 299
 300
 301
 302 ########################################################################
 303 # Basic system tests (standard libraries, headers, functions, types)   #
 304 ########################################################################
 305 include(CheckIncludeFiles)
 306 include(CheckIncludeFileCXX)
 307 check_include_files(unistd.h     HAVE_UNISTD_H)
 308 check_include_files(pwd.h        HAVE_PWD_H)
 309 check_include_files(dirent.h     HAVE_DIRENT_H)
 310 check_include_files(time.h       HAVE_TIME_H)
 311 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 312 check_include_files(io.h         HAVE_IO_H)
 313 check_include_files(sched.h      HAVE_SCHED_H)
 314
 315 check_include_files(regex.h      HAVE_POSIX_REGEX)
 316 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 317 # TODO: It could be nice to inform the user if no regex support is found,
 318 # as selections won't be fully functional.
 319
 320 include(CheckFunctionExists)
 321 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 322 check_function_exists(memalign          HAVE_MEMALIGN)
 323 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 324 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 325 check_function_exists(fsync             HAVE_FSYNC)
 326 check_function_exists(_fileno           HAVE__FILENO)
 327 check_function_exists(fileno            HAVE_FILENO)
 328 check_function_exists(_commit           HAVE__COMMIT)
 329 check_function_exists(sigaction         HAVE_SIGACTION)
 330 check_function_exists(sysconf           HAVE_SYSCONF)
 331 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 332 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 333 check_function_exists(rsqrt             HAVE_RSQRT)
 334 check_function_exists(rsqrtf            HAVE_RSQRTF)
 335 check_function_exists(sqrtf             HAVE_SQRTF)
 336
 337 include(CheckLibraryExists)
 338 check_library_exists(m sqrt "" HAVE_LIBM)
 339 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 340
 341 include(TestBigEndian)
 342 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 343
 344 # Management of GROMACS options for specific toolchains should go
 345 # here. Because the initial settings for some of the main options have
 346 # already happened, but things like library detection and MPI compiler
 347 # feature detection have not, the docstrings for any over-rides of
 348 # GROMACS defaults or user settings will make sense. Also, any
 349 # toolchain-related reasons for choosing whether to detect various
 350 # things can be sorted out now, before the detection takes place.
 351 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 352     include(gmxManageBlueGene)
 353 endif()
 354
 355 ########################################################################
 356 #Process MPI settings
 357 ########################################################################
 358 include(gmxManageMPI)
 359
 360
 361 ########################################################################
 362 #Process shared/static library settings
 363 ########################################################################
 364 include(gmxManageSharedLibraries)
 365
 366
 367 ########################################################################
 368 # Find external packages                                               #
 369 ########################################################################
 370
 371 # Unconditionally find the package, as it is also required for unit
 372 # tests. This exports LIBXML2_FOUND, which we should not use because
 373 # it does not tell us that linking will succeed. Instead, we test that
 374 # next.
 375 find_package(LibXml2)
 376 include(gmxTestLibXml2)
 377 gmx_test_libxml2(HAVE_LIBXML2)
 378 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 379 set(PKG_XML "")
 380 mark_as_advanced(GMX_XML)
 381 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 382 #if(GMX_XML AND NOT HAVE_LIBXML2)
 383 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 384 #endif()
 385 #if(GMX_XML)
 386 #    include_directories(${LIBXML2_INCLUDE_DIR})
 387 #    set(PKG_XML libxml-2.0)
 388 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 389 #endif(GMX_XML)
 390
 391 option(GMX_GSL "Add support for gsl" OFF)
 392 if (GMX_GSL)
 393   find_package(GSL)
 394   set(PKG_GSL "")
 395   if(GSL_FOUND)
 396     include_directories(${GSL_INCLUDE_DIR})
 397     set(PKG_GSL gsl)
 398     set(HAVE_LIBGSL 1)
 399   endif(GSL_FOUND)
 400 endif (GMX_GSL)
 401
 402 option(GMX_X11 "Use X window system" OFF)
 403 if (GMX_X11)
 404     find_package(X11)
 405     # X11 includes/libraries are only set in the ngmx subdirectory!
 406     if(NOT X11_FOUND)
 407         message(FATAL_ERROR
 408                 "X11 include files and/or libraries were not found. "
 409                 "Set GMX_X11=OFF to compile without X11 support. "
 410                 "gmx view will not be available.")
 411     endif()
 412     include_directories(${X11_INCLUDE_DIR})
 413 endif(GMX_X11)
 414
 415 include(ThreadMPI)
 416 set(THREAD_MPI_LIB thread_mpi)
 417 # Enable core threading facilities
 418 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 419 # Enable tMPI C++ support
 420 tmpi_enable_cxx()
 421 if(GMX_THREAD_MPI)
 422     # enable MPI functions
 423     tmpi_enable()
 424     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 425     set(GMX_MPI 1)
 426     set(MPI_IN_PLACE_EXISTS 1)
 427 endif(GMX_THREAD_MPI)
 428 tmpi_get_source_list(THREAD_MPI_SRC)
 429
 430 if(GMX_GPU)
 431     # now that we have detected the dependencies, do the second configure pass
 432     gmx_gpu_setup()
 433 endif(GMX_GPU)
 434
 435 if(CYGWIN)
 436     set(GMX_CYGWIN 1)
 437 endif(CYGWIN)
 438
 439 if(WIN32 AND NOT CYGWIN)
 440     set(GMX_NATIVE_WINDOWS 1)
 441     # This makes windows.h not declare min/max as macros that would break
 442     # C++ code using std::min/std::max.
 443     add_definitions(-DNOMINMAX)
 444 endif()
 445
 446 # only bother with finding git and using version.h if the source is a git repo
 447 if(GMX_GIT_VERSION_INFO)
 448     if (NOT SOURCE_IS_GIT_REPOSITORY)
 449         message(FATAL_ERROR
 450             "Cannot generate git version information from source tree not under git. "
 451             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 452     endif ()
 453     # We need at least git v1.5.3 be able to parse git's date output. If not
 454     # found or the version is too small, we can't generate version information.
 455     find_package(Git)
 456
 457     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 458         message(FATAL_ERROR
 459             "No compatible git version found (>= 1.5.3 required). "
 460             "Won't be able to generate development version information. "
 461             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 462     endif()
 463 endif()
 464
 465 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 466 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 467 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 468     find_package(Boost 1.44.0)
 469     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 470         set(Boost_FOUND FALSE)
 471     endif()
 472     # Print the notification only on first run, when determining the default
 473     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 474         message("Boost >= 1.44 not found. Using minimal internal version. "
 475                 "This may cause trouble if you plan on compiling/linking other "
 476                 "software that uses Boost against Gromacs.")
 477     endif()
 478 endif()
 479 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 480        ${Boost_FOUND})
 481 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 482     message(FATAL_ERROR
 483         "Boost >= 1.44 not found. "
 484         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 485         "version of Boost included with Gromacs.")
 486 endif()
 487
 488 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 489 mark_as_advanced(GMX_BUILD_UNITTESTS)
 490 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 491 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 492     message(FATAL_ERROR
 493         "Cannot build unit tests without libxml2. "
 494         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 495 endif()
 496
 497 ########################################################################
 498 # Generate development version info for cache
 499 ########################################################################
 500 # set(GEN_VERSION_INFO_INTERNAL "ON")
 501 # include(gmxGenerateVersionString)
 502
 503 ########################################################################
 504 # Our own GROMACS tests
 505 ########################################################################
 506
 507 add_definitions( -DHAVE_CONFIG_H )
 508 include_directories(${CMAKE_SOURCE_DIR}/src)
 509 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 510 include_directories(${CMAKE_BINARY_DIR}/src)
 511 # Required for gmx_header_config_gen.h to be found before installation
 512 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 513 # Required for now to make old code compile
 514 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 515
 516 include(gmxTestInlineASM)
 517 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 518
 519 include(gmxSetBuildInformation)
 520 gmx_set_build_information()
 521 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 522     set(HAVE_RDTSCP 1)
 523 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 524
 525 include(gmxTestFloatFormat)
 526 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 527                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 528                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 529
 530 include(gmxTestLargeFiles)
 531 gmx_test_large_files(GMX_LARGEFILES)
 532
 533 include(gmxTestSignal)
 534 gmx_test_sigusr1(HAVE_SIGUSR1)
 535
 536 include(gmxTestInline)
 537 gmx_test_inline(INLINE_KEYWORD)
 538
 539 include(gmxTestRestrict)
 540 gmx_test_restrict(RESTRICT_KEYWORD)
 541
 542 include(gmxTestPipes)
 543 gmx_test_pipes(HAVE_PIPES)
 544
 545 include(gmxTestIsfinite)
 546 gmx_test_isfinite(HAVE_ISFINITE)
 547 gmx_test__isfinite(HAVE__ISFINITE)
 548 gmx_test__finite(HAVE__FINITE)
 549
 550 include(gmxTestCXX11)
 551 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 552 include(CMakeDependentOption)
 553 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 554 # entirely to keep the compilation environment uniform.
 555 cmake_dependent_option(GMX_CXX11
 556     "Use C++11 features"
 557     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 558 mark_as_advanced(GMX_CXX11)
 559 if(GMX_CXX11)
 560     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 561 endif()
 562
 563
 564 include(gmxTestXDR)
 565 gmx_test_xdr(GMX_SYSTEM_XDR)
 566 if(NOT GMX_SYSTEM_XDR)
 567     set(GMX_INTERNAL_XDR 1)
 568 endif(NOT GMX_SYSTEM_XDR)
 569
 570 # include avx test source, used if the AVX flags are set below
 571 include(gmxTestAVXMaskload)
 572
 573 # Process nonbonded accelerated kernels settings
 574 #
 575 # Note that for the backward-compatible x86 SIMD architectures, the
 576 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 577 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 578 # SSE2). Accordingly, there are a set of CMake variables
 579 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 580 # CPU features that should be used. This means that the logic for
 581 # requiring such backward compatibility is all located here.
 582 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 583     # nothing to do
 584     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 585
 586 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 587
 588     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 589     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 590         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 591     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 592
 593     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 594     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 595         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 596     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 597
 598     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 599
 600     # Only test the include after we have tried to add the correct flag for SSE2 support
 601     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 602
 603     if(NOT HAVE_EMMINTRIN_H)
 604         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 605     endif(NOT HAVE_EMMINTRIN_H)
 606
 607     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 608     # The user should not be able to set this orthogonally to the acceleration
 609     set(GMX_X86_SSE2 1)
 610     set(ACCELERATION_STATUS_MESSAGE
 611         "Enabling SSE2 Gromacs acceleration")
 612
 613 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 614
 615     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 616     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 617         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 618     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 619     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 620         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 621         # intrinsics when SSE2 support is enabled, so we try that instead first.
 622         if (GMX_NATIVE_WINDOWS)
 623             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 624             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 625         else()
 626             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 627         endif()
 628     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 629
 630     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 631     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 632         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 633     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 634     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 635         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 636         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 637         # intrinsics when SSE2 support is enabled, so we try that instead.
 638         if (GMX_NATIVE_WINDOWS)
 639             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 640         endif()
 641     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 642
 643     # This must come after we have added the -msse4.1 flag on some platforms.
 644     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 645
 646     if(NOT HAVE_SMMINTRIN_H)
 647         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 648     endif(NOT HAVE_SMMINTRIN_H)
 649
 650     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 651         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 652     endif()
 653
 654     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 655     # The user should not be able to set this orthogonally to the acceleration
 656     set(GMX_X86_SSE4_1 1)
 657     set(GMX_X86_SSE2   1)
 658     set(ACCELERATION_STATUS_MESSAGE
 659         "Enabling SSE4.1 Gromacs acceleration")
 660
 661 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 662
 663     # Set the AVX compiler flag for both these choices!
 664
 665     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 666     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 667         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 668     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 669     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 670         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 671     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 672
 673     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 674     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 675         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 676     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 677     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 678         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 679     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 680
 681     # Set the FMA4 flags (MSVC doesn't require any)
 682     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 683         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 684         if (NOT GNU_FMA_CFLAG)
 685             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 686         endif(NOT GNU_FMA_CFLAG)
 687         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 688         # No big deal if we do not have xop, so no point yelling warnings about it.
 689         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 690         if (NOT GNU_FMA_CXXFLAG)
 691             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 692         endif (NOT GNU_FMA_CXXFLAG)
 693         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 694         # No big deal if we do not have xop, so no point yelling warnings about it.
 695     endif()
 696
 697     # Only test the header after we have tried to add the flag for AVX support
 698     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 699
 700     if(NOT HAVE_IMMINTRIN_H)
 701         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 702     endif(NOT HAVE_IMMINTRIN_H)
 703
 704     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 705         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 706             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 707             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 708         if(NOT TEST_AVX)
 709             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 710         endif()
 711     endif()
 712
 713     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 714     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 715     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 716
 717     # The user should not be able to set this orthogonally to the acceleration
 718     set(GMX_X86_SSE4_1 1)
 719     set(GMX_X86_SSE2   1)
 720
 721     # But just enable one of the choices internally...
 722     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 723         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 724         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 725         # hackintoshes is not worth the effort.
 726         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 727                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 728             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 729         endif()
 730
 731         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 732             # we assume that we have an external assembler that supports AVX
 733             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 734             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 735         endif()
 736         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 737             # we assume that we have an external assembler that supports AVX
 738             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 739             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 740         endif()
 741
 742         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 743         set(GMX_X86_AVX_128_FMA 1)
 744         set(ACCELERATION_STATUS_MESSAGE
 745             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 746
 747     else()
 748         # If we are not doing AVX_128, it must be AVX_256...
 749         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 750         set(GMX_X86_AVX_256 1)
 751         set(ACCELERATION_STATUS_MESSAGE
 752             "Enabling 256-bit AVX Gromacs acceleration")
 753     endif()
 754
 755     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 756     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 757     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 758
 759 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 760     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 761         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 762
 763     if (TEST_QPX)
 764         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 765         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 766     else()
 767         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 768     endif()
 769 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 770     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 771 else()
 772     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 773 endif()
 774 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 775 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 776     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 777 endif()
 778
 779 # Process QM/MM Settings
 780 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 781     set(GMX_QMMM_GAUSSIAN 1)
 782 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 783     set(GMX_QMMM_MOPAC 1)
 784 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 785     set(GMX_QMMM_GAMESS 1)
 786 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 787     set(GMX_QMMM_ORCA 1)
 788 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 789     # nothing to do
 790 else()
 791     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 792 endif()
 793
 794
 795 ##################################################
 796 # Process FFT library settings
 797 ##################################################
 798 include(gmxManageFFTLibraries)
 799
 800
 801 include(gmxManageLinearAlgebraLibraries)
 802
 803 # Whether GROMACS will really try to compile support for VMD plugins
 804 set(GMX_USE_PLUGINS OFF)
 805
 806 if(GMX_LOAD_PLUGINS)
 807   if(CYGWIN OR NOT WIN32)
 808     # Native Windows does not have, nor need dlopen
 809     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 810     include(gmxTestdlopen)
 811     gmx_test_dlopen(HAVE_DLOPEN)
 812   endif()
 813
 814   # so, should we use plug-ins?
 815   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 816     if(NOT VMD_QUIETLY)
 817       MESSAGE(STATUS
 818           "Found the ability to use plug-ins when building shared libaries, "
 819           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 820           "formats).")
 821     endif()
 822     if(NOT GMX_VMD_PLUGIN_PATH)
 823       find_package(VMD)
 824     endif()
 825     set(GMX_USE_PLUGINS ON)
 826     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 827     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 828   else()
 829     set(PKG_DL_LIBS)
 830   endif()
 831 endif(GMX_LOAD_PLUGINS)
 832 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 833
 834 # Link real-time library for POSIX timers. The check for clock_gettime
 835 # confirms the linkability of rt.
 836 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 837     list(APPEND GMX_EXTRA_LIBRARIES rt)
 838 endif()
 839
 840 # Math and thread libraries must often come after all others when linking...
 841 if(HAVE_LIBM)
 842     list(APPEND GMX_EXTRA_LIBRARIES m)
 843 endif(HAVE_LIBM)
 844 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 845     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 846     if(HAVE_MASS_SIMD)
 847         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 848     else()
 849         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 850     endif()
 851 endif()
 852
 853
 854 option(GMX_NACL "Configure for Native Client builds" OFF)
 855 if (GMX_NACL)
 856   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 857   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 858   set(GMX_NO_NICE 1)
 859   set(GMX_NO_RENAME 1)
 860 endif()
 861 mark_as_advanced(GMX_NACL)
 862
 863 if(GMX_FAHCORE)
 864   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 865       "Path to swindirect.h")
 866   include_directories(${COREWRAP_INCLUDE_DIR})
 867 endif(GMX_FAHCORE)
 868
 869 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 870 mark_as_advanced(GMX_BUILD_HELP)
 871 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 872     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 873
 874     message(FATAL_ERROR
 875         "Rebuilding HTML and man pages is not supported for in-source "
 876         "builds from a source distribution. "
 877         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 878 endif()
 879
 880 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 881 # these are set after everything else
 882 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 883     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 884     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 885     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 886     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 887 else()
 888     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 889     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 890     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 891     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 892     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 893     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 894     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 895     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 896     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 897 endif()
 898
 899 if(NOT GMX_OPENMP)
 900     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 901     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 902     unset(OpenMP_C_FLAGS CACHE)
 903     unset(OpenMP_CXX_FLAGS CACHE)
 904 else()
 905     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 906     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 907 endif()
 908 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 909
 910 ########################################################################
 911 # Specify install locations
 912 ########################################################################
 913 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 914     "Library installation directory (default: lib)")
 915 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 916     "Data installation directory under share/ (default: gromacs)")
 917 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 918
 919 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 920 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 921 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 922 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 923 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 924
 925 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 926 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 927
 928 # Binary and library suffix options
 929 include(gmxManageSuffixes)
 930
 931 ##################################################################
 932 # Shared library settings
 933 ##################################################################
 934 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 935     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 936     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 937     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 938     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 939 else()
 940     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 941         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 942         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 943     else()
 944         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 945     endif()
 946 endif()
 947
 948 #COPYING file: Only necessary for binary distributions.
 949 #Simpler to always install.
 950 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 951
 952 if(GMX_EXTERNAL_BOOST)
 953     include_directories(${Boost_INCLUDE_DIRS})
 954 else()
 955     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 956     # typeid not supported for minimal internal version
 957     # (would add significant amount of code)
 958     add_definitions(-DBOOST_NO_TYPEID)
 959     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 960     # (from share/template/)
 961     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 962     if (NOT GMX_BUILD_MDRUN_ONLY)
 963         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 964                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 965                 COMPONENT development)
 966     endif ()
 967 endif()
 968
 969 # TODO The Windows builds are still broken (we are avoiding some
 970 # unknown bug, perhaps with checkpointing?), because defaulting to
 971 # .tng output leads to calling null-op implementation functions, so
 972 # regressiontests will fail on Windows at the post-mdrun stages. We
 973 # can fix this during the 5.0 beta phase.
 974 gmx_add_cache_dependency(GMX_USE_TNG BOOL "NOT GMX_NATIVE_WINDOWS" OFF)
 975
 976 if(GMX_USE_TNG)
 977     find_package(ZLIB)
 978     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 979     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 980     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 981     # TODO reconsider use of OpenMP in TNG if/when trajectory writing is not serial in mdrun
 982     set(TNG_USE_OPENMP ${GMX_OPENMP} CACHE BOOL "Try to use the OpenMP library (if available) with TNG")
 983     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 984     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 985     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 986     set(GMX_TNG_LIBRARIES tng_io)
 987 endif()
 988 mark_as_advanced(TNG_BUILD_FORTRAN)
 989 mark_as_advanced(TNG_BUILD_EXAMPLES)
 990 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 991 mark_as_advanced(TNG_USE_OPENMP)
 992 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 993 mark_as_advanced(TNG_BUILD_TEST)
 994 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 995
 996 if (GMX_BUILD_FOR_COVERAGE)
 997     # Code heavy with asserts makes conditional coverage close to useless metric,
 998     # as by design most of the false branches are impossible to trigger in
 999     # correctly functioning code.  And the benefit of testing those that could
1000     # be triggered by using an API against its specification isn't usually
1001     # worth the effort.
1002     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1003 endif ()
1004
1005 if (BUILD_TESTING)
1006     # "tests" target builds all the separate test binaries.
1007     add_custom_target(tests)
1008     # "run-ctest" is an internal target that actually runs the tests.
1009     # This is necessary to be able to add separate targets that execute as part
1010     # of 'make check', but are ensured to be executed after the actual tests.
1011     add_custom_target(run-ctest
1012                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
1013                       COMMENT "Running all tests"
1014                       VERBATIM)
1015     add_dependencies(run-ctest tests)
1016     # "check" target builds and runs all tests.
1017     add_custom_target(check DEPENDS run-ctest)
1018 endif()
1019
1020 if (NOT GMX_BUILD_MDRUN_ONLY)
1021     add_subdirectory(doxygen)
1022     add_subdirectory(share)
1023     add_subdirectory(scripts)
1024 endif ()
1025 add_subdirectory(src)
1026
1027 if (BUILD_TESTING)
1028     add_subdirectory(tests)
1029 endif()
1030
1031 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1032 # Don't bother the user after the first configure pass.
1033 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1034     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1035 endif()
1036 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1037
1038 #######################
1039 ## uninstall target
1040 #######################
1041     CONFIGURE_FILE(
1042                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1043                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1044                    IMMEDIATE @ONLY)
1045 ###########################
1046 ADD_CUSTOM_TARGET(uninstall
1047                   "${CMAKE_COMMAND}" -P
1048                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1049 ###########################
1050
1051 ########################################################################
1052 # Manual                                                               #
1053 ########################################################################
1054
1055 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1056 mark_as_advanced(GMX_BUILD_MANUAL)
1057 if(GMX_BUILD_MANUAL)
1058     # Make sure we only do detection of manual-building dependencies
1059     # when the user opted in for that.
1060     add_subdirectory(manual)
1061 endif()