src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/gmxpreprocess)
  36
  37 file(GLOB MDRUN_SOURCES mdrun/*.c mdrun/*.cpp)
  38 # make an "object library" that we can re-use for multiple targets
  39 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  40
  41 if(GMX_FAHCORE)
  42     # The lack of a real source file here alongside the object library
  43     # may break some generators, according to CMake documentation. If
  44     # so, we can consider adding some dummy file to make it work.
  45     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  46 elseif(GMX_BUILD_MDRUN_ONLY)
  47     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  48     target_link_libraries(mdrun
  49         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  50     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  51     set_target_properties(mdrun PROPERTIES
  52         OUTPUT_NAME "${BINARY_NAME}"
  53         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  54     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  55     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  56          "complete -F _gmx_mdrun_compl ${BINARY_NAME}")
  57     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  58             DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
  59 else()
  60     file(GLOB GMX_MAIN_SOURCES gmx/gmx.cpp gmx/legacymodules.cpp)
  61     if(GMX_X11)
  62         file(GLOB VIEW_SOURCES view/*.cpp)
  63     else()
  64         file(GLOB VIEW_SOURCES view/view.cpp)
  65     endif()
  66     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  67     add_executable(gmx
  68         ${GMX_MAIN_SOURCES}
  69         $<TARGET_OBJECTS:mdrun_objlib>
  70         $<TARGET_OBJECTS:view_objlib>)
  71     target_link_libraries(gmx
  72         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  73     if(GMX_X11)
  74         target_link_libraries(gmx ${X11_LIBRARIES})
  75     endif()
  76     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  77     set_target_properties(gmx PROPERTIES
  78         OUTPUT_NAME "${BINARY_NAME}"
  79         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  80     install(TARGETS gmx
  81             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  82
  83     ########################
  84     # Completion generation
  85
  86     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  87     if(SOURCE_IS_SOURCE_DISTRIBUTION)
  88         # Make sure source package contains the completions.
  89         if(NOT EXISTS "${COMPLETION_DIR}/gmx-completion.bash")
  90             message(FATAL_ERROR "Shell completions are missing from source package.")
  91         endif()
  92     endif()
  93     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/completion)
  94     add_custom_target(completion
  95         gmx -quiet help -export completion
  96         COMMENT "Generating command-line completions for programs"
  97         WORKING_DIRECTORY completion
  98         VERBATIM)
  99     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
 100     # this can be done are exactly the same (ability to run the compiled
 101     # binaries).
 102     if (GMX_BUILD_HELP)
 103         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 104         set_directory_properties(PROPERTIES
 105             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 106         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 107     endif()
 108     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 109         install(DIRECTORY ${COMPLETION_DIR}/
 110                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 111         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 112              "complete -F _gmx_compl ${BINARY_NAME}")
 113         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 114                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 115     endif()
 116
 117     if (GMX_SYMLINK_OLD_BINARY_NAMES)
 118         configure_file(CreateLinks.cmake.cmakein CreateLinks.cmake @ONLY)
 119         set(CREATE_LINKS_SCRIPT ${CMAKE_CURRENT_BINARY_DIR}/CreateLinks.cmake)
 120         install(SCRIPT ${CREATE_LINKS_SCRIPT} COMPONENT links)
 121     endif ()
 122
 123     if(BUILD_TESTING)
 124         add_subdirectory(mdrun/tests)
 125     endif(BUILD_TESTING)
 126 endif()