src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  37 # make an "object library" that we can re-use for multiple targets
  38 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  39 gmx_target_compile_options(mdrun_objlib)
  40 target_compile_definitions(mdrun_objlib PRIVATE HAVE_CONFIG_H)
  41 target_include_directories(mdrun_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  42 # Should be possible to remove this when resolving #3290
  43 target_include_directories(mdrun_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  44 target_link_libraries(mdrun_objlib PRIVATE common)
  45 target_link_libraries(mdrun_objlib PRIVATE legacy_api)
  46 # TODO: Explicitly link specific modules.
  47 target_link_libraries(mdrun_objlib PRIVATE legacy_modules)
  48
  49 if(GMX_FAHCORE)
  50     # The lack of a real source file here alongside the object library
  51     # may break some generators, according to CMake documentation. If
  52     # so, we can consider adding some dummy file to make it work.
  53     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  54     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES} legacy_api)
  55 elseif(GMX_BUILD_MDRUN_ONLY)
  56     message(STATUS "The mdrun-only build is deprecated")
  57     add_executable(mdrun-only $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  58     gmx_target_compile_options(mdrun-only)
  59     target_include_directories(mdrun-only SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  60     target_compile_definitions(mdrun-only PRIVATE HAVE_CONFIG_H)
  61     target_link_libraries(mdrun-only PRIVATE
  62                           common
  63                           legacy_modules
  64                           libgromacs
  65                           ${GMX_COMMON_LIBRARIES}
  66                           ${GMX_EXE_LINKER_FLAGS}
  67                           )
  68     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  69     set_target_properties(mdrun-only PROPERTIES
  70         OUTPUT_NAME "${BINARY_NAME}")
  71     install(TARGETS mdrun-only DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun-only)
  72     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  73          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  74     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  75             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  76 else()
  77     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  78     if(GMX_X11)
  79         file(GLOB VIEW_SOURCES view/*.cpp)
  80     else()
  81         file(GLOB VIEW_SOURCES view/view.cpp)
  82     endif()
  83     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  84     gmx_target_compile_options(view_objlib)
  85     target_compile_definitions(view_objlib PRIVATE HAVE_CONFIG_H)
  86     target_include_directories(view_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  87     target_link_libraries(view_objlib PRIVATE common legacy_api)
  88     # TODO: Explicitly link specific modules.
  89     target_link_libraries(view_objlib PRIVATE legacy_modules)
  90     add_library(gmx_objlib OBJECT ${GMX_MAIN_SOURCES})
  91     target_link_libraries(gmx_objlib PRIVATE common legacy_api)
  92     # TODO: Explicitly link specific modules.
  93     target_link_libraries(gmx_objlib PRIVATE legacy_modules)
  94     target_include_directories(gmx_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  95     target_include_directories(gmx_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  96     add_executable(gmx
  97         $<TARGET_OBJECTS:gmx_objlib>
  98         $<TARGET_OBJECTS:mdrun_objlib>
  99         $<TARGET_OBJECTS:view_objlib>)
 100     add_executable(Gromacs::gmx ALIAS gmx)
 101     gmx_target_compile_options(gmx)
 102     target_compile_definitions(gmx PRIVATE HAVE_CONFIG_H)
 103     target_link_libraries(gmx PRIVATE
 104                           common
 105                           libgromacs
 106                           ${GMX_COMMON_LIBRARIES}
 107                           ${GMX_EXE_LINKER_FLAGS})
 108     if(GMX_X11)
 109         target_link_libraries(gmx ${X11_LIBRARIES})
 110     endif()
 111     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
 112     set_target_properties(gmx PROPERTIES
 113         OUTPUT_NAME "${BINARY_NAME}")
 114     # Add the executable to the INSTALL target and to the libgromacs EXPORT configuration.
 115     # The GROMACS installation then provides an importable (e.g. find_package(GROMACS))
 116     # Gromacs::gmx target, which may be used as the executable COMMAND argument for functions like
 117     # add_custom_command() or add_test(). The full path to the installed binary may retrieved
 118     # from the LOCATION property or with a $<TARGET_FILE:Gromacs:gmx> generator expression
 119     # (where generator expressions are allowed).
 120     install(TARGETS gmx
 121             EXPORT libgromacs
 122             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 123
 124     ########################
 125     # Completion generation
 126
 127     include(gmxCustomCommandUtilities)
 128
 129     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
 130     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
 131     # this can be done are exactly the same (ability to run the compiled
 132     # binaries).
 133     if (GMX_BUILD_HELP)
 134         gmx_add_custom_output_target(completion OUTPUT STAMP
 135             COMMAND ${CMAKE_COMMAND}
 136                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
 137                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 138                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 139             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 140             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 141             COMMENT "Generating command-line completions for programs")
 142         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 143         set_directory_properties(PROPERTIES
 144             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 145         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 146     endif()
 147     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 148         install(DIRECTORY ${COMPLETION_DIR}/
 149                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 150         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 151              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 152         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 153                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 154     endif()
 155     gmx_cpack_add_generated_source_directory(completion)
 156
 157     if(BUILD_TESTING)
 158         add_subdirectory(mdrun/tests)
 159     endif()
 160 endif()