src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/gmxpreprocess)
  36
  37 file(GLOB MDRUN_SOURCES mdrun/*.c mdrun/*.cpp)
  38
  39 if(GMX_FAHCORE)
  40     add_library(fahcore ${MDRUN_SOURCES})
  41 elseif(GMX_BUILD_MDRUN_ONLY)
  42     add_executable(mdrun ${MDRUN_SOURCES} mdrun_main.cpp)
  43     target_link_libraries(mdrun
  44         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  45     set_target_properties(mdrun PROPERTIES
  46         OUTPUT_NAME "mdrun${GMX_BINARY_SUFFIX}"
  47         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  48     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  49 else()
  50     file(GLOB GMX_EXECUTABLE_SOURCES gmx/*.c gmx/*.cpp)
  51     add_executable(gmx ${GMX_EXECUTABLE_SOURCES} ${MDRUN_SOURCES})
  52     target_link_libraries(gmx
  53         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  54     set_target_properties(gmx PROPERTIES
  55         OUTPUT_NAME "gmx${GMX_BINARY_SUFFIX}"
  56         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  57
  58     configure_file(CreateLinks.cmake.cmakein CreateLinks.cmake @ONLY)
  59     set(CREATE_LINKS_SCRIPT ${CMAKE_CURRENT_BINARY_DIR}/CreateLinks.cmake)
  60     # TODO: Currently this rule is always run and recreates the symlinks;
  61     # it would be best to just adapt the rest of the build such that this is
  62     # never needed (for now, this makes the binary directory seem like it was
  63     # earlier).
  64     add_custom_target(links ALL
  65         ${CMAKE_COMMAND}
  66             -DBINARY_DIRECTORY=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
  67             -DQUIETLY=TRUE
  68             -P ${CREATE_LINKS_SCRIPT}
  69         DEPENDS gmx
  70         COMMENT "Creating symlinks for alternative binary names"
  71         VERBATIM)
  72
  73     # TODO: Create man pages (currently not working since the old mechanism
  74     # requires a target for each binary to which one can add a post-build role, and
  75     # the symlinks do not have such targets).
  76
  77     install(TARGETS gmx
  78             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  79     if (GMX_SYMLINK_OLD_BINARY_NAMES)
  80         install(SCRIPT ${CREATE_LINKS_SCRIPT} COMPONENT links)
  81     endif ()
  82 endif()