tests/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 set(REGRESSIONTEST_PATH "" CACHE PATH "Directory containing regressiontests")
  36 mark_as_advanced(REGRESSIONTEST_PATH)
  37 option(REGRESSIONTEST_DOWNLOAD
  38     "Automatically download regressiontests. Tests can be run with ctest." no)
  39 if(REGRESSIONTEST_DOWNLOAD AND CMAKE_VERSION VERSION_LESS "2.8.2")
  40     message(WARNING "REGRESSIONTEST_DOWNLOAD requires cmake >=2.8.2. Please update cmake or manually download the regressiontests.")
  41     set(REGRESSIONTEST_DOWNLOAD FALSE CACHE BOOL
  42         "REGRESSIONTEST_DOWNLOAD not supported with cmake ${CMAKE_VERSION}" FORCE)
  43 endif()
  44 if(REGRESSIONTEST_DOWNLOAD)
  45     if("${PROJECT_VERSION}" MATCHES "-dev")
  46         set(REGRESSIONTEST_VERSION master)
  47     else()
  48         set(REGRESSIONTEST_VERSION ${PROJECT_VERSION})
  49     endif()
  50     set(REGRESSIONTEST_URL
  51         http://gerrit.gromacs.org/download/regressiontests-${REGRESSIONTEST_VERSION}.tar.gz)
  52     set(REGRESSIONTEST_FILE "${CMAKE_CURRENT_BINARY_DIR}/regressiontests.tgz")
  53     message("Downloading: ${REGRESSIONTEST_URL}")
  54     file(DOWNLOAD ${REGRESSIONTEST_URL} "${REGRESSIONTEST_FILE}" SHOW_PROGRESS STATUS status LOG log)
  55     list(GET status 0 status_code)
  56     list(GET status 1 status_string)
  57
  58     if(NOT status_code EQUAL 0)
  59         message(FATAL_ERROR "error: downloading '${REGRESSIONTEST_URL}' failed
  60 status_code: ${status_code}
  61 status_string: ${status_string}
  62 log: ${log}")
  63     endif()
  64
  65     set(REGRESSIONTEST_PATH
  66         "${CMAKE_CURRENT_BINARY_DIR}/regressiontests-${REGRESSIONTEST_VERSION}"
  67         CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  68     file(REMOVE_RECURSE "${REGRESSIONTEST_PATH}") #delete potential prior folder
  69     execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf "${REGRESSIONTEST_FILE}"
  70         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
  71     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  72         message(FATAL_ERROR "Download incorrect. Doesn't contain required gmxtest.pl")
  73     endif()
  74     set(REGRESSIONTEST_DOWNLOAD OFF CACHE BOOL "Tests already downloaded. Set to yes to download again" FORCE)
  75 endif()
  76
  77 if(REGRESSIONTEST_PATH AND (GMX_BLUEGENE OR CMAKE_CROSSCOMPILING OR CMAKE_CONFIGURATION_TYPES))
  78     #Bluegene requires us to compile both front-end and back-end binaries (single build is insufficient)
  79     message(WARNING
  80         "With cross-compiling or multi-configuration generators (e.g. Visual Studio), running regressiontests from build system is not supported. Please run gmxtest.pl directly.")
  81     set(REGRESSIONTEST_PATH OFF CACHE BOOL
  82         "With cross-compiling or multi-configuration generators, running regressiontests from build system is not supported." FORCE)
  83 endif()
  84
  85 if(REGRESSIONTEST_PATH)
  86     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  87         message(FATAL_ERROR
  88             "REGRESSIONTEST_PATH invalid. The path needs to contain gmxtest.pl.")
  89     endif()
  90     if(GMX_DOUBLE)
  91         list(APPEND ARGS -double)
  92     endif()
  93     if(GMX_LIB_MPI AND NOT MPIEXEC) #autodetection failed or CC=mpicc was used
  94         message(WARNING
  95             "Please set MPIEXEC. Otherwise mpirun is assumed for runnings tests.")
  96     endif()
  97     if(GMX_LIB_MPI)
  98         set(GMX_TEST_NUMBER_PROCS 8 CACHE STRING "Number of processors used for testing")
  99         mark_as_advanced(GMX_TEST_NUMBER_PROCS)
 100         list(APPEND ARGS -np ${GMX_TEST_NUMBER_PROCS})
 101         if(MPIEXEC)
 102             list(APPEND ARGS -mpirun ${MPIEXEC})
 103         endif()
 104         #We should use MPIEXEC_NUMPROC_FLAG but gmxtest.pl doesn't let us pass it
 105     endif()
 106     if(GMX_BINARY_SUFFIX)
 107         list(APPEND ARGS -suffix ${GMX_BINARY_SUFFIX})
 108     endif()
 109     #crosscompile is only used to disable checking whether binaries work
 110     #given that we know they are there and that mdrun might not be exectuable
 111     #(e.g. Cray) we enable it.
 112     list(APPEND ARGS -crosscompile)
 113
 114     set(REGRESSIONTEST_EXTRA_ARGS "" CACHE STRING
 115         "Extra arguments passed to gmxtest")
 116     mark_as_advanced(REGRESSIONTEST_EXTRA_ARGS)
 117     list(APPEND ARGS ${REGRESSIONTEST_EXTRA_ARGS})
 118
 119     list(APPEND ARGS -noverbose -nosuffix)
 120
 121     if(GMX_NATIVE_WINDOWS)
 122         set(PATH_SEPARATOR "\\;")
 123         #replacing \ with / shouldn't be neccessary. But otherwise "..\bin\;c:\.."
 124         #gets turned into "...\bin\\c:\.." don't know why and don't have a better
 125         #workaround. This workaround doesn't hurt.
 126         string(REPLACE "\\" "/" PATH "$ENV{PATH}")
 127         #protect ; (don't treat as list)
 128         string(REPLACE ";" "\\;" PATH "${PATH}")
 129     else()
 130         set(PATH_SEPARATOR ":")
 131         set(PATH "$ENV{PATH}")
 132     endif()
 133
 134     foreach(FOLDER kernel tools gmxlib mdlib) #lib folders might be needed for
 135         #e.g. DLLs. For GMX paths native ("\") is needed for GMXLIB detection
 136         file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/src/${FOLDER}" DIR)
 137         set(PATH "${DIR}${PATH_SEPARATOR}${PATH}")
 138     endforeach()
 139
 140     find_program(PERL_EXECUTABLE NAMES "perl")
 141     mark_as_advanced(PERL_EXECUTABLE)
 142
 143     if (NOT PERL_EXECUTABLE)
 144         message(FATAL_ERROR "Perl not found. Install perl, set PERL_EXECUTABLE to the perl location, or unset REGRESSIONTEST_PATH to disable testing.")
 145     endif()
 146
 147     #currently not testing tools because they don't contain any useful tests
 148     foreach(subtest simple complex kernel freeenergy pdb2gmx)
 149         add_test(NAME regressiontests/${subtest}
 150             #windows requires the command to be perl and not the script
 151             COMMAND perl "${REGRESSIONTEST_PATH}/gmxtest.pl" ${subtest} ${ARGS})
 152         set_tests_properties(regressiontests/${subtest} PROPERTIES
 153             ENVIRONMENT "PATH=${PATH}")
 154     endforeach()
 155 endif()