src/gromacs/nbnxm/cuda/nbnxm_cuda_kernel.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2012,2013,2014,2015,2016 by the GROMACS development team.
   5  * Copyright (c) 2017,2018,2019,2020, by the GROMACS development team, led by
   6  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7  * and including many others, as listed in the AUTHORS file in the
   8  * top-level source directory and at http://www.gromacs.org.
   9  *
  10  * GROMACS is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU Lesser General Public License
  12  * as published by the Free Software Foundation; either version 2.1
  13  * of the License, or (at your option) any later version.
  14  *
  15  * GROMACS is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18  * Lesser General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU Lesser General Public
  21  * License along with GROMACS; if not, see
  22  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24  *
  25  * If you want to redistribute modifications to GROMACS, please
  26  * consider that scientific software is very special. Version
  27  * control is crucial - bugs must be traceable. We will be happy to
  28  * consider code for inclusion in the official distribution, but
  29  * derived work must not be called official GROMACS. Details are found
  30  * in the README & COPYING files - if they are missing, get the
  31  * official version at http://www.gromacs.org.
  32  *
  33  * To help us fund GROMACS development, we humbly ask that you cite
  34  * the research papers on the package. Check out http://www.gromacs.org.
  35  */
  36
  37 /*! \internal \file
  38  *  \brief
  39  *  CUDA non-bonded kernel used through preprocessor-based code generation
  40  *  of multiple kernel flavors, see nbnxn_cuda_kernels.cuh.
  41  *
  42  *  NOTE: No include fence as it is meant to be included multiple times.
  43  *
  44  *  \author Szilárd Páll <pall.szilard@gmail.com>
  45  *  \author Berk Hess <hess@kth.se>
  46  *  \ingroup module_nbnxm
  47  */
  48
  49 #include "gromacs/gpu_utils/cuda_arch_utils.cuh"
  50 #include "gromacs/gpu_utils/cuda_kernel_utils.cuh"
  51 #include "gromacs/math/utilities.h"
  52 #include "gromacs/pbcutil/ishift.h"
  53 /* Note that floating-point constants in CUDA code should be suffixed
  54  * with f (e.g. 0.5f), to stop the compiler producing intermediate
  55  * code that is in double precision.
  56  */
  57
  58 #if defined EL_EWALD_ANA || defined EL_EWALD_TAB
  59 /* Note: convenience macro, needs to be undef-ed at the end of the file. */
  60 #    define EL_EWALD_ANY
  61 #endif
  62
  63 #if defined EL_EWALD_ANY || defined EL_RF || defined LJ_EWALD \
  64         || (defined EL_CUTOFF && defined CALC_ENERGIES)
  65 /* Macro to control the calculation of exclusion forces in the kernel
  66  * We do that with Ewald (elec/vdw) and RF. Cut-off only has exclusion
  67  * energy terms.
  68  *
  69  * Note: convenience macro, needs to be undef-ed at the end of the file.
  70  */
  71 #    define EXCLUSION_FORCES
  72 #endif
  73
  74 #if defined LJ_EWALD_COMB_GEOM || defined LJ_EWALD_COMB_LB
  75 /* Note: convenience macro, needs to be undef-ed at the end of the file. */
  76 #    define LJ_EWALD
  77 #endif
  78
  79 #if defined LJ_COMB_GEOM || defined LJ_COMB_LB
  80 #    define LJ_COMB
  81 #endif
  82
  83 /*
  84    Kernel launch parameters:
  85     - #blocks   = #pair lists, blockId = pair list Id
  86     - #threads  = NTHREAD_Z * c_clSize^2
  87     - shmem     = see nbnxn_cuda.cu:calc_shmem_required_nonbonded()
  88
  89     Each thread calculates an i force-component taking one pair of i-j atoms.
  90  */
  91
  92 /**@{*/
  93 /*! \brief Compute capability dependent definition of kernel launch configuration parameters.
  94  *
  95  * NTHREAD_Z controls the number of j-clusters processed concurrently on NTHREAD_Z
  96  * warp-pairs per block.
  97  *
  98  * - On CC 3.0-3.5, and >=5.0 NTHREAD_Z == 1, translating to 64 th/block with 16
  99  * blocks/multiproc, is the fastest even though this setup gives low occupancy
 100  * (except on 6.0).
 101  * NTHREAD_Z > 1 results in excessive register spilling unless the minimum blocks
 102  * per multiprocessor is reduced proportionally to get the original number of max
 103  * threads in flight (and slightly lower performance).
 104  * - On CC 3.7 there are enough registers to double the number of threads; using
 105  * NTHREADS_Z == 2 is fastest with 16 blocks (TODO: test with RF and other kernels
 106  * with low-register use).
 107  *
 108  * Note that the current kernel implementation only supports NTHREAD_Z > 1 with
 109  * shuffle-based reduction, hence CC >= 3.0.
 110  *
 111  *
 112  * NOTEs on Volta / CUDA 9 extensions:
 113  *
 114  * - While active thread masks are required for the warp collectives
 115  *   (we use any and shfl), the kernel is designed such that all conditions
 116  *   (other than the inner-most distance check) including loop trip counts
 117  *   are warp-synchronous. Therefore, we don't need ballot to compute the
 118  *   active masks as these are all full-warp masks.
 119  *
 120  * - TODO: reconsider the use of __syncwarp(): its only role is currently to prevent
 121  *   WAR hazard due to the cj preload; we should try to replace it with direct
 122  *   loads (which may be faster given the improved L1 on Volta).
 123  */
 124
 125 /* Kernel launch bounds for different compute capabilities. The value of NTHREAD_Z
 126  * determines the number of threads per block and it is chosen such that
 127  * 16 blocks/multiprocessor can be kept in flight.
 128  * - CC 3.0,3.5, and >=5.0: NTHREAD_Z=1, (64, 16) bounds
 129  * - CC 3.7:                NTHREAD_Z=2, (128, 16) bounds
 130  *
 131  * Note: convenience macros, need to be undef-ed at the end of the file.
 132  */
 133 #if GMX_PTX_ARCH == 370
 134 #    define NTHREAD_Z (2)
 135 #    define MIN_BLOCKS_PER_MP (16)
 136 #else
 137 #    define NTHREAD_Z (1)
 138 #    define MIN_BLOCKS_PER_MP (16)
 139 #endif /* GMX_PTX_ARCH == 370 */
 140 #define THREADS_PER_BLOCK (c_clSize * c_clSize * NTHREAD_Z)
 141
 142 #if GMX_PTX_ARCH >= 350
 143 /**@}*/
 144 __launch_bounds__(THREADS_PER_BLOCK, MIN_BLOCKS_PER_MP)
 145 #else
 146 __launch_bounds__(THREADS_PER_BLOCK)
 147 #endif /* GMX_PTX_ARCH >= 350 */
 148 #ifdef PRUNE_NBL
 149 #    ifdef CALC_ENERGIES
 150         __global__ void NB_KERNEL_FUNC_NAME(nbnxn_kernel, _VF_prune_cuda)
 151 #    else
 152         __global__ void NB_KERNEL_FUNC_NAME(nbnxn_kernel, _F_prune_cuda)
 153 #    endif /* CALC_ENERGIES */
 154 #else
 155 #    ifdef CALC_ENERGIES
 156         __global__ void NB_KERNEL_FUNC_NAME(nbnxn_kernel, _VF_cuda)
 157 #    else
 158         __global__ void NB_KERNEL_FUNC_NAME(nbnxn_kernel, _F_cuda)
 159 #    endif /* CALC_ENERGIES */
 160 #endif     /* PRUNE_NBL */
 161                 (const cu_atomdata_t atdat, const cu_nbparam_t nbparam, const cu_plist_t plist, bool bCalcFshift)
 162 #ifdef FUNCTION_DECLARATION_ONLY
 163                         ; /* Only do function declaration, omit the function body. */
 164 #else
 165 {
 166     /* convenience variables */
 167     const nbnxn_sci_t* pl_sci = plist.sci;
 168 #    ifndef PRUNE_NBL
 169     const
 170 #    endif
 171             nbnxn_cj4_t* pl_cj4      = plist.cj4;
 172     const nbnxn_excl_t*  excl        = plist.excl;
 173 #    ifndef LJ_COMB
 174     const int*           atom_types  = atdat.atom_types;
 175     int                  ntypes      = atdat.ntypes;
 176 #    else
 177     const float2* lj_comb = atdat.lj_comb;
 178     float2        ljcp_i, ljcp_j;
 179 #    endif
 180     const float4*        xq          = atdat.xq;
 181     float3*              f           = atdat.f;
 182     const float3*        shift_vec   = atdat.shift_vec;
 183     float                rcoulomb_sq = nbparam.rcoulomb_sq;
 184 #    ifdef VDW_CUTOFF_CHECK
 185     float                rvdw_sq     = nbparam.rvdw_sq;
 186     float                vdw_in_range;
 187 #    endif
 188 #    ifdef LJ_EWALD
 189     float                lje_coeff2, lje_coeff6_6;
 190 #    endif
 191 #    ifdef EL_RF
 192     float                two_k_rf    = nbparam.two_k_rf;
 193 #    endif
 194 #    ifdef EL_EWALD_ANA
 195     float                beta2       = nbparam.ewald_beta * nbparam.ewald_beta;
 196     float                beta3       = nbparam.ewald_beta * nbparam.ewald_beta * nbparam.ewald_beta;
 197 #    endif
 198 #    ifdef PRUNE_NBL
 199     float                rlist_sq    = nbparam.rlistOuter_sq;
 200 #    endif
 201
 202 #    ifdef CALC_ENERGIES
 203 #        ifdef EL_EWALD_ANY
 204     float                beta        = nbparam.ewald_beta;
 205     float                ewald_shift = nbparam.sh_ewald;
 206 #        else
 207     float c_rf = nbparam.c_rf;
 208 #        endif /* EL_EWALD_ANY */
 209     float*               e_lj        = atdat.e_lj;
 210     float*               e_el        = atdat.e_el;
 211 #    endif     /* CALC_ENERGIES */
 212
 213     /* thread/block/warp id-s */
 214     unsigned int tidxi = threadIdx.x;
 215     unsigned int tidxj = threadIdx.y;
 216     unsigned int tidx  = threadIdx.y * blockDim.x + threadIdx.x;
 217 #    if NTHREAD_Z == 1
 218     unsigned int tidxz = 0;
 219 #    else
 220     unsigned int  tidxz = threadIdx.z;
 221 #    endif
 222     unsigned int bidx  = blockIdx.x;
 223     unsigned int widx  = tidx / warp_size; /* warp index */
 224
 225     int          sci, ci, cj, ai, aj, cij4_start, cij4_end;
 226 #    ifndef LJ_COMB
 227     int          typei, typej;
 228 #    endif
 229     int          i, jm, j4, wexcl_idx;
 230     float        qi, qj_f, r2, inv_r, inv_r2;
 231 #    if !defined LJ_COMB_LB || defined CALC_ENERGIES
 232     float        inv_r6, c6, c12;
 233 #    endif
 234 #    ifdef LJ_COMB_LB
 235     float        sigma, epsilon;
 236 #    endif
 237     float        int_bit, F_invr;
 238 #    ifdef CALC_ENERGIES
 239     float        E_lj, E_el;
 240 #    endif
 241 #    if defined CALC_ENERGIES || defined LJ_POT_SWITCH
 242     float        E_lj_p;
 243 #    endif
 244     unsigned int wexcl, imask, mask_ji;
 245     float4       xqbuf;
 246     float3       xi, xj, rv, f_ij, fcj_buf;
 247     float3       fci_buf[c_numClPerSupercl]; /* i force buffer */
 248     nbnxn_sci_t  nb_sci;
 249
 250     /*! i-cluster interaction mask for a super-cluster with all c_numClPerSupercl=8 bits set */
 251     const unsigned superClInteractionMask = ((1U << c_numClPerSupercl) - 1U);
 252
 253     /*********************************************************************
 254      * Set up shared memory pointers.
 255      * sm_nextSlotPtr should always be updated to point to the "next slot",
 256      * that is past the last point where data has been stored.
 257      */
 258     extern __shared__ char sm_dynamicShmem[];
 259     char*                  sm_nextSlotPtr = sm_dynamicShmem;
 260     static_assert(sizeof(char) == 1,
 261                   "The shared memory offset calculation assumes that char is 1 byte");
 262
 263     /* shmem buffer for i x+q pre-loading */
 264     float4* xqib = (float4*)sm_nextSlotPtr;
 265     sm_nextSlotPtr += (c_numClPerSupercl * c_clSize * sizeof(*xqib));
 266
 267     /* shmem buffer for cj, for each warp separately */
 268     int* cjs = (int*)(sm_nextSlotPtr);
 269     /* the cjs buffer's use expects a base pointer offset for pairs of warps in the j-concurrent execution */
 270     cjs += tidxz * c_nbnxnGpuClusterpairSplit * c_nbnxnGpuJgroupSize;
 271     sm_nextSlotPtr += (NTHREAD_Z * c_nbnxnGpuClusterpairSplit * c_nbnxnGpuJgroupSize * sizeof(*cjs));
 272
 273 #    ifndef LJ_COMB
 274     /* shmem buffer for i atom-type pre-loading */
 275     int* atib = (int*)sm_nextSlotPtr;
 276     sm_nextSlotPtr += (c_numClPerSupercl * c_clSize * sizeof(*atib));
 277 #    else
 278     /* shmem buffer for i-atom LJ combination rule parameters */
 279     float2* ljcpib = (float2*)sm_nextSlotPtr;
 280     sm_nextSlotPtr += (c_numClPerSupercl * c_clSize * sizeof(*ljcpib));
 281 #    endif
 282     /*********************************************************************/
 283
 284     nb_sci     = pl_sci[bidx];         /* my i super-cluster's index = current bidx */
 285     sci        = nb_sci.sci;           /* super-cluster */
 286     cij4_start = nb_sci.cj4_ind_start; /* first ...*/
 287     cij4_end   = nb_sci.cj4_ind_end;   /* and last index of j clusters */
 288
 289     if (tidxz == 0)
 290     {
 291         /* Pre-load i-atom x and q into shared memory */
 292         ci = sci * c_numClPerSupercl + tidxj;
 293         ai = ci * c_clSize + tidxi;
 294
 295         float* shiftptr = (float*)&shift_vec[nb_sci.shift];
 296         xqbuf = xq[ai] + make_float4(LDG(shiftptr), LDG(shiftptr + 1), LDG(shiftptr + 2), 0.0f);
 297         xqbuf.w *= nbparam.epsfac;
 298         xqib[tidxj * c_clSize + tidxi] = xqbuf;
 299
 300 #    ifndef LJ_COMB
 301         /* Pre-load the i-atom types into shared memory */
 302         atib[tidxj * c_clSize + tidxi] = atom_types[ai];
 303 #    else
 304         /* Pre-load the LJ combination parameters into shared memory */
 305         ljcpib[tidxj * c_clSize + tidxi] = lj_comb[ai];
 306 #    endif
 307     }
 308     __syncthreads();
 309
 310     for (i = 0; i < c_numClPerSupercl; i++)
 311     {
 312         fci_buf[i] = make_float3(0.0f);
 313     }
 314
 315 #    ifdef LJ_EWALD
 316     /* TODO: we are trading registers with flops by keeping lje_coeff-s, try re-calculating it later */
 317     lje_coeff2   = nbparam.ewaldcoeff_lj * nbparam.ewaldcoeff_lj;
 318     lje_coeff6_6 = lje_coeff2 * lje_coeff2 * lje_coeff2 * c_oneSixth;
 319 #    endif
 320
 321
 322 #    ifdef CALC_ENERGIES
 323     E_lj         = 0.0f;
 324     E_el         = 0.0f;
 325
 326 #        ifdef EXCLUSION_FORCES /* Ewald or RF */
 327     if (nb_sci.shift == CENTRAL && pl_cj4[cij4_start].cj[0] == sci * c_numClPerSupercl)
 328     {
 329         /* we have the diagonal: add the charge and LJ self interaction energy term */
 330         for (i = 0; i < c_numClPerSupercl; i++)
 331         {
 332 #            if defined EL_EWALD_ANY || defined EL_RF || defined EL_CUTOFF
 333             qi = xqib[i * c_clSize + tidxi].w;
 334             E_el += qi * qi;
 335 #            endif
 336
 337 #            ifdef LJ_EWALD
 338 #                if DISABLE_CUDA_TEXTURES
 339             E_lj += LDG(
 340                     &nbparam.nbfp[atom_types[(sci * c_numClPerSupercl + i) * c_clSize + tidxi] * (ntypes + 1) * 2]);
 341 #                else
 342             E_lj += tex1Dfetch<float>(
 343                     nbparam.nbfp_texobj,
 344                     atom_types[(sci * c_numClPerSupercl + i) * c_clSize + tidxi] * (ntypes + 1) * 2);
 345 #                endif
 346 #            endif
 347         }
 348
 349         /* divide the self term(s) equally over the j-threads, then multiply with the coefficients. */
 350 #            ifdef LJ_EWALD
 351         E_lj /= c_clSize * NTHREAD_Z;
 352         E_lj *= 0.5f * c_oneSixth * lje_coeff6_6;
 353 #            endif
 354
 355 #            if defined EL_EWALD_ANY || defined EL_RF || defined EL_CUTOFF
 356         /* Correct for epsfac^2 due to adding qi^2 */
 357         E_el /= nbparam.epsfac * c_clSize * NTHREAD_Z;
 358 #                if defined EL_RF || defined EL_CUTOFF
 359         E_el *= -0.5f * c_rf;
 360 #                else
 361         E_el *= -beta * M_FLOAT_1_SQRTPI; /* last factor 1/sqrt(pi) */
 362 #                endif
 363 #            endif /* EL_EWALD_ANY || defined EL_RF || defined EL_CUTOFF */
 364     }
 365 #        endif     /* EXCLUSION_FORCES */
 366
 367 #    endif /* CALC_ENERGIES */
 368
 369 #    ifdef EXCLUSION_FORCES
 370     const int nonSelfInteraction = !(nb_sci.shift == CENTRAL & tidxj <= tidxi);
 371 #    endif
 372
 373     /* loop over the j clusters = seen by any of the atoms in the current super-cluster;
 374      * The loop stride NTHREAD_Z ensures that consecutive warps-pairs are assigned
 375      * consecutive j4's entries.
 376      */
 377     for (j4 = cij4_start + tidxz; j4 < cij4_end; j4 += NTHREAD_Z)
 378     {
 379         wexcl_idx = pl_cj4[j4].imei[widx].excl_ind;
 380         imask     = pl_cj4[j4].imei[widx].imask;
 381         wexcl     = excl[wexcl_idx].pair[(tidx) & (warp_size - 1)];
 382
 383 #    ifndef PRUNE_NBL
 384         if (imask)
 385 #    endif
 386         {
 387             /* Pre-load cj into shared memory on both warps separately */
 388             if ((tidxj == 0 | tidxj == 4) & (tidxi < c_nbnxnGpuJgroupSize))
 389             {
 390                 cjs[tidxi + tidxj * c_nbnxnGpuJgroupSize / c_splitClSize] = pl_cj4[j4].cj[tidxi];
 391             }
 392             __syncwarp(c_fullWarpMask);
 393
 394             /* Unrolling this loop
 395                - with pruning leads to register spilling;
 396                - on Kepler and later it is much slower;
 397                Tested with up to nvcc 7.5 */
 398             for (jm = 0; jm < c_nbnxnGpuJgroupSize; jm++)
 399             {
 400                 if (imask & (superClInteractionMask << (jm * c_numClPerSupercl)))
 401                 {
 402                     mask_ji = (1U << (jm * c_numClPerSupercl));
 403
 404                     cj = cjs[jm + (tidxj & 4) * c_nbnxnGpuJgroupSize / c_splitClSize];
 405                     aj = cj * c_clSize + tidxj;
 406
 407                     /* load j atom data */
 408                     xqbuf = xq[aj];
 409                     xj    = make_float3(xqbuf.x, xqbuf.y, xqbuf.z);
 410                     qj_f  = xqbuf.w;
 411 #    ifndef LJ_COMB
 412                     typej = atom_types[aj];
 413 #    else
 414                     ljcp_j = lj_comb[aj];
 415 #    endif
 416
 417                     fcj_buf = make_float3(0.0f);
 418
 419 #    if !defined PRUNE_NBL
 420 #        pragma unroll 8
 421 #    endif
 422                     for (i = 0; i < c_numClPerSupercl; i++)
 423                     {
 424                         if (imask & mask_ji)
 425                         {
 426                             ci = sci * c_numClPerSupercl + i; /* i cluster index */
 427
 428                             /* all threads load an atom from i cluster ci into shmem! */
 429                             xqbuf = xqib[i * c_clSize + tidxi];
 430                             xi    = make_float3(xqbuf.x, xqbuf.y, xqbuf.z);
 431
 432                             /* distance between i and j atoms */
 433                             rv = xi - xj;
 434                             r2 = norm2(rv);
 435
 436 #    ifdef PRUNE_NBL
 437                             /* If _none_ of the atoms pairs are in cutoff range,
 438                                the bit corresponding to the current
 439                                cluster-pair in imask gets set to 0. */
 440                             if (!__any_sync(c_fullWarpMask, r2 < rlist_sq))
 441                             {
 442                                 imask &= ~mask_ji;
 443                             }
 444 #    endif
 445
 446                             int_bit = (wexcl & mask_ji) ? 1.0f : 0.0f;
 447
 448                             /* cutoff & exclusion check */
 449 #    ifdef EXCLUSION_FORCES
 450                             if ((r2 < rcoulomb_sq) * (nonSelfInteraction | (ci != cj)))
 451 #    else
 452                             if ((r2 < rcoulomb_sq) * int_bit)
 453 #    endif
 454                             {
 455                                 /* load the rest of the i-atom parameters */
 456                                 qi = xqbuf.w;
 457
 458 #    ifndef LJ_COMB
 459                                 /* LJ 6*C6 and 12*C12 */
 460                                 typei = atib[i * c_clSize + tidxi];
 461                                 fetch_nbfp_c6_c12(c6, c12, nbparam, ntypes * typei + typej);
 462 #    else
 463                                 ljcp_i       = ljcpib[i * c_clSize + tidxi];
 464 #        ifdef LJ_COMB_GEOM
 465                                 c6           = ljcp_i.x * ljcp_j.x;
 466                                 c12          = ljcp_i.y * ljcp_j.y;
 467 #        else
 468                                 /* LJ 2^(1/6)*sigma and 12*epsilon */
 469                                 sigma   = ljcp_i.x + ljcp_j.x;
 470                                 epsilon = ljcp_i.y * ljcp_j.y;
 471 #            if defined CALC_ENERGIES || defined LJ_FORCE_SWITCH || defined LJ_POT_SWITCH
 472                                 convert_sigma_epsilon_to_c6_c12(sigma, epsilon, &c6, &c12);
 473 #            endif
 474 #        endif /* LJ_COMB_GEOM */
 475 #    endif     /* LJ_COMB */
 476
 477                                 // Ensure distance do not become so small that r^-12 overflows
 478                                 r2 = max(r2, NBNXN_MIN_RSQ);
 479
 480                                 inv_r  = rsqrt(r2);
 481                                 inv_r2 = inv_r * inv_r;
 482 #    if !defined LJ_COMB_LB || defined CALC_ENERGIES
 483                                 inv_r6 = inv_r2 * inv_r2 * inv_r2;
 484 #        ifdef EXCLUSION_FORCES
 485                                 /* We could mask inv_r2, but with Ewald
 486                                  * masking both inv_r6 and F_invr is faster */
 487                                 inv_r6 *= int_bit;
 488 #        endif /* EXCLUSION_FORCES */
 489
 490                                 F_invr = inv_r6 * (c12 * inv_r6 - c6) * inv_r2;
 491 #        if defined CALC_ENERGIES || defined LJ_POT_SWITCH
 492                                 E_lj_p = int_bit
 493                                          * (c12 * (inv_r6 * inv_r6 + nbparam.repulsion_shift.cpot) * c_oneTwelveth
 494                                             - c6 * (inv_r6 + nbparam.dispersion_shift.cpot) * c_oneSixth);
 495 #        endif
 496 #    else /* !LJ_COMB_LB || CALC_ENERGIES */
 497                                 float sig_r  = sigma * inv_r;
 498                                 float sig_r2 = sig_r * sig_r;
 499                                 float sig_r6 = sig_r2 * sig_r2 * sig_r2;
 500 #        ifdef EXCLUSION_FORCES
 501                                 sig_r6 *= int_bit;
 502 #        endif /* EXCLUSION_FORCES */
 503
 504                                 F_invr = epsilon * sig_r6 * (sig_r6 - 1.0f) * inv_r2;
 505 #    endif     /* !LJ_COMB_LB || CALC_ENERGIES */
 506
 507 #    ifdef LJ_FORCE_SWITCH
 508 #        ifdef CALC_ENERGIES
 509                                 calculate_force_switch_F_E(nbparam, c6, c12, inv_r, r2, &F_invr, &E_lj_p);
 510 #        else
 511                                 calculate_force_switch_F(nbparam, c6, c12, inv_r, r2, &F_invr);
 512 #        endif /* CALC_ENERGIES */
 513 #    endif     /* LJ_FORCE_SWITCH */
 514
 515
 516 #    ifdef LJ_EWALD
 517 #        ifdef LJ_EWALD_COMB_GEOM
 518 #            ifdef CALC_ENERGIES
 519                                 calculate_lj_ewald_comb_geom_F_E(nbparam, typei, typej, r2, inv_r2,
 520                                                                  lje_coeff2, lje_coeff6_6, int_bit,
 521                                                                  &F_invr, &E_lj_p);
 522 #            else
 523                                 calculate_lj_ewald_comb_geom_F(nbparam, typei, typej, r2, inv_r2,
 524                                                                lje_coeff2, lje_coeff6_6, &F_invr);
 525 #            endif /* CALC_ENERGIES */
 526 #        elif defined LJ_EWALD_COMB_LB
 527                                 calculate_lj_ewald_comb_LB_F_E(nbparam, typei, typej, r2, inv_r2,
 528                                                                lje_coeff2, lje_coeff6_6,
 529 #            ifdef CALC_ENERGIES
 530                                                                int_bit, &F_invr, &E_lj_p
 531 #            else
 532                                                                0, &F_invr, nullptr
 533 #            endif /* CALC_ENERGIES */
 534                                 );
 535 #        endif     /* LJ_EWALD_COMB_GEOM */
 536 #    endif         /* LJ_EWALD */
 537
 538 #    ifdef LJ_POT_SWITCH
 539 #        ifdef CALC_ENERGIES
 540                                 calculate_potential_switch_F_E(nbparam, inv_r, r2, &F_invr, &E_lj_p);
 541 #        else
 542                                 calculate_potential_switch_F(nbparam, inv_r, r2, &F_invr, &E_lj_p);
 543 #        endif /* CALC_ENERGIES */
 544 #    endif     /* LJ_POT_SWITCH */
 545
 546 #    ifdef VDW_CUTOFF_CHECK
 547                                 /* Separate VDW cut-off check to enable twin-range cut-offs
 548                                  * (rvdw < rcoulomb <= rlist)
 549                                  */
 550                                 vdw_in_range = (r2 < rvdw_sq) ? 1.0f : 0.0f;
 551                                 F_invr *= vdw_in_range;
 552 #        ifdef CALC_ENERGIES
 553                                 E_lj_p *= vdw_in_range;
 554 #        endif
 555 #    endif /* VDW_CUTOFF_CHECK */
 556
 557 #    ifdef CALC_ENERGIES
 558                                 E_lj += E_lj_p;
 559 #    endif
 560
 561
 562 #    ifdef EL_CUTOFF
 563 #        ifdef EXCLUSION_FORCES
 564                                 F_invr += qi * qj_f * int_bit * inv_r2 * inv_r;
 565 #        else
 566                                 F_invr += qi * qj_f * inv_r2 * inv_r;
 567 #        endif
 568 #    endif
 569 #    ifdef EL_RF
 570                                 F_invr += qi * qj_f * (int_bit * inv_r2 * inv_r - two_k_rf);
 571 #    endif
 572 #    if defined   EL_EWALD_ANA
 573                                 F_invr += qi * qj_f
 574                                           * (int_bit * inv_r2 * inv_r + pmecorrF(beta2 * r2) * beta3);
 575 #    elif defined EL_EWALD_TAB
 576                                 F_invr += qi * qj_f
 577                                           * (int_bit * inv_r2
 578                                              - interpolate_coulomb_force_r(nbparam, r2 * inv_r))
 579                                           * inv_r;
 580 #    endif /* EL_EWALD_ANA/TAB */
 581
 582 #    ifdef CALC_ENERGIES
 583 #        ifdef EL_CUTOFF
 584                                 E_el += qi * qj_f * (int_bit * inv_r - c_rf);
 585 #        endif
 586 #        ifdef EL_RF
 587                                 E_el += qi * qj_f * (int_bit * inv_r + 0.5f * two_k_rf * r2 - c_rf);
 588 #        endif
 589 #        ifdef EL_EWALD_ANY
 590                                 /* 1.0f - erff is faster than erfcf */
 591                                 E_el += qi * qj_f
 592                                         * (inv_r * (int_bit - erff(r2 * inv_r * beta)) - int_bit * ewald_shift);
 593 #        endif /* EL_EWALD_ANY */
 594 #    endif
 595                                 f_ij = rv * F_invr;
 596
 597                                 /* accumulate j forces in registers */
 598                                 fcj_buf -= f_ij;
 599
 600                                 /* accumulate i forces in registers */
 601                                 fci_buf[i] += f_ij;
 602                             }
 603                         }
 604
 605                         /* shift the mask bit by 1 */
 606                         mask_ji += mask_ji;
 607                     }
 608
 609                     /* reduce j forces */
 610                     reduce_force_j_warp_shfl(fcj_buf, f, tidxi, aj, c_fullWarpMask);
 611                 }
 612             }
 613 #    ifdef PRUNE_NBL
 614             /* Update the imask with the new one which does not contain the
 615                out of range clusters anymore. */
 616             pl_cj4[j4].imei[widx].imask = imask;
 617 #    endif
 618         }
 619         // avoid shared memory WAR hazards between loop iterations
 620         __syncwarp(c_fullWarpMask);
 621     }
 622
 623     /* skip central shifts when summing shift forces */
 624     if (nb_sci.shift == CENTRAL)
 625     {
 626         bCalcFshift = false;
 627     }
 628
 629     float fshift_buf = 0.0f;
 630
 631     /* reduce i forces */
 632     for (i = 0; i < c_numClPerSupercl; i++)
 633     {
 634         ai = (sci * c_numClPerSupercl + i) * c_clSize + tidxi;
 635         reduce_force_i_warp_shfl(fci_buf[i], f, &fshift_buf, bCalcFshift, tidxj, ai, c_fullWarpMask);
 636     }
 637
 638     /* add up local shift forces into global mem, tidxj indexes x,y,z */
 639     if (bCalcFshift && (tidxj & 3) < 3)
 640     {
 641         atomicAdd(&(atdat.fshift[nb_sci.shift].x) + (tidxj & 3), fshift_buf);
 642     }
 643
 644 #    ifdef CALC_ENERGIES
 645     /* reduce the energies over warps and store into global memory */
 646     reduce_energy_warp_shfl(E_lj, E_el, e_lj, e_el, tidx, c_fullWarpMask);
 647 #    endif
 648 }
 649 #endif /* FUNCTION_DECLARATION_ONLY */
 650
 651 #undef NTHREAD_Z
 652 #undef MIN_BLOCKS_PER_MP
 653 #undef THREADS_PER_BLOCK
 654
 655 #undef EL_EWALD_ANY
 656 #undef EXCLUSION_FORCES
 657 #undef LJ_EWALD
 658
 659 #undef LJ_COMB