src/testutils/TestMacros.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 function (gmx_add_unit_test_object_library NAME)
  36     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  37         include_directories(BEFORE ${GMOCK_INCLUDE_DIRS})
  38         add_library(${NAME} OBJECT ${UNITTEST_TARGET_OPTIONS} ${ARGN})
  39         set_property(TARGET ${NAME} APPEND PROPERTY COMPILE_DEFINITIONS "${GMOCK_COMPILE_DEFINITIONS}")
  40         set_property(TARGET ${NAME} APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  41     endif()
  42 endfunction ()
  43
  44 function (gmx_build_unit_test NAME EXENAME)
  45     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  46         include_directories(BEFORE ${GMOCK_INCLUDE_DIRS})
  47         add_executable(${EXENAME} ${UNITTEST_TARGET_OPTIONS} ${ARGN} ${TESTUTILS_DIR}/unittest_main.cpp)
  48         set_property(TARGET ${EXENAME} APPEND PROPERTY COMPILE_DEFINITIONS "${GMOCK_COMPILE_DEFINITIONS}")
  49         set_property(TARGET ${EXENAME} APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  50         target_link_libraries(${EXENAME} ${TESTUTILS_LIBS} libgromacs ${GMOCK_LIBRARIES} ${GMX_EXE_LINKER_FLAGS})
  51         file(RELATIVE_PATH _input_files_path ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  52         set(_temporary_files_path "${CMAKE_CURRENT_BINARY_DIR}/Testing/Temporary")
  53         file(MAKE_DIRECTORY ${_temporary_files_path})
  54         # Note that the quotation marks in the next line form part of
  55         # the defined symbol, so that the macro replacement in the
  56         # source file is as a string.
  57         set(EXTRA_COMPILE_DEFINITIONS
  58             TEST_DATA_PATH="${_input_files_path}"
  59             TEST_TEMP_PATH="${_temporary_files_path}")
  60
  61         set_property(TARGET ${EXENAME} APPEND PROPERTY COMPILE_DEFINITIONS "${EXTRA_COMPILE_DEFINITIONS}")
  62     endif()
  63 endfunction ()
  64
  65 function (gmx_register_unit_test NAME EXENAME)
  66     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  67         add_test(NAME ${NAME}
  68                  COMMAND ${EXENAME} --gtest_output=xml:${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml)
  69         set_tests_properties(${NAME} PROPERTIES LABELS "GTest;UnitTest")
  70         add_dependencies(tests ${EXENAME})
  71     endif()
  72 endfunction ()
  73
  74 # Use this function to register a test binary as an integration test
  75 function (gmx_register_integration_test NAME EXENAME)
  76     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  77         add_test(NAME ${NAME}
  78                  COMMAND ${EXENAME} --gtest_output=xml:${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml)
  79         set_tests_properties(${testname} PROPERTIES LABELS "IntegrationTest")
  80         add_dependencies(tests ${EXENAME})
  81
  82         # GMX_EXTRA_LIBRARIES might be needed for mdrun integration tests at
  83         # some point.
  84         # target_link_libraries(${EXENAME} ${GMX_EXTRA_LIBRARIES})
  85     endif()
  86 endfunction ()
  87
  88 # Use this function to register a test binary as an integration test
  89 # that requires MPI. The intended number of MPI ranks is also passed
  90 #
  91 # TODO When a test case needs it, generalize the NUMPROC mechanism so
  92 # that ctest can run the test binary over a range of numbers of MPI
  93 # ranks.
  94 function (gmx_register_mpi_integration_test NAME EXENAME NUMPROC)
  95     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  96         if (GMX_MPI)
  97             foreach(VARNAME MPIEXEC MPIEXEC_NUMPROC_FLAG MPIEXEC_PREFLAGS MPIEXEC_POSTFLAGS)
  98                 # These variables need a valid value for the test to run
  99                 # and pass, but conceivably any of them might be valid
 100                 # with arbitrary (including empty) content. They can't be
 101                 # valid if they've been populated with the CMake
 102                 # find_package magic suffix/value "NOTFOUND", though.
 103                 if (${VARNAME} MATCHES ".*NOTFOUND")
 104                     message(STATUS "CMake variable ${VARNAME} was not detected to be a valid value. To test GROMACS correctly, check the advice in the install guide.")
 105                     set(_cannot_run_mpi_tests 1)
 106                 endif()
 107                 if (NOT VARNAME STREQUAL MPIEXEC AND ${VARNAME})
 108                     set(_an_mpi_variable_had_content 1)
 109                 endif()
 110             endforeach()
 111             if(_an_mpi_variable_had_content AND NOT MPIEXEC)
 112                 message(STATUS "CMake variable MPIEXEC must have a valid value if one of the other related MPIEXEC variables does. To test GROMACS correctly, check the advice in the install guide.")
 113                 set(_cannot_run_mpi_tests 1)
 114             endif()
 115             if(NOT _cannot_run_mpi_tests)
 116                 add_test(NAME ${NAME}
 117                     COMMAND
 118                     ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} ${NUMPROC}
 119                     ${MPIEXEC_PREFLAGS} $<TARGET_FILE:${EXENAME}> ${MPIEXEC_POSTFLAGS}
 120                     --gtest_output=xml:${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml
 121                     )
 122                 set_tests_properties(${testname} PROPERTIES LABELS "MpiIntegrationTest")
 123                 add_dependencies(tests ${EXENAME})
 124             endif()
 125
 126             # GMX_EXTRA_LIBRARIES might be needed for mdrun integration tests at
 127             # some point.
 128             # target_link_libraries(${EXENAME} ${GMX_EXTRA_LIBRARIES})
 129         elseif(GMX_THREAD_MPI)
 130             add_test(NAME ${NAME}
 131                 COMMAND
 132                 $<TARGET_FILE:${EXENAME}> -nt ${NUMPROC}
 133                 --gtest_output=xml:${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml
 134                 )
 135             set_tests_properties(${testname} PROPERTIES LABELS "MpiIntegrationTest")
 136             add_dependencies(tests ${EXENAME})
 137
 138             # GMX_EXTRA_LIBRARIES might be needed for mdrun integration tests at
 139             # some point.
 140             # target_link_libraries(${EXENAME} ${GMX_EXTRA_LIBRARIES})
 141         endif()
 142     endif()
 143 endfunction ()
 144
 145 function (gmx_add_unit_test NAME EXENAME)
 146     gmx_build_unit_test(${NAME} ${EXENAME} ${ARGN})
 147     gmx_register_unit_test(${NAME} ${EXENAME})
 148 endfunction()