tests/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(REGRESSIONTEST_PATH "" CACHE PATH "Directory containing regressiontests")
  36 mark_as_advanced(REGRESSIONTEST_PATH)
  37 option(REGRESSIONTEST_DOWNLOAD
  38     "Automatically download regressiontests. Tests can be run with ctest." OFF)
  39
  40 if(REGRESSIONTEST_DOWNLOAD)
  41     if (NOT SOURCE_IS_SOURCE_DISTRIBUTION)
  42         set(REGRESSIONTEST_URL http://gerrit.gromacs.org/snapshot/${REGRESSIONTEST_BRANCH})
  43         set(REGRESSIONTEST_PATH "${CMAKE_CURRENT_BINARY_DIR}/regressiontests"
  44             CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  45     else()
  46         set(REGRESSIONTEST_URL http://gerrit.gromacs.org/download/regressiontests-${REGRESSIONTEST_VERSION}.tar.gz)
  47         set(REGRESSIONTEST_PATH
  48             "${CMAKE_CURRENT_BINARY_DIR}/regressiontests-${REGRESSIONTEST_VERSION}"
  49             CACHE PATH "Path to auto-downloaded regressiontests" FORCE)
  50     endif()
  51     set(REGRESSIONTEST_FILE "${CMAKE_CURRENT_BINARY_DIR}/regressiontests.tgz")
  52     message("Downloading: ${REGRESSIONTEST_URL}")
  53     file(DOWNLOAD ${REGRESSIONTEST_URL} "${REGRESSIONTEST_FILE}" SHOW_PROGRESS STATUS status LOG log)
  54     list(GET status 0 status_code)
  55     list(GET status 1 status_string)
  56
  57     if(NOT status_code EQUAL 0)
  58         message(FATAL_ERROR "error: downloading '${REGRESSIONTEST_URL}' failed
  59 status_code: ${status_code}
  60 status_string: ${status_string}
  61 log: ${log}")
  62     endif()
  63
  64     file(REMOVE_RECURSE "${REGRESSIONTEST_PATH}") #delete potential prior folder
  65     execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf "${REGRESSIONTEST_FILE}"
  66         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
  67     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  68         message(FATAL_ERROR "Download incorrect. Doesn't contain required gmxtest.pl")
  69     endif()
  70     set(REGRESSIONTEST_DOWNLOAD OFF CACHE BOOL "Tests already downloaded. Set to yes to download again" FORCE)
  71 endif()
  72
  73 if(REGRESSIONTEST_PATH AND (GMX_BLUEGENE OR CMAKE_CROSSCOMPILING OR CMAKE_CONFIGURATION_TYPES OR GMX_BUILD_MDRUN_ONLY))
  74     # TODO: It would be nicer to do these before potentially downloading the tests.
  75     # Bluegene requires us to compile both front-end and back-end binaries
  76     # (single build is insufficient)
  77     # Testing an mdrun-only builds require supporting binaries from a full build
  78     message(WARNING
  79         "With cross-compiling, multi-configuration generators (e.g. Visual Studio), or with mdrun-only builds, running regressiontests from build system is not supported. Please run gmxtest.pl directly.")
  80     set(REGRESSIONTEST_PATH OFF CACHE BOOL
  81         "With cross-compiling or multi-configuration generators, running regressiontests from build system is not supported." FORCE)
  82 endif()
  83
  84 if(REGRESSIONTEST_PATH)
  85     if(NOT EXISTS ${REGRESSIONTEST_PATH}/gmxtest.pl)
  86         message(FATAL_ERROR
  87             "REGRESSIONTEST_PATH invalid. The path needs to contain gmxtest.pl.")
  88     endif()
  89
  90     # gmxtests target builds all binaries required for running gmxtest
  91     add_custom_target(gmxtests DEPENDS gmx)
  92     add_dependencies(check gmxtests)
  93
  94     if(GMX_DOUBLE)
  95         list(APPEND ARGS -double)
  96     endif()
  97     if(GMX_LIB_MPI AND NOT MPIEXEC) #autodetection failed or CC=mpicc was used
  98         message(WARNING
  99             "Please set MPIEXEC. Otherwise mpirun is assumed for runnings tests.")
 100     endif()
 101     if(GMX_LIB_MPI)
 102         set(GMX_TEST_NUMBER_PROCS 8 CACHE STRING "Number of processors used for testing")
 103         mark_as_advanced(GMX_TEST_NUMBER_PROCS)
 104         list(APPEND ARGS -np ${GMX_TEST_NUMBER_PROCS})
 105         if(MPIEXEC)
 106             list(APPEND ARGS -mpirun ${MPIEXEC})
 107         endif()
 108         #We should use MPIEXEC_NUMPROC_FLAG but gmxtest.pl doesn't let us pass it
 109     endif()
 110     if(GMX_BINARY_SUFFIX)
 111         list(APPEND ARGS -suffix ${GMX_BINARY_SUFFIX})
 112     endif()
 113     #crosscompile is only used to disable checking whether binaries work
 114     #given that we know they are there and that mdrun might not be exectuable
 115     #(e.g. Cray) we enable it.
 116     list(APPEND ARGS -crosscompile)
 117
 118     set(REGRESSIONTEST_EXTRA_ARGS "" CACHE STRING
 119         "Extra arguments passed to gmxtest")
 120     mark_as_advanced(REGRESSIONTEST_EXTRA_ARGS)
 121     list(APPEND ARGS ${REGRESSIONTEST_EXTRA_ARGS})
 122
 123     list(APPEND ARGS -noverbose -nosuffix)
 124
 125     if(GMX_NATIVE_WINDOWS)
 126         set(PATH_SEPARATOR "\\;")
 127         #replacing \ with / shouldn't be neccessary. But otherwise "..\bin\;c:\.."
 128         #gets turned into "...\bin\\c:\.." don't know why and don't have a better
 129         #workaround. This workaround doesn't hurt.
 130         string(REPLACE "\\" "/" PATH "$ENV{PATH}")
 131         #protect ; (don't treat as list)
 132         string(REPLACE ";" "\\;" PATH "${PATH}")
 133     else()
 134         set(PATH_SEPARATOR ":")
 135         set(PATH "$ENV{PATH}")
 136     endif()
 137
 138     foreach(FOLDER bin lib) #lib folders might be needed for
 139         #e.g. DLLs. For GMX paths native ("\") is needed for GMXLIB detection
 140         file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${FOLDER}" DIR)
 141         set(PATH "${DIR}${PATH_SEPARATOR}${PATH}")
 142     endforeach()
 143
 144     find_program(PERL_EXECUTABLE NAMES "perl")
 145     mark_as_advanced(PERL_EXECUTABLE)
 146
 147     if (NOT PERL_EXECUTABLE)
 148         message(FATAL_ERROR "Perl not found. Install perl, set PERL_EXECUTABLE to the perl location, or unset REGRESSIONTEST_PATH to disable testing.")
 149     endif()
 150
 151     #currently not testing tools because they don't contain any useful tests
 152     foreach(subtest simple complex kernel freeenergy pdb2gmx rotation)
 153         add_test(NAME regressiontests/${subtest}
 154             #windows requires the command to be perl and not the script
 155             COMMAND perl "${REGRESSIONTEST_PATH}/gmxtest.pl" ${subtest} ${ARGS})
 156         set_tests_properties(regressiontests/${subtest} PROPERTIES
 157             ENVIRONMENT "PATH=${PATH}")
 158     endforeach()
 159 else()
 160     add_custom_target(regressiontests-notice
 161         ${CMAKE_COMMAND} -E echo "NOTE: Regression tests have not been run. If you want to run them from the build system, get the correct version of the regression tests package and set REGRESSIONTEST_PATH in CMake to point to it, or set REGRESSIONTEST_DOWNLOAD=ON."
 162         DEPENDS run-ctest
 163         COMMENT "Regression tests not available" VERBATIM)
 164     add_dependencies(check regressiontests-notice)
 165 endif()
 166
 167 include(CppCheck.cmake)