tests/CppCheck.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(CPPCHECK_EXECUTABLE
  36     NAMES cppcheck
  37     DOC "cppcheck executable")
  38 mark_as_advanced(CPPCHECK_EXECUTABLE)
  39 option(CPPCHECK_XML_OUTPUT "Whether to produce XML output from cppcheck (mainly for Jenkins)"
  40        OFF)
  41 mark_as_advanced(CPPCHECK_XML_OUTPUT)
  42
  43 # Depends on stderr redirection and cat
  44 if (CPPCHECK_EXECUTABLE AND UNIX)
  45     # Produce the list of files to check
  46     file(GLOB_RECURSE _inputfiles RELATIVE ${CMAKE_SOURCE_DIR}
  47         ${CMAKE_SOURCE_DIR}/src/*.c
  48         ${CMAKE_SOURCE_DIR}/src/*.cpp
  49         ${CMAKE_SOURCE_DIR}/src/*.cu)
  50     file(GLOB_RECURSE _files_to_ignore RELATIVE ${CMAKE_SOURCE_DIR}
  51         ${CMAKE_SOURCE_DIR}/src/nb_kernel_Elec*.c
  52         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_blas/*.c
  53         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_lapack/*.c
  54         ${CMAKE_SOURCE_DIR}/src/contrib/*.c
  55         ${CMAKE_SOURCE_DIR}/src/contrib/*.cpp
  56         ${CMAKE_SOURCE_DIR}/src/contrib/*.cu)
  57     list(REMOVE_ITEM _inputfiles ${_files_to_ignore})
  58
  59     # Set flags for cppcheck
  60     set(_outputext txt)
  61     set(_outputopt --template=gcc)
  62     if (CPPCHECK_XML_OUTPUT)
  63         set(_outputext xml)
  64         set(_outputopt --xml)
  65     endif()
  66     set(_common_flags
  67         --enable=style -DLINUX
  68         -I src/gromacs/legacyheaders -I src
  69         -I ${CMAKE_BINARY_DIR}/src -I ${CMAKE_BINARY_DIR}/src/gromacs/utility
  70         --quiet
  71         ${_outputopt})
  72     set(_c_flags
  73         -I src/gromacs/gmxpreprocess
  74         -I src/programs/mdrun
  75         --suppress=variableScope
  76         --suppress=unnecessaryForwardDeclaration
  77         --suppress=unusedVariable
  78         --suppress=unreadVariable
  79         --suppress=unusedStructMember
  80         --suppress=invalidscanf
  81         --suppress=sizeofCalculation
  82         --suppress=missingInclude:src/programs/mdrun/gmx_gpu_utils/gmx_gpu_utils.cu
  83         --inline-suppr)
  84     set(_cxx_flags
  85         -D__cplusplus
  86         --suppress=variableScope
  87         --suppress=unnecessaryForwardDeclaration
  88         --suppress=invalidscanf:src/gromacs/fileio/matio.cpp
  89         --suppress=invalidscanf:src/gromacs/gmxlib/xvgr.cpp
  90         --suppress=invalidscanf:src/gromacs/gmxpreprocess/pdb2top.cpp
  91         --suppress=*:src/gromacs/selection/scanner.cpp)
  92
  93     # This list will hold the list of all files with cppcheck errors
  94     # (one per input file)
  95     set(_filelist)
  96
  97     foreach (_filename ${_inputfiles})
  98         set(_target_name cppcheck-${_filename}.${_outputext})
  99         string(REPLACE "/" "_" _target_name ${_target_name})
 100         list(APPEND _filelist ${_target_name})
 101         if (_filename MATCHES "\\.cpp$")
 102             set(_lang CXX)
 103             set(_lang_flags ${_cxx_flags})
 104         else()
 105             set(_lang C)
 106             set(_lang_flags ${_c_flags})
 107         endif()
 108         add_custom_command(
 109             OUTPUT ${_target_name}
 110             COMMAND ${CPPCHECK_EXECUTABLE} ${_common_flags} ${_lang_flags}
 111                 ${_filename} 2> ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 112             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 113             IMPLICIT_DEPENDS ${_lang} ${CMAKE_SOURCE_DIR}/${_filename}
 114             COMMENT "Running cppcheck for ${_filename}"
 115             VERBATIM)
 116         if (NOT CPPCHECK_XML_OUTPUT)
 117             add_custom_command(
 118                 OUTPUT ${_target_name}
 119                 COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 120                 VERBATIM APPEND)
 121         endif()
 122     endforeach()
 123     if (NOT CPPCHECK_XML_OUTPUT)
 124         set(_target_name cppcheck-errors.${_outputext})
 125         add_custom_command(
 126             OUTPUT ${_target_name}
 127             COMMAND cat ${_filelist} > ${_target_name}
 128             DEPENDS ${_filelist}
 129             COMMENT "Combining cppcheck results"
 130             VERBATIM)
 131         list(APPEND _filelist ${_target_name})
 132     endif()
 133     add_custom_target(cppcheck DEPENDS ${_filelist})
 134 else()
 135     add_custom_target(cppcheck
 136         COMMAND ${CMAKE_COMMAND} -E echo
 137             "cppcheck was not found by CMake. Rerun CMake specifying CPPCHECK_EXECUTABLE."
 138         VERBATIM)
 139 endif()