src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \cond \internal \file scanner.l
  36  * \brief
  37  * Tokenizer for the selection language.
  38  *
  39  * \author Teemu Murtola <teemu.murtola@gmail.com>
  40  * \ingroup module_selection
  41  * \endcond
  42  */
  43 /*! \internal \file scanner.cpp
  44  * \brief
  45  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  46  *
  47  * \ingroup module_selection
  48  */
  49 %top{
  50 // Required before flex definitions, since it includes <stdint.h>.
  51 // Otherwise, compilers not strictly C99 get macro redefinition errors,
  52 // since flex defines INT32_MAX etc. in such cases.
  53 #include "gromacs/legacyheaders/types/simple.h"
  54 }
  55 %{
  56 #include "gromacs/utility/cstringutil.h"
  57
  58 #include "parser.h"
  59 #include "scanner.h"
  60 #include "scanner_internal.h"
  61
  62 // This macro makes the actions a bit shorter, since nearly every action needs
  63 // this call.
  64 #define ADD_TOKEN _gmx_sel_lexer_add_token(yytext, yyleng, state)
  65
  66 %}
  67
  68 INTEGER    [[:digit:]]+
  69 DSEQ       ([[:digit:]]+)
  70 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  71 EXP        ([eE][+-]?{DSEQ})
  72 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  73 STRING     (\"([^\"\\\n]|(\\\"))*\")
  74 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  75 CMPOP      (([<>]=?)|([!=]=))
  76 COMMENT    (#.*)
  77
  78 %option nodefault
  79 %option noyywrap
  80 %option reentrant
  81 %option prefix="_gmx_sel_yy"
  82 %option header-file="scanner_flex.h"
  83 %option nounistd
  84 %option never-interactive
  85
  86 %s matchof
  87 %s matchbool
  88 %s cmdstart
  89
  90 %%
  91
  92 %{
  93     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
  94     int              retval;
  95     /* Return a token if one is pending */
  96     retval = _gmx_sel_lexer_process_pending(yylval, state);
  97     if (retval != 0)
  98     {
  99         return retval;
 100     }
 101     /* Handle the start conditions for 'of' matching */
 102     if (state->bMatchOf)
 103     {
 104         BEGIN(matchof);
 105         state->bMatchOf = false;
 106     }
 107     else if (state->bMatchBool)
 108     {
 109         BEGIN(matchbool);
 110         state->bMatchBool = false;
 111     }
 112     else if (state->bCmdStart)
 113     {
 114         BEGIN(cmdstart);
 115         state->bCmdStart = false;
 116     }
 117     else
 118     {
 119         BEGIN(0);
 120     }
 121 %}
 122
 123 {COMMENT}
 124 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 125 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 126 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 127
 128 \\\n            { _gmx_sel_lexer_add_token(" ", 1, state); }
 129 ";"|\n          {
 130                     if (yytext[0] == ';' || state->bInteractive)
 131                     {
 132                         rtrim(state->pselstr);
 133                         state->bCmdStart = true;
 134                         return CMD_SEP;
 135                     }
 136                     else
 137                     {
 138                         _gmx_sel_lexer_add_token(" ", 1, state);
 139                     }
 140                 }
 141
 142 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 143 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 144
 145 <matchbool>{
 146 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 147 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 148 }
 149 group           { ADD_TOKEN; return GROUP; }
 150 to              { ADD_TOKEN; return TO; }
 151 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 152 and|"&&"        { ADD_TOKEN; return AND; }
 153 or|"||"         { ADD_TOKEN; return OR; }
 154 xor             { ADD_TOKEN; return XOR; }
 155 not|"!"         { ADD_TOKEN; return NOT; }
 156 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 157
 158 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yytext, yyleng, state); }
 159
 160 [[:space:]]+    { _gmx_sel_lexer_add_token(" ", 1, state); }
 161 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 162 .               { ADD_TOKEN; return yytext[0]; }