src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  36 # make an "object library" that we can re-use for multiple targets
  37 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  38 gmx_target_compile_options(mdrun_objlib)
  39 target_compile_definitions(mdrun_objlib PRIVATE HAVE_CONFIG_H)
  40 target_include_directories(mdrun_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  41
  42 if(GMX_FAHCORE)
  43     # The lack of a real source file here alongside the object library
  44     # may break some generators, according to CMake documentation. If
  45     # so, we can consider adding some dummy file to make it work.
  46     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  47     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES})
  48 elseif(GMX_BUILD_MDRUN_ONLY)
  49     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  50     gmx_target_compile_options(mdrun)
  51     target_compile_definitions(mdrun PRIVATE HAVE_CONFIG_H)
  52     target_link_libraries(mdrun libgromacs
  53         ${GMX_COMMON_LIBRARIES}
  54         ${GMX_EXE_LINKER_FLAGS})
  55     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  56     set_target_properties(mdrun PROPERTIES
  57         OUTPUT_NAME "${BINARY_NAME}")
  58     install(TARGETS mdrun DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun)
  59     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  60          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  61     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  62             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  63 else()
  64     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  65     if(GMX_X11)
  66         file(GLOB VIEW_SOURCES view/*.cpp)
  67     else()
  68         file(GLOB VIEW_SOURCES view/view.cpp)
  69     endif()
  70     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  71     gmx_target_compile_options(view_objlib)
  72     target_compile_definitions(view_objlib PRIVATE HAVE_CONFIG_H)
  73     add_executable(gmx
  74         ${GMX_MAIN_SOURCES}
  75         $<TARGET_OBJECTS:mdrun_objlib>
  76         $<TARGET_OBJECTS:view_objlib>)
  77     gmx_target_compile_options(gmx)
  78     target_compile_definitions(gmx PRIVATE HAVE_CONFIG_H)
  79     target_link_libraries(gmx libgromacs
  80         ${GMX_COMMON_LIBRARIES}
  81         ${GMX_EXE_LINKER_FLAGS})
  82     if(GMX_X11)
  83         target_link_libraries(gmx ${X11_LIBRARIES})
  84     endif()
  85     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  86     set_target_properties(gmx PROPERTIES
  87         OUTPUT_NAME "${BINARY_NAME}")
  88     install(TARGETS gmx
  89             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  90
  91     ########################
  92     # Completion generation
  93
  94     include(gmxCustomCommandUtilities)
  95
  96     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  97     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
  98     # this can be done are exactly the same (ability to run the compiled
  99     # binaries).
 100     if (GMX_BUILD_HELP)
 101         gmx_add_custom_output_target(completion OUTPUT STAMP
 102             COMMAND ${CMAKE_COMMAND}
 103                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
 104                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 105                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 106             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 107             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 108             COMMENT "Generating command-line completions for programs")
 109         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 110         set_directory_properties(PROPERTIES
 111             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 112         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 113     endif()
 114     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 115         install(DIRECTORY ${COMPLETION_DIR}/
 116                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 117         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 118              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 119         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 120                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 121     endif()
 122     gmx_cpack_add_generated_source_directory(completion)
 123
 124     if(BUILD_TESTING)
 125         add_subdirectory(mdrun/tests)
 126     endif()
 127 endif()