src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \cond \internal \file scanner.l
  36  * \brief
  37  * Tokenizer for the selection language.
  38  *
  39  * \author Teemu Murtola <teemu.murtola@gmail.com>
  40  * \ingroup module_selection
  41  * \endcond
  42  */
  43 /*! \internal \file scanner.cpp
  44  * \brief
  45  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  46  *
  47  * \ingroup module_selection
  48  */
  49 %top{
  50 #if !defined _gmx_sel_yyIN_HEADER
  51 #include "gmxpre.h"
  52 #endif
  53
  54 // Required before flex definitions, since it includes <stdint.h>.
  55 // Otherwise, compilers not strictly C99 get macro redefinition errors,
  56 // since flex defines INT32_MAX etc. in such cases.
  57 #include "gromacs/utility/basedefinitions.h"
  58 }
  59 %{
  60 #include "gromacs/utility/cstringutil.h"
  61 #include "gromacs/utility/stringutil.h"
  62
  63 #include "parser.h"
  64 #include "scanner.h"
  65 #include "scanner_internal.h"
  66
  67 // This macro makes the actions a bit shorter, since nearly every action needs
  68 // this call.
  69 #define ADD_TOKEN _gmx_sel_lexer_add_token(yylloc, yytext, yyleng, state)
  70
  71 // Set YY_BREAK to an empty value to avoid warnings (for the PGI compiler)
  72 // when we have return statements followed by break. Instead, we add breaks
  73 // manually.
  74 #define YY_BREAK
  75 %}
  76
  77 INTEGER    [[:digit:]]+
  78 DSEQ       ([[:digit:]]+)
  79 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  80 EXP        ([eE][+-]?{DSEQ})
  81 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  82 STRING     (\"([^\"\\\n]|(\\\"))*\")
  83 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  84 CMPOP      (([<>]=?)|([!=]=))
  85 COMMENT    (#.*)
  86
  87 %option nodefault
  88 %option noyywrap
  89 %option reentrant
  90 %option prefix="_gmx_sel_yy"
  91 %option header-file="scanner_flex.h"
  92 %option nounistd
  93 %option never-interactive
  94
  95 %s matchof
  96 %s matchbool
  97 %s cmdstart
  98
  99 %%
 100
 101 %{
 102     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
 103     int              retval;
 104     /* Return a token if one is pending */
 105     retval = _gmx_sel_lexer_process_pending(yylval, yylloc, state);
 106     if (retval != 0)
 107     {
 108         return retval;
 109     }
 110     /* Handle the start conditions for 'of' matching */
 111     if (state->bMatchOf)
 112     {
 113         BEGIN(matchof);
 114         state->bMatchOf = false;
 115     }
 116     else if (state->bMatchBool)
 117     {
 118         BEGIN(matchbool);
 119         state->bMatchBool = false;
 120     }
 121     else if (state->bCmdStart)
 122     {
 123         BEGIN(cmdstart);
 124         state->bCmdStart = false;
 125     }
 126     else
 127     {
 128         BEGIN(0);
 129     }
 130 %}
 131
 132 {COMMENT}       break;
 133 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 134 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 135 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 136
 137 \\\n            { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 138 ";"|\n          {
 139                     if (yytext[0] == ';' || state->statusWriter != NULL)
 140                     {
 141                         state->pselstr = gmx::stripString(state->pselstr);
 142                         state->bCmdStart = true;
 143                         return CMD_SEP;
 144                     }
 145                     else
 146                     {
 147                         _gmx_sel_lexer_add_token(yylloc, " ", 1, state);
 148                     }
 149                     break;
 150                 }
 151
 152 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 153 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 154
 155 <matchbool>{
 156 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 157 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 158 }
 159 group           { ADD_TOKEN; return GROUP; }
 160 to              { ADD_TOKEN; return TO; }
 161 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 162 and|"&&"        { ADD_TOKEN; return AND; }
 163 or|"||"         { ADD_TOKEN; return OR; }
 164 xor             { ADD_TOKEN; return XOR; }
 165 not|"!"         { ADD_TOKEN; return NOT; }
 166 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 167
 168 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yylloc, yytext, yyleng, state); }
 169
 170 [[:space:]]+    { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 171 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 172 .               { ADD_TOKEN; return yytext[0]; }