src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/gmxpreprocess)
  36
  37 file(GLOB MDRUN_SOURCES mdrun/*.c mdrun/*.cpp)
  38 # make an "object library" that we can re-use for multiple targets
  39 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  40
  41 if(GMX_FAHCORE)
  42     # The lack of a real source file here alongside the object library
  43     # may break some generators, according to CMake documentation. If
  44     # so, we can consider adding some dummy file to make it work.
  45     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  46 elseif(GMX_BUILD_MDRUN_ONLY)
  47     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  48     target_link_libraries(mdrun
  49         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  50     set_target_properties(mdrun PROPERTIES
  51         OUTPUT_NAME "mdrun${GMX_BINARY_SUFFIX}"
  52         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  53     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  54 else()
  55     file(GLOB GMX_GENERAL_SOURCES gmx/*.c gmx/*.cpp)
  56     file(GLOB GMX_MAIN_SOURCES gmx/gmx.cpp gmx/legacymodules.cpp)
  57     list(REMOVE_ITEM GMX_GENERAL_SOURCES ${GMX_MAIN_SOURCES})
  58     if(GMX_X11)
  59         file(GLOB VIEW_SOURCES view/*.cpp)
  60     else()
  61         file(GLOB VIEW_SOURCES view/view.cpp)
  62     endif()
  63     add_library(gmx_objlib OBJECT ${GMX_GENERAL_SOURCES})
  64     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  65     add_executable(gmx
  66         ${GMX_MAIN_SOURCES}
  67         $<TARGET_OBJECTS:gmx_objlib>
  68         $<TARGET_OBJECTS:mdrun_objlib>
  69         $<TARGET_OBJECTS:view_objlib>)
  70     target_link_libraries(gmx
  71         ${GMX_EXTRA_LIBRARIES} libgromacs ${GMX_EXE_LINKER_FLAGS})
  72     if(GMX_X11)
  73         target_link_libraries(gmx ${X11_LIBRARIES})
  74     endif()
  75     set_target_properties(gmx PROPERTIES
  76         OUTPUT_NAME "gmx${GMX_BINARY_SUFFIX}"
  77         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  78
  79     configure_file(CreateLinks.cmake.cmakein CreateLinks.cmake @ONLY)
  80     set(CREATE_LINKS_SCRIPT ${CMAKE_CURRENT_BINARY_DIR}/CreateLinks.cmake)
  81
  82     install(TARGETS gmx
  83             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  84     if (GMX_SYMLINK_OLD_BINARY_NAMES)
  85         install(SCRIPT ${CREATE_LINKS_SCRIPT} COMPONENT links)
  86     endif ()
  87
  88     if(BUILD_TESTING)
  89         add_subdirectory(mdrun/tests)
  90     endif(BUILD_TESTING)
  91 endif()