src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 file(GLOB MDRUN_SOURCES mdrun/*.c mdrun/*.cpp)
  36 # make an "object library" that we can re-use for multiple targets
  37 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  38
  39 if(GMX_FAHCORE)
  40     # The lack of a real source file here alongside the object library
  41     # may break some generators, according to CMake documentation. If
  42     # so, we can consider adding some dummy file to make it work.
  43     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  44 elseif(GMX_BUILD_MDRUN_ONLY)
  45     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  46     target_link_libraries(mdrun
  47         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  48     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  49     set_target_properties(mdrun PROPERTIES
  50         OUTPUT_NAME "${BINARY_NAME}"
  51         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  52     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  53     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  54          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  55     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  56             DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
  57 else()
  58     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  59     if(GMX_X11)
  60         file(GLOB VIEW_SOURCES view/*.cpp)
  61     else()
  62         file(GLOB VIEW_SOURCES view/view.cpp)
  63     endif()
  64     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  65     add_executable(gmx
  66         ${GMX_MAIN_SOURCES}
  67         $<TARGET_OBJECTS:mdrun_objlib>
  68         $<TARGET_OBJECTS:view_objlib>)
  69     target_link_libraries(gmx
  70         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  71     if(GMX_X11)
  72         target_link_libraries(gmx ${X11_LIBRARIES})
  73     endif()
  74     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  75     set_target_properties(gmx PROPERTIES
  76         OUTPUT_NAME "${BINARY_NAME}"
  77         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  78     install(TARGETS gmx
  79             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  80
  81     ########################
  82     # Completion generation
  83
  84     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  85     if(SOURCE_IS_SOURCE_DISTRIBUTION)
  86         # Make sure source package contains the completions.
  87         if(NOT EXISTS "${COMPLETION_DIR}/gmx-completion.bash")
  88             message(FATAL_ERROR "Shell completions are missing from source package.")
  89         endif()
  90     endif()
  91     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/completion)
  92     add_custom_target(completion
  93         gmx -quiet help -export completion
  94         COMMENT "Generating command-line completions for programs"
  95         WORKING_DIRECTORY completion
  96         VERBATIM)
  97     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
  98     # this can be done are exactly the same (ability to run the compiled
  99     # binaries).
 100     if (GMX_BUILD_HELP)
 101         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 102         set_directory_properties(PROPERTIES
 103             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 104         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 105     endif()
 106     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 107         install(DIRECTORY ${COMPLETION_DIR}/
 108                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 109         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 110              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 111         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 112                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 113     endif()
 114
 115     if (GMX_SYMLINK_OLD_BINARY_NAMES)
 116         configure_file(CreateLinks.cmake.cmakein CreateLinks.cmake @ONLY)
 117         set(CREATE_LINKS_SCRIPT ${CMAKE_CURRENT_BINARY_DIR}/CreateLinks.cmake)
 118         install(SCRIPT ${CREATE_LINKS_SCRIPT} COMPONENT links)
 119     endif()
 120
 121     if(BUILD_TESTING)
 122         add_subdirectory(mdrun/tests)
 123     endif()
 124 endif()