src/testutils/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015 by the GROMACS development team.
   5 # Copyright (c) 2016,2017,2018,2019,2020 by the GROMACS development team.
   6 # Copyright (c) 2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 if (NOT GMX_BUILD_UNITTESTS)
  38     gmx_add_missing_tests_notice("Unit tests have not been run. You need to set GMX_BUILD_UNITTESTS=ON if you want to build and run them.")
  39     return()
  40 endif()
  41
  42 if (GMX_GPU_CUDA)
  43     # Work around FindCUDA that prevents using target_link_libraries()
  44     # with keywords otherwise...
  45     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
  46     if (NOT GMX_CLANG_CUDA)
  47         gmx_cuda_add_library(testutils)
  48     else()
  49         set_source_files_properties(test_device.cpp PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
  50         gmx_compile_cuda_file_with_clang(test_device.cpp)
  51         add_library(testutils STATIC ${TESTUTILS_SOURCES})
  52         target_link_libraries(testutils PRIVATE ${GMX_CUDA_CLANG_LINK_LIBS})
  53     endif()
  54     target_link_libraries(testutils PRIVATE ${CUDA_CUFFT_LIBRARIES})
  55 else()
  56     add_library(testutils STATIC ${UNITTEST_TARGET_OPTIONS})
  57 endif()
  58
  59 # Module interface / provided facilities
  60 target_include_directories(testutils PUBLIC include)
  61
  62 # Executable targets for tests based on `testutils` acquire the source for
  63 # their entry point from unittest_main.cpp when linking to the `testutils` target.
  64 target_sources(testutils INTERFACE unittest_main.cpp)
  65
  66
  67 target_sources(testutils PRIVATE
  68                cmdlinetest.cpp
  69                conftest.cpp
  70                filematchers.cpp
  71                interactivetest.cpp
  72                loggertest.cpp
  73                mpi_printer.cpp
  74                mpitest.cpp
  75                refdata.cpp
  76                refdata_xml.cpp
  77                simulationdatabase.cpp
  78                stdiohelper.cpp
  79                stringtest.cpp
  80                testasserts.cpp
  81                testfilemanager.cpp
  82                testfileredirector.cpp
  83                test_device.cpp
  84                test_hardware_environment.cpp
  85                testinit.cpp
  86                testmatchers.cpp
  87                testoptions.cpp
  88                textblockmatchers.cpp
  89                tprfilegenerator.cpp
  90                xvgtest.cpp
  91                )
  92
  93
  94 if(HAVE_TINYXML2)
  95     target_include_directories(testutils SYSTEM PRIVATE ${TinyXML2_INCLUDE_DIR})
  96     target_link_libraries(testutils PRIVATE ${TinyXML2_LIBRARIES})
  97 else()
  98     target_include_directories(testutils SYSTEM BEFORE PRIVATE ${CMAKE_SOURCE_DIR}/src/external/tinyxml2)
  99     target_sources(testutils PRIVATE ${CMAKE_SOURCE_DIR}/src/external/tinyxml2/tinyxml2.cpp)
 100 endif()
 101
 102 target_include_directories(testutils PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
 103
 104 if (GMX_GPU_SYCL)
 105     add_sycl_to_target(
 106         TARGET testutils
 107         SOURCES test_device.cpp
 108         )
 109 endif()
 110
 111 gmx_target_compile_options(testutils)
 112 target_compile_definitions(testutils PRIVATE HAVE_CONFIG_H)
 113 target_include_directories(testutils SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 114 target_link_libraries(testutils PRIVATE libgromacs ${GMX_COMMON_LIBRARIES} gmock)
 115 target_link_libraries(testutils PUBLIC common)
 116
 117 # GROMACS module dependencies.
 118 # Note that testutils conveys transitive dependencies on some modules.
 119 # TODO: Explicitly link specific modules with minimal exposure.
 120 target_link_libraries(testutils PUBLIC legacy_modules)
 121
 122 add_subdirectory(tests)