src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \cond \internal \file scanner.l
  36  * \brief
  37  * Tokenizer for the selection language.
  38  *
  39  * \author Teemu Murtola <teemu.murtola@gmail.com>
  40  * \ingroup module_selection
  41  * \endcond
  42  */
  43 /*! \internal \file scanner.cpp
  44  * \brief
  45  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  46  *
  47  * \ingroup module_selection
  48  */
  49 %top{
  50 // Required before flex definitions, since it includes <stdint.h>.
  51 // Otherwise, compilers not strictly C99 get macro redefinition errors,
  52 // since flex defines INT32_MAX etc. in such cases.
  53 #include "gromacs/legacyheaders/types/simple.h"
  54 }
  55 %{
  56 #include "gromacs/utility/cstringutil.h"
  57
  58 #include "parser.h"
  59 #include "scanner.h"
  60 #include "scanner_internal.h"
  61
  62 // This macro makes the actions a bit shorter, since nearly every action needs
  63 // this call.
  64 #define ADD_TOKEN _gmx_sel_lexer_add_token(yytext, yyleng, state)
  65
  66 // Set YY_BREAK to an empty value to avoid warnings (for the PGI compiler)
  67 // when we have return statements followed by break. Instead, we add breaks
  68 // manually.
  69 #define YY_BREAK
  70 %}
  71
  72 INTEGER    [[:digit:]]+
  73 DSEQ       ([[:digit:]]+)
  74 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  75 EXP        ([eE][+-]?{DSEQ})
  76 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  77 STRING     (\"([^\"\\\n]|(\\\"))*\")
  78 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  79 CMPOP      (([<>]=?)|([!=]=))
  80 COMMENT    (#.*)
  81
  82 %option nodefault
  83 %option noyywrap
  84 %option reentrant
  85 %option prefix="_gmx_sel_yy"
  86 %option header-file="scanner_flex.h"
  87 %option nounistd
  88 %option never-interactive
  89
  90 %s matchof
  91 %s matchbool
  92 %s cmdstart
  93
  94 %%
  95
  96 %{
  97     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
  98     int              retval;
  99     /* Return a token if one is pending */
 100     retval = _gmx_sel_lexer_process_pending(yylval, state);
 101     if (retval != 0)
 102     {
 103         return retval;
 104     }
 105     /* Handle the start conditions for 'of' matching */
 106     if (state->bMatchOf)
 107     {
 108         BEGIN(matchof);
 109         state->bMatchOf = false;
 110     }
 111     else if (state->bMatchBool)
 112     {
 113         BEGIN(matchbool);
 114         state->bMatchBool = false;
 115     }
 116     else if (state->bCmdStart)
 117     {
 118         BEGIN(cmdstart);
 119         state->bCmdStart = false;
 120     }
 121     else
 122     {
 123         BEGIN(0);
 124     }
 125 %}
 126
 127 {COMMENT}       break;
 128 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 129 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 130 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 131
 132 \\\n            { _gmx_sel_lexer_add_token(" ", 1, state); break; }
 133 ";"|\n          {
 134                     if (yytext[0] == ';' || state->bInteractive)
 135                     {
 136                         rtrim(state->pselstr);
 137                         state->bCmdStart = true;
 138                         return CMD_SEP;
 139                     }
 140                     else
 141                     {
 142                         _gmx_sel_lexer_add_token(" ", 1, state);
 143                     }
 144                     break;
 145                 }
 146
 147 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 148 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 149
 150 <matchbool>{
 151 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 152 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 153 }
 154 group           { ADD_TOKEN; return GROUP; }
 155 to              { ADD_TOKEN; return TO; }
 156 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 157 and|"&&"        { ADD_TOKEN; return AND; }
 158 or|"||"         { ADD_TOKEN; return OR; }
 159 xor             { ADD_TOKEN; return XOR; }
 160 not|"!"         { ADD_TOKEN; return NOT; }
 161 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 162
 163 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yytext, yyleng, state); }
 164
 165 [[:space:]]+    { _gmx_sel_lexer_add_token(" ", 1, state); break; }
 166 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 167 .               { ADD_TOKEN; return yytext[0]; }