tests/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(REGRESSIONTEST_PATH "" CACHE PATH "Directory containing regressiontests")
  36 mark_as_advanced(REGRESSIONTEST_PATH)
  37 option(REGRESSIONTEST_DOWNLOAD
  38     "Automatically download regressiontests. Tests can be run with ctest." OFF)
  39
  40 if(REGRESSIONTEST_DOWNLOAD)
  41     if("${PROJECT_VERSION}" MATCHES "-dev")
  42        if("${PROJECT_VERSION}" MATCHES "^5[.]")
  43           set(REGRESSIONTEST_URL http://gerrit.gromacs.org/snapshot/refs/heads/master)
  44        else()
  45           set(REGRESSIONTEST_URL http://gerrit.gromacs.org/snapshot/refs/heads/release-4-6)
  46       endif()
  47       set(REGRESSIONTEST_PATH "${CMAKE_CURRENT_BINARY_DIR}/regressiontests"
  48            CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  49     else()
  50         if(NOT REGRESSIONTEST_VERSION)
  51           message(FATAL_ERROR "The configuration files do not specify what regressiontests tarball is suitable for automated download and testing. Please obtain and use a suitable set of tests yourself.")
  52         endif()
  53         set(REGRESSIONTEST_URL http://gerrit.gromacs.org/download/regressiontests-${REGRESSIONTEST_VERSION}.tar.gz)
  54         set(REGRESSIONTEST_PATH
  55            "${CMAKE_CURRENT_BINARY_DIR}/regressiontests-${REGRESSIONTEST_VERSION}"
  56            CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  57     endif()
  58     set(REGRESSIONTEST_FILE "${CMAKE_CURRENT_BINARY_DIR}/regressiontests.tgz")
  59     message("Downloading: ${REGRESSIONTEST_URL}")
  60     file(DOWNLOAD ${REGRESSIONTEST_URL} "${REGRESSIONTEST_FILE}" SHOW_PROGRESS STATUS status LOG log)
  61     list(GET status 0 status_code)
  62     list(GET status 1 status_string)
  63
  64     if(NOT status_code EQUAL 0)
  65         message(FATAL_ERROR "error: downloading '${REGRESSIONTEST_URL}' failed
  66 status_code: ${status_code}
  67 status_string: ${status_string}
  68 log: ${log}")
  69     endif()
  70
  71     file(REMOVE_RECURSE "${REGRESSIONTEST_PATH}") #delete potential prior folder
  72     execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf "${REGRESSIONTEST_FILE}"
  73         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
  74     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  75         message(FATAL_ERROR "Download incorrect. Doesn't contain required gmxtest.pl")
  76     endif()
  77     set(REGRESSIONTEST_DOWNLOAD OFF CACHE BOOL "Tests already downloaded. Set to yes to download again" FORCE)
  78 endif()
  79
  80 if(REGRESSIONTEST_PATH AND (GMX_BLUEGENE OR CMAKE_CROSSCOMPILING OR CMAKE_CONFIGURATION_TYPES OR GMX_BUILD_MDRUN_ONLY))
  81     # TODO: It would be nicer to do these before potentially downloading the tests.
  82     # Bluegene requires us to compile both front-end and back-end binaries
  83     # (single build is insufficient)
  84     # Testing an mdrun-only builds require supporting binaries from a full build
  85     message(WARNING
  86         "With cross-compiling, multi-configuration generators (e.g. Visual Studio), or with mdrun-only builds, running regressiontests from build system is not supported. Please run gmxtest.pl directly.")
  87     set(REGRESSIONTEST_PATH OFF CACHE BOOL
  88         "With cross-compiling or multi-configuration generators, running regressiontests from build system is not supported." FORCE)
  89 endif()
  90
  91 if(REGRESSIONTEST_PATH)
  92     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  93         message(FATAL_ERROR
  94             "REGRESSIONTEST_PATH invalid. The path needs to contain gmxtest.pl.")
  95     endif()
  96
  97     # gmxtests target builds all binaries required for running gmxtest
  98     add_custom_target(gmxtests DEPENDS gmx)
  99     add_dependencies(check gmxtests)
 100
 101     if(GMX_DOUBLE)
 102         list(APPEND ARGS -double)
 103     endif()
 104     if(GMX_LIB_MPI AND NOT MPIEXEC) #autodetection failed or CC=mpicc was used
 105         message(WARNING
 106             "Please set MPIEXEC. Otherwise mpirun is assumed for runnings tests.")
 107     endif()
 108     if(GMX_LIB_MPI)
 109         set(GMX_TEST_NUMBER_PROCS 8 CACHE STRING "Number of processors used for testing")
 110         mark_as_advanced(GMX_TEST_NUMBER_PROCS)
 111         list(APPEND ARGS -np ${GMX_TEST_NUMBER_PROCS})
 112         if(MPIEXEC)
 113             list(APPEND ARGS -mpirun ${MPIEXEC})
 114         endif()
 115         #We should use MPIEXEC_NUMPROC_FLAG but gmxtest.pl doesn't let us pass it
 116     endif()
 117     if(GMX_BINARY_SUFFIX)
 118         list(APPEND ARGS -suffix ${GMX_BINARY_SUFFIX})
 119     endif()
 120     #crosscompile is only used to disable checking whether binaries work
 121     #given that we know they are there and that mdrun might not be exectuable
 122     #(e.g. Cray) we enable it.
 123     list(APPEND ARGS -crosscompile)
 124
 125     set(REGRESSIONTEST_EXTRA_ARGS "" CACHE STRING
 126         "Extra arguments passed to gmxtest")
 127     mark_as_advanced(REGRESSIONTEST_EXTRA_ARGS)
 128     list(APPEND ARGS ${REGRESSIONTEST_EXTRA_ARGS})
 129
 130     list(APPEND ARGS -noverbose -nosuffix)
 131
 132     if(GMX_NATIVE_WINDOWS)
 133         set(PATH_SEPARATOR "\\;")
 134         #replacing \ with / shouldn't be neccessary. But otherwise "..\bin\;c:\.."
 135         #gets turned into "...\bin\\c:\.." don't know why and don't have a better
 136         #workaround. This workaround doesn't hurt.
 137         string(REPLACE "\\" "/" PATH "$ENV{PATH}")
 138         #protect ; (don't treat as list)
 139         string(REPLACE ";" "\\;" PATH "${PATH}")
 140     else()
 141         set(PATH_SEPARATOR ":")
 142         set(PATH "$ENV{PATH}")
 143     endif()
 144
 145     foreach(FOLDER bin lib) #lib folders might be needed for
 146         #e.g. DLLs. For GMX paths native ("\") is needed for GMXLIB detection
 147         file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${FOLDER}" DIR)
 148         set(PATH "${DIR}${PATH_SEPARATOR}${PATH}")
 149     endforeach()
 150
 151     find_program(PERL_EXECUTABLE NAMES "perl")
 152     mark_as_advanced(PERL_EXECUTABLE)
 153
 154     if (NOT PERL_EXECUTABLE)
 155         message(FATAL_ERROR "Perl not found. Install perl, set PERL_EXECUTABLE to the perl location, or unset REGRESSIONTEST_PATH to disable testing.")
 156     endif()
 157
 158     #currently not testing tools because they don't contain any useful tests
 159     foreach(subtest simple complex kernel freeenergy pdb2gmx rotation)
 160         add_test(NAME regressiontests/${subtest}
 161             #windows requires the command to be perl and not the script
 162             COMMAND perl "${REGRESSIONTEST_PATH}/gmxtest.pl" ${subtest} ${ARGS})
 163         set_tests_properties(regressiontests/${subtest} PROPERTIES
 164             ENVIRONMENT "PATH=${PATH}")
 165     endforeach()
 166 else()
 167     add_custom_target(regressiontests-notice
 168         ${CMAKE_COMMAND} -E echo "NOTE: Regression tests have not been run. If you want to run them from the build system, get the correct version of the regression tests package and set REGRESSIONTEST_PATH in CMake to point to it, or set REGRESSIONTEST_DOWNLOAD=ON."
 169         DEPENDS run-ctest
 170         COMMENT "Regression tests not available" VERBATIM)
 171     add_dependencies(check regressiontests-notice)
 172 endif()
 173
 174 include(CppCheck.cmake)