src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  37 # make an "object library" that we can re-use for multiple targets
  38 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  39 gmx_target_compile_options(mdrun_objlib)
  40 target_compile_definitions(mdrun_objlib PRIVATE HAVE_CONFIG_H)
  41 target_include_directories(mdrun_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  42 # Should be possible to remove this when resolving #3290
  43 target_include_directories(mdrun_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  44 target_link_libraries(mdrun_objlib PRIVATE common)
  45 target_link_libraries(mdrun_objlib PRIVATE legacy_api)
  46 # TODO: Explicitly link specific modules.
  47 target_link_libraries(mdrun_objlib PRIVATE legacy_modules)
  48
  49 if(GMX_FAHCORE)
  50     # The lack of a real source file here alongside the object library
  51     # may break some generators, according to CMake documentation. If
  52     # so, we can consider adding some dummy file to make it work.
  53     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  54     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES} legacy_api)
  55 elseif(GMX_BUILD_MDRUN_ONLY)
  56     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  57     gmx_target_compile_options(mdrun)
  58     target_compile_definitions(mdrun PRIVATE HAVE_CONFIG_H)
  59     target_link_libraries(mdrun libgromacs
  60         ${GMX_COMMON_LIBRARIES}
  61         ${GMX_EXE_LINKER_FLAGS})
  62     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  63     set_target_properties(mdrun PROPERTIES
  64         OUTPUT_NAME "${BINARY_NAME}")
  65     install(TARGETS mdrun DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun)
  66     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  67          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  68     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  69             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  70 else()
  71     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  72     if(GMX_X11)
  73         file(GLOB VIEW_SOURCES view/*.cpp)
  74     else()
  75         file(GLOB VIEW_SOURCES view/view.cpp)
  76     endif()
  77     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  78     gmx_target_compile_options(view_objlib)
  79     target_compile_definitions(view_objlib PRIVATE HAVE_CONFIG_H)
  80     target_include_directories(view_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  81     target_link_libraries(view_objlib PRIVATE common legacy_api)
  82     # TODO: Explicitly link specific modules.
  83     target_link_libraries(view_objlib PRIVATE legacy_modules)
  84     add_library(gmx_objlib OBJECT ${GMX_MAIN_SOURCES})
  85     target_link_libraries(gmx_objlib PRIVATE common legacy_api)
  86     # TODO: Explicitly link specific modules.
  87     target_link_libraries(gmx_objlib PRIVATE legacy_modules)
  88     target_include_directories(gmx_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  89     target_include_directories(gmx_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  90     add_executable(gmx
  91         $<TARGET_OBJECTS:gmx_objlib>
  92         $<TARGET_OBJECTS:mdrun_objlib>
  93         $<TARGET_OBJECTS:view_objlib>)
  94     add_executable(Gromacs::gmx ALIAS gmx)
  95     gmx_target_compile_options(gmx)
  96     target_compile_definitions(gmx PRIVATE HAVE_CONFIG_H)
  97     target_link_libraries(gmx PRIVATE
  98                           common
  99                           libgromacs
 100                           ${GMX_COMMON_LIBRARIES}
 101                           ${GMX_EXE_LINKER_FLAGS})
 102     if(GMX_X11)
 103         target_link_libraries(gmx ${X11_LIBRARIES})
 104     endif()
 105     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
 106     set_target_properties(gmx PROPERTIES
 107         OUTPUT_NAME "${BINARY_NAME}")
 108     # Add the executable to the INSTALL target and to the libgromacs EXPORT configuration.
 109     # The GROMACS installation then provides an importable (e.g. find_package(GROMACS))
 110     # Gromacs::gmx target, which may be used as the executable COMMAND argument for functions like
 111     # add_custom_command() or add_test(). The full path to the installed binary may retrieved
 112     # from the LOCATION property or with a $<TARGET_FILE:Gromacs:gmx> generator expression
 113     # (where generator expressions are allowed).
 114     install(TARGETS gmx
 115             EXPORT libgromacs
 116             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 117
 118     ########################
 119     # Completion generation
 120
 121     include(gmxCustomCommandUtilities)
 122
 123     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
 124     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
 125     # this can be done are exactly the same (ability to run the compiled
 126     # binaries).
 127     if (GMX_BUILD_HELP)
 128         gmx_add_custom_output_target(completion OUTPUT STAMP
 129             COMMAND ${CMAKE_COMMAND}
 130                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
 131                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 132                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 133             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 134             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 135             COMMENT "Generating command-line completions for programs")
 136         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 137         set_directory_properties(PROPERTIES
 138             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 139         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 140     endif()
 141     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 142         install(DIRECTORY ${COMPLETION_DIR}/
 143                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 144         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 145              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 146         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 147                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 148     endif()
 149     gmx_cpack_add_generated_source_directory(completion)
 150
 151     if(BUILD_TESTING)
 152         add_subdirectory(mdrun/tests)
 153     endif()
 154 endif()