tests/CppCheck.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(CPPCHECK_EXECUTABLE
  36     NAMES cppcheck
  37     DOC "cppcheck executable")
  38 mark_as_advanced(CPPCHECK_EXECUTABLE)
  39 option(CPPCHECK_XML_OUTPUT "Whether to produce XML output from cppcheck (mainly for Jenkins)"
  40        OFF)
  41 mark_as_advanced(CPPCHECK_XML_OUTPUT)
  42
  43 # Depends on stderr redirection and cat
  44 if (CPPCHECK_EXECUTABLE AND UNIX)
  45     # Produce the list of files to check
  46     file(GLOB_RECURSE _inputfiles RELATIVE ${CMAKE_SOURCE_DIR}
  47         ${CMAKE_SOURCE_DIR}/src/*.c
  48         ${CMAKE_SOURCE_DIR}/src/*.cpp
  49         ${CMAKE_SOURCE_DIR}/src/*.cu)
  50     file(GLOB_RECURSE _files_to_ignore RELATIVE ${CMAKE_SOURCE_DIR}
  51         ${CMAKE_SOURCE_DIR}/src/nb_kernel_Elec*.c
  52         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_blas/*.c
  53         ${CMAKE_SOURCE_DIR}/src/gromacs/linearalgebra/gmx_lapack/*.c
  54         ${CMAKE_SOURCE_DIR}/src/contrib/*.c
  55         ${CMAKE_SOURCE_DIR}/src/contrib/*.cpp
  56         ${CMAKE_SOURCE_DIR}/src/contrib/*.cu
  57         ${CMAKE_SOURCE_DIR}/src/external/*.c
  58         ${CMAKE_SOURCE_DIR}/src/external/*.cpp
  59         ${CMAKE_SOURCE_DIR}/src/external/*.cu
  60         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/scanner.cpp
  61         ${CMAKE_SOURCE_DIR}/src/gromacs/selection/parser.cpp
  62         )
  63     list(REMOVE_ITEM _inputfiles ${_files_to_ignore})
  64
  65     # Set flags for cppcheck
  66     set(_outputext txt)
  67     set(_outputopt --template=gcc)
  68     if (CPPCHECK_XML_OUTPUT)
  69         set(_outputext xml)
  70         set(_outputopt --xml)
  71     endif()
  72     set(_common_flags
  73         --enable=style -DLINUX -DHAVE_UNISTD_H
  74         -I src/gromacs/legacyheaders -I src
  75         -I src/external/thread_mpi/include
  76         -I ${CMAKE_BINARY_DIR}/src -I ${CMAKE_BINARY_DIR}/src/gromacs/utility
  77         --quiet
  78         --inline-suppr
  79         ${_outputopt})
  80     set(_c_flags
  81         --suppress=variableScope
  82         --suppress=unnecessaryForwardDeclaration
  83         --suppress=unusedVariable
  84         --suppress=unreadVariable
  85         --suppress=unusedStructMember
  86         --suppress=invalidscanf
  87         --suppress=sizeofCalculation
  88         --suppress=missingInclude:src/programs/mdrun/gmx_gpu_utils/gmx_gpu_utils.cu
  89         --suppress=*:src/external/Random123-1.08/include/Random123/features/compilerfeatures.h
  90         --suppress=assignIfError:src/gromacs/mdlib/nbnxn_atomdata.c #Ticket 5695
  91         --suppress=invalidPointerCast:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  92         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel.cuh
  93         --suppress=passedByValue:src/gromacs/mdlib/nbnxn_cuda/nbnxn_cuda_kernel_utils.cuh
  94         )
  95     set(_cxx_flags
  96         -D__cplusplus
  97         --suppress=variableScope
  98         --suppress=unnecessaryForwardDeclaration
  99         --suppress=invalidscanf:src/gromacs/fileio/matio.cpp
 100         --suppress=invalidscanf:src/gromacs/fileio/xvgr.cpp
 101         --suppress=invalidscanf:src/gromacs/topology/index.cpp
 102         --suppress=invalidscanf:src/gromacs/gmxpreprocess/pdb2top.cpp)
 103
 104     # This list will hold the list of all files with cppcheck errors
 105     # (one per input file)
 106     set(_filelist)
 107
 108     foreach (_filename ${_inputfiles})
 109         set(_target_name cppcheck-${_filename}.${_outputext})
 110         string(REPLACE "/" "_" _target_name ${_target_name})
 111         list(APPEND _filelist ${_target_name})
 112         if (_filename MATCHES "\\.cpp$")
 113             set(_lang CXX)
 114             set(_lang_flags ${_cxx_flags})
 115         else()
 116             set(_lang C)
 117             set(_lang_flags ${_c_flags})
 118         endif()
 119         add_custom_command(
 120             OUTPUT ${_target_name}
 121             COMMAND ${CPPCHECK_EXECUTABLE} ${_common_flags} ${_lang_flags}
 122                 ${_filename} 2> ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 123             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 124             IMPLICIT_DEPENDS ${_lang} ${CMAKE_SOURCE_DIR}/${_filename}
 125             COMMENT "Running cppcheck for ${_filename}"
 126             VERBATIM)
 127         if (NOT CPPCHECK_XML_OUTPUT)
 128             add_custom_command(
 129                 OUTPUT ${_target_name}
 130                 COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/${_target_name}
 131                 VERBATIM APPEND)
 132         endif()
 133     endforeach()
 134     if (NOT CPPCHECK_XML_OUTPUT)
 135         set(_target_name cppcheck-errors.${_outputext})
 136         add_custom_command(
 137             OUTPUT ${_target_name}
 138             COMMAND cat ${_filelist} > ${_target_name}
 139             DEPENDS ${_filelist}
 140             COMMENT "Combining cppcheck results"
 141             VERBATIM)
 142         list(APPEND _filelist ${_target_name})
 143     endif()
 144     add_custom_target(cppcheck DEPENDS ${_filelist})
 145 else()
 146     add_custom_target(cppcheck
 147         COMMAND ${CMAKE_COMMAND} -E echo
 148             "cppcheck was not found by CMake. Rerun CMake specifying CPPCHECK_EXECUTABLE."
 149         VERBATIM)
 150 endif()