src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  36 # make an "object library" that we can re-use for multiple targets
  37 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  38
  39 if(GMX_FAHCORE)
  40     # The lack of a real source file here alongside the object library
  41     # may break some generators, according to CMake documentation. If
  42     # so, we can consider adding some dummy file to make it work.
  43     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  44     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES})
  45 elseif(GMX_BUILD_MDRUN_ONLY)
  46     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  47     target_link_libraries(mdrun libgromacs
  48         ${GMX_COMMON_LIBRARIES}
  49         ${GMX_EXE_LINKER_FLAGS})
  50     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  51     set_target_properties(mdrun PROPERTIES
  52         OUTPUT_NAME "${BINARY_NAME}")
  53     install(TARGETS mdrun DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun)
  54     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  55          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  56     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  57             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  58 else()
  59     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  60     if(GMX_X11)
  61         file(GLOB VIEW_SOURCES view/*.cpp)
  62     else()
  63         file(GLOB VIEW_SOURCES view/view.cpp)
  64     endif()
  65     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  66     add_executable(gmx
  67         ${GMX_MAIN_SOURCES}
  68         $<TARGET_OBJECTS:mdrun_objlib>
  69         $<TARGET_OBJECTS:view_objlib>)
  70     target_link_libraries(gmx libgromacs
  71         ${GMX_COMMON_LIBRARIES}
  72         ${GMX_EXE_LINKER_FLAGS})
  73     if(GMX_X11)
  74         target_link_libraries(gmx ${X11_LIBRARIES})
  75     endif()
  76     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  77     set_target_properties(gmx PROPERTIES
  78         OUTPUT_NAME "${BINARY_NAME}")
  79     install(TARGETS gmx
  80             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  81
  82     ########################
  83     # Completion generation
  84
  85     include(gmxCustomCommandUtilities)
  86
  87     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  88     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
  89     # this can be done are exactly the same (ability to run the compiled
  90     # binaries).
  91     if (GMX_BUILD_HELP)
  92         gmx_add_custom_output_target(completion OUTPUT STAMP
  93             COMMAND ${CMAKE_COMMAND}
  94                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
  95                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
  96                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
  97             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  98             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
  99             COMMENT "Generating command-line completions for programs")
 100         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 101         set_directory_properties(PROPERTIES
 102             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 103         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 104     endif()
 105     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 106         install(DIRECTORY ${COMPLETION_DIR}/
 107                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 108         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 109              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 110         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 111                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 112     endif()
 113     gmx_cpack_add_generated_source_directory(completion)
 114
 115     if(BUILD_TESTING)
 116         add_subdirectory(mdrun/tests)
 117     endif()
 118 endif()