2 * This file is part of the GROMACS molecular simulation package.
4 * Copyright (c) 2019,2020, by the GROMACS development team, led by
5 * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
6 * and including many others, as listed in the AUTHORS file in the
7 * top-level source directory and at http://www.gromacs.org.
9 * GROMACS is free software; you can redistribute it and/or
10 * modify it under the terms of the GNU Lesser General Public License
11 * as published by the Free Software Foundation; either version 2.1
12 * of the License, or (at your option) any later version.
14 * GROMACS is distributed in the hope that it will be useful,
15 * but WITHOUT ANY WARRANTY; without even the implied warranty of
16 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
17 * Lesser General Public License for more details.
19 * You should have received a copy of the GNU Lesser General Public
20 * License along with GROMACS; if not, see
21 * http://www.gnu.org/licenses, or write to the Free Software Foundation,
22 * Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
24 * If you want to redistribute modifications to GROMACS, please
25 * consider that scientific software is very special. Version
26 * control is crucial - bugs must be traceable. We will be happy to
27 * consider code for inclusion in the official distribution, but
28 * derived work must not be called official GROMACS. Details are found
29 * in the README & COPYING files - if they are missing, get the
30 * official version at http://www.gromacs.org.
32 * To help us fund GROMACS development, we humbly ask that you cite
33 * the research papers on the package. Check out http://www.gromacs.org.
37 * \brief Implements LINCS using CUDA
39 * This file contains implementation of LINCS constraints algorithm
40 * using CUDA, including class initialization, data-structures management
43 * \author Artem Zhmurov <zhmurov@gmail.com>
44 * \author Alan Gray <alang@nvidia.com>
46 * \ingroup module_mdlib
50 #include "lincs_gpu.cuh"
59 #include "gromacs/gpu_utils/cuda_arch_utils.cuh"
60 #include "gromacs/gpu_utils/cudautils.cuh"
61 #include "gromacs/gpu_utils/devicebuffer.cuh"
62 #include "gromacs/gpu_utils/gputraits.cuh"
63 #include "gromacs/gpu_utils/vectype_ops.cuh"
64 #include "gromacs/math/vec.h"
65 #include "gromacs/mdlib/constr.h"
66 #include "gromacs/pbcutil/pbc.h"
67 #include "gromacs/pbcutil/pbc_aiuc_cuda.cuh"
68 #include "gromacs/topology/forcefieldparameters.h"
69 #include "gromacs/topology/ifunc.h"
70 #include "gromacs/topology/topology.h"
75 //! Number of CUDA threads in a block
76 constexpr static int c_threadsPerBlock = 256;
77 //! Maximum number of threads in a block (for __launch_bounds__)
78 constexpr static int c_maxThreadsPerBlock = c_threadsPerBlock;
80 /*! \brief Main kernel for LINCS constraints.
82 * See Hess et al., J. Comput. Chem. 18: 1463-1472 (1997) for the description of the algorithm.
84 * In CUDA version, one thread is responsible for all computations for one constraint. The blocks are
85 * filled in a way that no constraint is coupled to the constraint from the next block. This is achieved
86 * by moving active threads to the next block, if the correspondent group of coupled constraints is to big
87 * to fit the current thread block. This may leave some 'dummy' threads in the end of the thread block, i.e.
88 * threads that are not required to do actual work. Since constraints from different blocks are not coupled,
89 * there is no need to synchronize across the device. However, extensive communication in a thread block
92 * \todo Reduce synchronization overhead. Some ideas are:
93 * 1. Consider going to warp-level synchronization for the coupled constraints.
94 * 2. Move more data to local/shared memory and try to get rid of atomic operations (at least on
96 * 3. Use analytical solution for matrix A inversion.
97 * 4. Introduce mapping of thread id to both single constraint and single atom, thus designating
98 * Nth threads to deal with Nat <= Nth coupled atoms and Nc <= Nth coupled constraints.
99 * See Redmine issue #2885 for details (https://redmine.gromacs.org/issues/2885)
100 * \todo The use of __restrict__ for gm_xp and gm_v causes failure, probably because of the atomic
101 operations. Investigate this issue further.
103 * \param[in,out] kernelParams All parameters and pointers for the kernel condensed in single struct.
104 * \param[in] invdt Inverse timestep (needed to update velocities).
106 template<bool updateVelocities, bool computeVirial>
107 __launch_bounds__(c_maxThreadsPerBlock) __global__
108 void lincs_kernel(LincsGpuKernelParameters kernelParams,
109 const float3* __restrict__ gm_x,
114 const PbcAiuc pbcAiuc = kernelParams.pbcAiuc;
115 const int numConstraintsThreads = kernelParams.numConstraintsThreads;
116 const int numIterations = kernelParams.numIterations;
117 const int expansionOrder = kernelParams.expansionOrder;
118 const int2* __restrict__ gm_constraints = kernelParams.d_constraints;
119 const float* __restrict__ gm_constraintsTargetLengths = kernelParams.d_constraintsTargetLengths;
120 const int* __restrict__ gm_coupledConstraintsCounts = kernelParams.d_coupledConstraintsCounts;
121 const int* __restrict__ gm_coupledConstraintsIdxes = kernelParams.d_coupledConstraintsIndices;
122 const float* __restrict__ gm_massFactors = kernelParams.d_massFactors;
123 float* __restrict__ gm_matrixA = kernelParams.d_matrixA;
124 const float* __restrict__ gm_inverseMasses = kernelParams.d_inverseMasses;
125 float* __restrict__ gm_virialScaled = kernelParams.d_virialScaled;
127 int threadIndex = blockIdx.x * blockDim.x + threadIdx.x;
129 // numConstraintsThreads should be a integer multiple of blockSize (numConstraintsThreads = numBlocks*blockSize).
130 // This is to ensure proper synchronizations and reduction. All array are padded to the required size.
131 assert(threadIndex < numConstraintsThreads);
133 // Vectors connecting constrained atoms before algorithm was applied.
134 // Needed to construct constrain matrix A
135 extern __shared__ float3 sm_r[];
137 int2 pair = gm_constraints[threadIndex];
141 // Mass-scaled Lagrange multiplier
142 float lagrangeScaled = 0.0f;
147 float sqrtReducedMass;
153 // i == -1 indicates dummy constraint at the end of the thread block.
154 bool isDummyThread = (i == -1);
156 // Everything computed for these dummies will be equal to zero
162 sqrtReducedMass = 0.0f;
164 xi = make_float3(0.0f, 0.0f, 0.0f);
165 xj = make_float3(0.0f, 0.0f, 0.0f);
166 rc = make_float3(0.0f, 0.0f, 0.0f);
171 targetLength = gm_constraintsTargetLengths[threadIndex];
172 inverseMassi = gm_inverseMasses[i];
173 inverseMassj = gm_inverseMasses[j];
174 sqrtReducedMass = rsqrt(inverseMassi + inverseMassj);
179 float3 dx = pbcDxAiuc(pbcAiuc, xi, xj);
181 float rlen = rsqrtf(dx.x * dx.x + dx.y * dx.y + dx.z * dx.z);
185 sm_r[threadIdx.x] = rc;
186 // Make sure that all r's are saved into shared memory
187 // before they are accessed in the loop below
191 * Constructing LINCS matrix (A)
194 // Only non-zero values are saved (for coupled constraints)
195 int coupledConstraintsCount = gm_coupledConstraintsCounts[threadIndex];
196 for (int n = 0; n < coupledConstraintsCount; n++)
198 int index = n * numConstraintsThreads + threadIndex;
199 int c1 = gm_coupledConstraintsIdxes[index];
201 float3 rc1 = sm_r[c1 - blockIdx.x * blockDim.x];
202 gm_matrixA[index] = gm_massFactors[index] * (rc.x * rc1.x + rc.y * rc1.y + rc.z * rc1.z);
205 // Skipping in dummy threads
212 float3 dx = pbcDxAiuc(pbcAiuc, xi, xj);
214 float sol = sqrtReducedMass * ((rc.x * dx.x + rc.y * dx.y + rc.z * dx.z) - targetLength);
217 * Inverse matrix using a set of expansionOrder matrix multiplications
220 // This will use the same memory space as sm_r, which is no longer needed.
221 extern __shared__ float sm_rhs[];
222 // Save current right-hand-side vector in the shared memory
223 sm_rhs[threadIdx.x] = sol;
225 for (int rec = 0; rec < expansionOrder; rec++)
227 // Making sure that all sm_rhs are saved before they are accessed in a loop below
231 for (int n = 0; n < coupledConstraintsCount; n++)
233 int index = n * numConstraintsThreads + threadIndex;
234 int c1 = gm_coupledConstraintsIdxes[index];
235 // Convolute current right-hand-side with A
236 // Different, non overlapping parts of sm_rhs[..] are read during odd and even iterations
237 mvb = mvb + gm_matrixA[index] * sm_rhs[c1 - blockIdx.x * blockDim.x + blockDim.x * (rec % 2)];
239 // 'Switch' rhs vectors, save current result
240 // These values will be accessed in the loop above during the next iteration.
241 sm_rhs[threadIdx.x + blockDim.x * ((rec + 1) % 2)] = mvb;
245 // Current mass-scaled Lagrange multipliers
246 lagrangeScaled = sqrtReducedMass * sol;
248 // Save updated coordinates before correction for the rotational lengthening
249 float3 tmp = rc * lagrangeScaled;
251 // Writing for all but dummy constraints
254 atomicAdd(&gm_xp[i], -tmp * inverseMassi);
255 atomicAdd(&gm_xp[j], tmp * inverseMassj);
259 * Correction for centripetal effects
261 for (int iter = 0; iter < numIterations; iter++)
263 // Make sure that all xp's are saved: atomic operation calls before are
264 // communicating current xp[..] values across thread block.
273 float3 dx = pbcDxAiuc(pbcAiuc, xi, xj);
275 float len2 = targetLength * targetLength;
276 float dlen2 = 2.0f * len2 - norm2(dx);
278 // TODO A little bit more effective but slightly less readable version of the below would be:
279 // float proj = sqrtReducedMass*(targetLength - (dlen2 > 0.0f ? 1.0f : 0.0f)*dlen2*rsqrt(dlen2));
283 proj = sqrtReducedMass * (targetLength - dlen2 * rsqrt(dlen2));
287 proj = sqrtReducedMass * targetLength;
290 sm_rhs[threadIdx.x] = proj;
294 * Same matrix inversion as above is used for updated data
296 for (int rec = 0; rec < expansionOrder; rec++)
298 // Make sure that all elements of rhs are saved into shared memory
302 for (int n = 0; n < coupledConstraintsCount; n++)
304 int index = n * numConstraintsThreads + threadIndex;
305 int c1 = gm_coupledConstraintsIdxes[index];
307 mvb = mvb + gm_matrixA[index] * sm_rhs[c1 - blockIdx.x * blockDim.x + blockDim.x * (rec % 2)];
309 sm_rhs[threadIdx.x + blockDim.x * ((rec + 1) % 2)] = mvb;
313 // Add corrections to Lagrange multipliers
314 float sqrtmu_sol = sqrtReducedMass * sol;
315 lagrangeScaled += sqrtmu_sol;
317 // Save updated coordinates for the next iteration
318 // Dummy constraints are skipped
321 float3 tmp = rc * sqrtmu_sol;
322 atomicAdd(&gm_xp[i], -tmp * inverseMassi);
323 atomicAdd(&gm_xp[j], tmp * inverseMassj);
327 // Updating particle velocities for all but dummy threads
328 if (updateVelocities && !isDummyThread)
330 float3 tmp = rc * invdt * lagrangeScaled;
331 atomicAdd(&gm_v[i], -tmp * inverseMassi);
332 atomicAdd(&gm_v[j], tmp * inverseMassj);
338 // Virial is computed from Lagrange multiplier (lagrangeScaled), target constrain length
339 // (targetLength) and the normalized vector connecting constrained atoms before
340 // the algorithm was applied (rc). The evaluation of virial in each thread is
341 // followed by basic reduction for the values inside single thread block.
342 // Then, the values are reduced across grid by atomicAdd(...).
344 // TODO Shuffle reduction.
345 // TODO Should be unified and/or done once when virial is actually needed.
346 // TODO Recursive version that removes atomicAdd(...)'s entirely is needed. Ideally,
347 // one that works for any datatype.
349 // Save virial for each thread into the shared memory. Tensor is symmetrical, hence only
350 // 6 values are saved. Dummy threads will have zeroes in their virial: targetLength,
351 // lagrangeScaled and rc are all set to zero for them in the beginning of the kernel.
352 // The sm_threadVirial[..] will overlap with the sm_r[..] and sm_rhs[..], but the latter
353 // two are no longer in use.
354 extern __shared__ float sm_threadVirial[];
355 float mult = targetLength * lagrangeScaled;
356 sm_threadVirial[0 * blockDim.x + threadIdx.x] = mult * rc.x * rc.x;
357 sm_threadVirial[1 * blockDim.x + threadIdx.x] = mult * rc.x * rc.y;
358 sm_threadVirial[2 * blockDim.x + threadIdx.x] = mult * rc.x * rc.z;
359 sm_threadVirial[3 * blockDim.x + threadIdx.x] = mult * rc.y * rc.y;
360 sm_threadVirial[4 * blockDim.x + threadIdx.x] = mult * rc.y * rc.z;
361 sm_threadVirial[5 * blockDim.x + threadIdx.x] = mult * rc.z * rc.z;
365 // Reduce up to one virial per thread block. All blocks are divided by half, the first
366 // half of threads sums two virials. Then the first half is divided by two and the first
367 // half of it sums two values. This procedure is repeated until only one thread is left.
368 // Only works if the threads per blocks is a power of two (hence static_assert
369 // in the beginning of the kernel).
370 for (int divideBy = 2; divideBy <= static_cast<int>(blockDim.x); divideBy *= 2)
372 int dividedAt = blockDim.x / divideBy;
373 if (static_cast<int>(threadIdx.x) < dividedAt)
375 for (int d = 0; d < 6; d++)
377 sm_threadVirial[d * blockDim.x + threadIdx.x] +=
378 sm_threadVirial[d * blockDim.x + (threadIdx.x + dividedAt)];
381 // Syncronize if not within one warp
382 if (dividedAt > warpSize / 2)
387 // First 6 threads in the block add the results of 6 tensor components to the global memory address.
390 atomicAdd(&(gm_virialScaled[threadIdx.x]), sm_threadVirial[threadIdx.x * blockDim.x]);
397 /*! \brief Select templated kernel.
399 * Returns pointer to a CUDA kernel based on provided booleans.
401 * \param[in] updateVelocities If the velocities should be constrained.
402 * \param[in] computeVirial If virial should be updated.
404 * \return Pointer to CUDA kernel
406 inline auto getLincsKernelPtr(const bool updateVelocities, const bool computeVirial)
409 auto kernelPtr = lincs_kernel<true, true>;
410 if (updateVelocities && computeVirial)
412 kernelPtr = lincs_kernel<true, true>;
414 else if (updateVelocities && !computeVirial)
416 kernelPtr = lincs_kernel<true, false>;
418 else if (!updateVelocities && computeVirial)
420 kernelPtr = lincs_kernel<false, true>;
422 else if (!updateVelocities && !computeVirial)
424 kernelPtr = lincs_kernel<false, false>;
429 void LincsGpu::apply(const float3* d_x,
431 const bool updateVelocities,
434 const bool computeVirial,
436 const PbcAiuc pbcAiuc)
438 ensureNoPendingCudaError("In CUDA version of LINCS");
440 // Early exit if no constraints
441 if (kernelParams_.numConstraintsThreads == 0)
448 // Fill with zeros so the values can be reduced to it
449 // Only 6 values are needed because virial is symmetrical
450 clearDeviceBufferAsync(&kernelParams_.d_virialScaled, 0, 6, commandStream_);
453 auto kernelPtr = getLincsKernelPtr(updateVelocities, computeVirial);
455 KernelLaunchConfig config;
456 config.blockSize[0] = c_threadsPerBlock;
457 config.blockSize[1] = 1;
458 config.blockSize[2] = 1;
459 config.gridSize[0] = (kernelParams_.numConstraintsThreads + c_threadsPerBlock - 1) / c_threadsPerBlock;
460 config.gridSize[1] = 1;
461 config.gridSize[2] = 1;
463 // Shared memory is used to store:
464 // -- Current coordinates (3 floats per thread)
465 // -- Right-hand-sides for matrix inversion (2 floats per thread)
466 // -- Virial tensor components (6 floats per thread)
467 // Since none of these three are needed simultaneously, they can be saved at the same shared memory address
468 // (i.e. correspondent arrays are intentionally overlapped in address space). Consequently, only
469 // max{3, 2, 6} = 6 floats per thread are needed in case virial is computed, or max{3, 2} = 3 if not.
472 config.sharedMemorySize = c_threadsPerBlock * 6 * sizeof(float);
476 config.sharedMemorySize = c_threadsPerBlock * 3 * sizeof(float);
478 config.stream = commandStream_;
480 kernelParams_.pbcAiuc = pbcAiuc;
482 const auto kernelArgs =
483 prepareGpuKernelArguments(kernelPtr, config, &kernelParams_, &d_x, &d_xp, &d_v, &invdt);
485 launchGpuKernel(kernelPtr, config, nullptr, "lincs_kernel<updateVelocities, computeVirial>", kernelArgs);
489 // Copy LINCS virial data and add it to the common virial
490 copyFromDeviceBuffer(h_virialScaled_.data(), &kernelParams_.d_virialScaled, 0, 6,
491 commandStream_, GpuApiCallBehavior::Sync, nullptr);
493 // Mapping [XX, XY, XZ, YY, YZ, ZZ] internal format to a tensor object
494 virialScaled[XX][XX] += h_virialScaled_[0];
495 virialScaled[XX][YY] += h_virialScaled_[1];
496 virialScaled[XX][ZZ] += h_virialScaled_[2];
498 virialScaled[YY][XX] += h_virialScaled_[1];
499 virialScaled[YY][YY] += h_virialScaled_[3];
500 virialScaled[YY][ZZ] += h_virialScaled_[4];
502 virialScaled[ZZ][XX] += h_virialScaled_[2];
503 virialScaled[ZZ][YY] += h_virialScaled_[4];
504 virialScaled[ZZ][ZZ] += h_virialScaled_[5];
510 LincsGpu::LincsGpu(int numIterations, int expansionOrder, CommandStream commandStream) :
511 commandStream_(commandStream)
513 kernelParams_.numIterations = numIterations;
514 kernelParams_.expansionOrder = expansionOrder;
516 static_assert(sizeof(real) == sizeof(float),
517 "Real numbers should be in single precision in GPU code.");
519 c_threadsPerBlock > 0 && ((c_threadsPerBlock & (c_threadsPerBlock - 1)) == 0),
520 "Number of threads per block should be a power of two in order for reduction to work.");
522 allocateDeviceBuffer(&kernelParams_.d_virialScaled, 6, nullptr);
523 h_virialScaled_.resize(6);
525 // The data arrays should be expanded/reallocated on first call of set() function.
526 numConstraintsThreadsAlloc_ = 0;
530 LincsGpu::~LincsGpu()
532 freeDeviceBuffer(&kernelParams_.d_virialScaled);
534 if (numConstraintsThreadsAlloc_ > 0)
536 freeDeviceBuffer(&kernelParams_.d_constraints);
537 freeDeviceBuffer(&kernelParams_.d_constraintsTargetLengths);
539 freeDeviceBuffer(&kernelParams_.d_coupledConstraintsCounts);
540 freeDeviceBuffer(&kernelParams_.d_coupledConstraintsIndices);
541 freeDeviceBuffer(&kernelParams_.d_massFactors);
542 freeDeviceBuffer(&kernelParams_.d_matrixA);
544 if (numAtomsAlloc_ > 0)
546 freeDeviceBuffer(&kernelParams_.d_inverseMasses);
550 //! Helper type for discovering coupled constraints
551 struct AtomsAdjacencyListElement
553 AtomsAdjacencyListElement(const int indexOfSecondConstrainedAtom,
554 const int indexOfConstraint,
555 const int signFactor) :
556 indexOfSecondConstrainedAtom_(indexOfSecondConstrainedAtom),
557 indexOfConstraint_(indexOfConstraint),
558 signFactor_(signFactor)
561 //! The index of the other atom constrained to this atom.
562 int indexOfSecondConstrainedAtom_;
563 //! The index of this constraint in the container of constraints.
564 int indexOfConstraint_;
565 /*! \brief A multiplicative factor that indicates the relative
566 * order of the atoms in the atom list.
568 * Used for computing the mass factor of this constraint
569 * relative to any coupled constraints. */
572 //! Constructs and returns an atom constraint adjacency list
573 static std::vector<std::vector<AtomsAdjacencyListElement>>
574 constructAtomsAdjacencyList(const int numAtoms, ArrayRef<const int> iatoms)
576 const int stride = 1 + NRAL(F_CONSTR);
577 const int numConstraints = iatoms.ssize() / stride;
578 std::vector<std::vector<AtomsAdjacencyListElement>> atomsAdjacencyList(numAtoms);
579 for (int c = 0; c < numConstraints; c++)
581 int a1 = iatoms[stride * c + 1];
582 int a2 = iatoms[stride * c + 2];
584 // Each constraint will be represented as a tuple, containing index of the second
585 // constrained atom, index of the constraint and a sign that indicates the order of atoms in
586 // which they are listed. Sign is needed to compute the mass factors.
587 atomsAdjacencyList[a1].emplace_back(a2, c, +1);
588 atomsAdjacencyList[a2].emplace_back(a1, c, -1);
591 return atomsAdjacencyList;
594 /*! \brief Helper function to go through constraints recursively.
596 * For each constraint, counts the number of coupled constraints and stores the value in \p numCoupledConstraints array.
597 * This information is used to split the array of constraints between thread blocks on a GPU so there is no
598 * coupling between constraints from different thread blocks. After the \p numCoupledConstraints array is filled, the
599 * value \p numCoupledConstraints[c] should be equal to the number of constraints that are coupled to \p c and located
600 * after it in the constraints array.
602 * \param[in] a Atom index.
603 * \param[in,out] numCoupledConstraints Indicates if the constraint was already counted and stores
604 * the number of constraints (i) connected to it and (ii) located
605 * after it in memory. This array is filled by this recursive function.
606 * For a set of coupled constraints, only for the first one in this list
607 * the number of consecutive coupled constraints is needed: if there is
608 * not enough space for this set of constraints in the thread block,
609 * the group has to be moved to the next one.
610 * \param[in] atomsAdjacencyList Stores information about connections between atoms.
612 inline int countCoupled(int a,
613 ArrayRef<int> numCoupledConstraints,
614 ArrayRef<const std::vector<AtomsAdjacencyListElement>> atomsAdjacencyList)
618 for (const auto& adjacentAtom : atomsAdjacencyList[a])
620 const int c2 = adjacentAtom.indexOfConstraint_;
621 if (numCoupledConstraints[c2] == -1)
623 numCoupledConstraints[c2] = 0; // To indicate we've been here
625 + countCoupled(adjacentAtom.indexOfSecondConstrainedAtom_,
626 numCoupledConstraints, atomsAdjacencyList);
632 /*! \brief Add constraint to \p splitMap with all constraints coupled to it.
634 * Adds the constraint \p c from the constrain list \p iatoms to the map \p splitMap
635 * if it was not yet added. Then goes through all the constraints coupled to \p c
636 * and calls itself recursively. This ensures that all the coupled constraints will
637 * be added to neighboring locations in the final data structures on the device,
638 * hence mapping all coupled constraints to the same thread block. A value of -1 in
639 * the \p splitMap is used to flag that constraint was not yet added to the \p splitMap.
641 * \param[in] iatoms The list of constraints.
642 * \param[in] stride Number of elements per constraint in \p iatoms.
643 * \param[in] atomsAdjacencyList Information about connections between atoms.
644 * \param[our] splitMap Map of sequential constraint indexes to indexes to be on the device
645 * \param[in] c Sequential index for constraint to consider adding.
646 * \param[in,out] currentMapIndex The rolling index for the constraints mapping.
648 inline void addWithCoupled(ArrayRef<const int> iatoms,
650 ArrayRef<const std::vector<AtomsAdjacencyListElement>> atomsAdjacencyList,
651 ArrayRef<int> splitMap,
653 int* currentMapIndex)
655 if (splitMap[c] == -1)
657 splitMap[c] = *currentMapIndex;
658 (*currentMapIndex)++;
660 // Constraints, coupled through both atoms.
661 for (int atomIndexInConstraint = 0; atomIndexInConstraint < 2; atomIndexInConstraint++)
663 const int a1 = iatoms[stride * c + 1 + atomIndexInConstraint];
664 for (const auto& adjacentAtom : atomsAdjacencyList[a1])
666 const int c2 = adjacentAtom.indexOfConstraint_;
669 addWithCoupled(iatoms, stride, atomsAdjacencyList, splitMap, c2, currentMapIndex);
676 /*! \brief Computes and returns how many constraints are coupled to each constraint
678 * Needed to introduce splits in data so that all coupled constraints will be computed in a
679 * single GPU block. The position \p c of the vector \p numCoupledConstraints should have the number
680 * of constraints that are coupled to a constraint \p c and are after \p c in the vector. Only
681 * first index of the connected group of the constraints is needed later in the code, hence the
682 * numCoupledConstraints vector is also used to keep track if the constrain was already counted.
684 static std::vector<int> countNumCoupledConstraints(ArrayRef<const int> iatoms,
685 ArrayRef<const std::vector<AtomsAdjacencyListElement>> atomsAdjacencyList)
687 const int stride = 1 + NRAL(F_CONSTR);
688 const int numConstraints = iatoms.ssize() / stride;
689 std::vector<int> numCoupledConstraints(numConstraints, -1);
690 for (int c = 0; c < numConstraints; c++)
692 const int a1 = iatoms[stride * c + 1];
693 const int a2 = iatoms[stride * c + 2];
694 if (numCoupledConstraints[c] == -1)
696 numCoupledConstraints[c] = countCoupled(a1, numCoupledConstraints, atomsAdjacencyList)
697 + countCoupled(a2, numCoupledConstraints, atomsAdjacencyList);
701 return numCoupledConstraints;
704 bool LincsGpu::isNumCoupledConstraintsSupported(const gmx_mtop_t& mtop)
706 for (const gmx_moltype_t& molType : mtop.moltype)
708 ArrayRef<const int> iatoms = molType.ilist[F_CONSTR].iatoms;
709 const auto atomsAdjacencyList = constructAtomsAdjacencyList(molType.atoms.nr, iatoms);
710 // Compute, how many constraints are coupled to each constraint
711 const auto numCoupledConstraints = countNumCoupledConstraints(iatoms, atomsAdjacencyList);
712 for (const int numCoupled : numCoupledConstraints)
714 if (numCoupled > c_threadsPerBlock)
724 void LincsGpu::set(const InteractionDefinitions& idef, const t_mdatoms& md)
726 int numAtoms = md.nr;
727 // List of constrained atoms (CPU memory)
728 std::vector<int2> constraintsHost;
729 // Equilibrium distances for the constraints (CPU)
730 std::vector<float> constraintsTargetLengthsHost;
731 // Number of constraints, coupled with the current one (CPU)
732 std::vector<int> coupledConstraintsCountsHost;
733 // List of coupled with the current one (CPU)
734 std::vector<int> coupledConstraintsIndicesHost;
735 // Mass factors (CPU)
736 std::vector<float> massFactorsHost;
738 // List of constrained atoms in local topology
739 ArrayRef<const int> iatoms = idef.il[F_CONSTR].iatoms;
740 const int stride = NRAL(F_CONSTR) + 1;
741 const int numConstraints = idef.il[F_CONSTR].size() / stride;
743 // Early exit if no constraints
744 if (numConstraints == 0)
746 kernelParams_.numConstraintsThreads = 0;
750 // Construct the adjacency list, a useful intermediate structure
751 const auto atomsAdjacencyList = constructAtomsAdjacencyList(numAtoms, iatoms);
753 // Compute, how many constraints are coupled to each constraint
754 const auto numCoupledConstraints = countNumCoupledConstraints(iatoms, atomsAdjacencyList);
756 // Map of splits in the constraints data. For each 'old' constraint index gives 'new' which
757 // takes into account the empty spaces which might be needed in the end of each thread block.
758 std::vector<int> splitMap(numConstraints, -1);
759 int currentMapIndex = 0;
760 for (int c = 0; c < numConstraints; c++)
762 // Check if coupled constraints all fit in one block
763 if (numCoupledConstraints.at(c) > c_threadsPerBlock)
766 "Maximum number of coupled constraints (%d) exceeds the size of the CUDA "
767 "thread block (%d). Most likely, you are trying to use the GPU version of "
768 "LINCS with constraints on all-bonds, which is not supported for large "
769 "molecules. When compatible with the force field and integration settings, "
770 "using constraints on H-bonds only.",
771 numCoupledConstraints.at(c), c_threadsPerBlock);
773 if (currentMapIndex / c_threadsPerBlock
774 != (currentMapIndex + numCoupledConstraints.at(c)) / c_threadsPerBlock)
776 currentMapIndex = ((currentMapIndex / c_threadsPerBlock) + 1) * c_threadsPerBlock;
778 addWithCoupled(iatoms, stride, atomsAdjacencyList, splitMap, c, ¤tMapIndex);
781 kernelParams_.numConstraintsThreads =
782 currentMapIndex + c_threadsPerBlock - currentMapIndex % c_threadsPerBlock;
783 GMX_RELEASE_ASSERT(kernelParams_.numConstraintsThreads % c_threadsPerBlock == 0,
784 "Number of threads should be a multiple of the block size");
786 // Initialize constraints and their target indexes taking into account the splits in the data arrays.
790 constraintsHost.resize(kernelParams_.numConstraintsThreads, pair);
791 std::fill(constraintsHost.begin(), constraintsHost.end(), pair);
792 constraintsTargetLengthsHost.resize(kernelParams_.numConstraintsThreads, 0.0);
793 std::fill(constraintsTargetLengthsHost.begin(), constraintsTargetLengthsHost.end(), 0.0);
794 for (int c = 0; c < numConstraints; c++)
796 int a1 = iatoms[stride * c + 1];
797 int a2 = iatoms[stride * c + 2];
798 int type = iatoms[stride * c];
803 constraintsHost.at(splitMap.at(c)) = pair;
804 constraintsTargetLengthsHost.at(splitMap.at(c)) = idef.iparams[type].constr.dA;
807 // The adjacency list of constraints (i.e. the list of coupled constraints for each constraint).
808 // We map a single thread to a single constraint, hence each thread 'c' will be using one
809 // element from coupledConstraintsCountsHost array, which is the number of constraints coupled
810 // to the constraint 'c'. The coupled constraints indexes are placed into the
811 // coupledConstraintsIndicesHost array. Latter is organized as a one-dimensional array to ensure
812 // good memory alignment. It is addressed as [c + i*numConstraintsThreads], where 'i' goes from
813 // zero to the number of constraints coupled to 'c'. 'numConstraintsThreads' is the width of the
814 // array --- a number, greater then total number of constraints, taking into account the splits
815 // in the constraints array due to the GPU block borders. This number can be adjusted to improve
816 // memory access pattern. Mass factors are saved in a similar data structure.
817 int maxCoupledConstraints = 0;
818 for (int c = 0; c < numConstraints; c++)
820 int a1 = iatoms[stride * c + 1];
821 int a2 = iatoms[stride * c + 2];
823 // Constraint 'c' is counted twice, but it should be excluded altogether. Hence '-2'.
824 int nCoupedConstraints = atomsAdjacencyList.at(a1).size() + atomsAdjacencyList.at(a2).size() - 2;
826 if (nCoupedConstraints > maxCoupledConstraints)
828 maxCoupledConstraints = nCoupedConstraints;
832 coupledConstraintsCountsHost.resize(kernelParams_.numConstraintsThreads, 0);
833 coupledConstraintsIndicesHost.resize(maxCoupledConstraints * kernelParams_.numConstraintsThreads, -1);
834 massFactorsHost.resize(maxCoupledConstraints * kernelParams_.numConstraintsThreads, -1);
836 for (int c1 = 0; c1 < numConstraints; c1++)
838 coupledConstraintsCountsHost.at(splitMap.at(c1)) = 0;
839 int c1a1 = iatoms[stride * c1 + 1];
840 int c1a2 = iatoms[stride * c1 + 2];
842 // Constraints, coupled through the first atom.
844 for (const auto& atomAdjacencyList : atomsAdjacencyList[c1a1])
846 int c2 = atomAdjacencyList.indexOfConstraint_;
850 int c2a2 = atomAdjacencyList.indexOfSecondConstrainedAtom_;
851 int sign = atomAdjacencyList.signFactor_;
852 int index = kernelParams_.numConstraintsThreads
853 * coupledConstraintsCountsHost.at(splitMap.at(c1))
856 coupledConstraintsIndicesHost.at(index) = splitMap.at(c2);
860 float sqrtmu1 = 1.0 / sqrt(md.invmass[c1a1] + md.invmass[c1a2]);
861 float sqrtmu2 = 1.0 / sqrt(md.invmass[c2a1] + md.invmass[c2a2]);
863 massFactorsHost.at(index) = -sign * md.invmass[center] * sqrtmu1 * sqrtmu2;
865 coupledConstraintsCountsHost.at(splitMap.at(c1))++;
869 // Constraints, coupled through the second atom.
871 for (const auto& atomAdjacencyList : atomsAdjacencyList[c1a2])
873 int c2 = atomAdjacencyList.indexOfConstraint_;
877 int c2a2 = atomAdjacencyList.indexOfSecondConstrainedAtom_;
878 int sign = atomAdjacencyList.signFactor_;
879 int index = kernelParams_.numConstraintsThreads
880 * coupledConstraintsCountsHost.at(splitMap.at(c1))
883 coupledConstraintsIndicesHost.at(index) = splitMap.at(c2);
887 float sqrtmu1 = 1.0 / sqrt(md.invmass[c1a1] + md.invmass[c1a2]);
888 float sqrtmu2 = 1.0 / sqrt(md.invmass[c2a1] + md.invmass[c2a2]);
890 massFactorsHost.at(index) = sign * md.invmass[center] * sqrtmu1 * sqrtmu2;
892 coupledConstraintsCountsHost.at(splitMap.at(c1))++;
897 // (Re)allocate the memory, if the number of constraints has increased.
898 if (kernelParams_.numConstraintsThreads > numConstraintsThreadsAlloc_)
900 // Free memory if it was allocated before (i.e. if not the first time here).
901 if (numConstraintsThreadsAlloc_ > 0)
903 freeDeviceBuffer(&kernelParams_.d_constraints);
904 freeDeviceBuffer(&kernelParams_.d_constraintsTargetLengths);
906 freeDeviceBuffer(&kernelParams_.d_coupledConstraintsCounts);
907 freeDeviceBuffer(&kernelParams_.d_coupledConstraintsIndices);
908 freeDeviceBuffer(&kernelParams_.d_massFactors);
909 freeDeviceBuffer(&kernelParams_.d_matrixA);
912 numConstraintsThreadsAlloc_ = kernelParams_.numConstraintsThreads;
914 allocateDeviceBuffer(&kernelParams_.d_constraints, kernelParams_.numConstraintsThreads, nullptr);
915 allocateDeviceBuffer(&kernelParams_.d_constraintsTargetLengths,
916 kernelParams_.numConstraintsThreads, nullptr);
918 allocateDeviceBuffer(&kernelParams_.d_coupledConstraintsCounts,
919 kernelParams_.numConstraintsThreads, nullptr);
920 allocateDeviceBuffer(&kernelParams_.d_coupledConstraintsIndices,
921 maxCoupledConstraints * kernelParams_.numConstraintsThreads, nullptr);
922 allocateDeviceBuffer(&kernelParams_.d_massFactors,
923 maxCoupledConstraints * kernelParams_.numConstraintsThreads, nullptr);
924 allocateDeviceBuffer(&kernelParams_.d_matrixA,
925 maxCoupledConstraints * kernelParams_.numConstraintsThreads, nullptr);
928 // (Re)allocate the memory, if the number of atoms has increased.
929 if (numAtoms > numAtomsAlloc_)
931 if (numAtomsAlloc_ > 0)
933 freeDeviceBuffer(&kernelParams_.d_inverseMasses);
935 numAtomsAlloc_ = numAtoms;
936 allocateDeviceBuffer(&kernelParams_.d_inverseMasses, numAtoms, nullptr);
940 copyToDeviceBuffer(&kernelParams_.d_constraints, constraintsHost.data(), 0,
941 kernelParams_.numConstraintsThreads, commandStream_,
942 GpuApiCallBehavior::Sync, nullptr);
943 copyToDeviceBuffer(&kernelParams_.d_constraintsTargetLengths,
944 constraintsTargetLengthsHost.data(), 0, kernelParams_.numConstraintsThreads,
945 commandStream_, GpuApiCallBehavior::Sync, nullptr);
946 copyToDeviceBuffer(&kernelParams_.d_coupledConstraintsCounts,
947 coupledConstraintsCountsHost.data(), 0, kernelParams_.numConstraintsThreads,
948 commandStream_, GpuApiCallBehavior::Sync, nullptr);
949 copyToDeviceBuffer(&kernelParams_.d_coupledConstraintsIndices, coupledConstraintsIndicesHost.data(),
950 0, maxCoupledConstraints * kernelParams_.numConstraintsThreads,
951 commandStream_, GpuApiCallBehavior::Sync, nullptr);
952 copyToDeviceBuffer(&kernelParams_.d_massFactors, massFactorsHost.data(), 0,
953 maxCoupledConstraints * kernelParams_.numConstraintsThreads, commandStream_,
954 GpuApiCallBehavior::Sync, nullptr);
956 GMX_RELEASE_ASSERT(md.invmass != nullptr, "Masses of atoms should be specified.\n");
957 copyToDeviceBuffer(&kernelParams_.d_inverseMasses, md.invmass, 0, numAtoms, commandStream_,
958 GpuApiCallBehavior::Sync, nullptr);