src/programs/mdrun/CMakeLists.txt

   1 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/gmxpreprocess)
   2
   3 set(MDRUN_SOURCES
   4     do_gct.c      gctio.c       genalg.c    ionize.c
   5     md.c          mdrun.cpp     membed.c
   6     pme_loadbal.c repl_ex.c     runner.c    xutils.c)
   7
   8 if(GMX_FAHCORE)
   9     add_library(fahcore ${MDRUN_SOURCES})
  10 else(GMX_FAHCORE)
  11     add_executable(mdrun ${MDRUN_SOURCES})
  12     gmx_add_man_page(mdrun)
  13     target_link_libraries(mdrun ${GMX_EXTRA_LIBRARIES} libgromacs
  14         ${GMX_EXE_LINKER_FLAGS})
  15     set_target_properties(mdrun PROPERTIES OUTPUT_NAME "mdrun${GMX_BINARY_SUFFIX}"
  16         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  17     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  18
  19     # Create the custom install-mdrun target
  20     if (BUILD_SHARED_LIBS)
  21         # If shared libraries are used, we need to install the libraries in
  22         # addition to the mdrun binary.
  23         add_custom_target(install-mdrun
  24             COMMAND ${CMAKE_COMMAND} -DCOMPONENT=libraries
  25                     -P ${CMAKE_BINARY_DIR}/cmake_install.cmake
  26             COMMAND ${CMAKE_COMMAND} -DCOMPONENT=mdrun
  27                     -P ${CMAKE_BINARY_DIR}/cmake_install.cmake
  28             COMMENT "Installing mdrun")
  29     else (BUILD_SHARED_LIBS)
  30         add_custom_target(install-mdrun
  31             COMMAND ${CMAKE_COMMAND} -DCOMPONENT=mdrun
  32                     -P ${CMAKE_BINARY_DIR}/cmake_install.cmake
  33             COMMENT "Installing mdrun")
  34     endif (BUILD_SHARED_LIBS)
  35     add_dependencies(install-mdrun mdrun)
  36 endif(GMX_FAHCORE)